mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-09-29 19:07:52 +00:00
6a1f6ee1f8
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
113 lines
4.1 KiB
EmacsLisp
113 lines
4.1 KiB
EmacsLisp
;;; ob-groovy.el --- Babel Functions for Groovy -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2013-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Miro Bezjak
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
;; Currently only supports the external execution. No session support yet.
|
|
|
|
;;; Requirements:
|
|
;; - Groovy language :: http://groovy.codehaus.org
|
|
;; - Groovy major mode :: Can be installed from MELPA or
|
|
;; https://github.com/russel/Emacs-Groovy-Mode
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(defvar org-babel-tangle-lang-exts) ;; Autoloaded
|
|
(add-to-list 'org-babel-tangle-lang-exts '("groovy" . "groovy"))
|
|
(defvar org-babel-default-header-args:groovy '())
|
|
(defcustom org-babel-groovy-command "groovy"
|
|
"Name of the command to use for executing Groovy code.
|
|
May be either a command in the path, like groovy
|
|
or an absolute path name, like /usr/local/bin/groovy
|
|
parameters may be used, like groovy -v"
|
|
:group 'org-babel
|
|
:version "24.3"
|
|
:type 'string)
|
|
|
|
(defun org-babel-execute:groovy (body params)
|
|
"Execute a block of Groovy code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(message "executing Groovy source code block")
|
|
(let* ((processed-params (org-babel-process-params params))
|
|
(session (org-babel-groovy-initiate-session (nth 0 processed-params)))
|
|
(result-params (nth 2 processed-params))
|
|
(result-type (cdr (assq :result-type params)))
|
|
(full-body (org-babel-expand-body:generic
|
|
body params))
|
|
(result (org-babel-groovy-evaluate
|
|
session full-body result-type result-params)))
|
|
|
|
(org-babel-reassemble-table
|
|
result
|
|
(org-babel-pick-name
|
|
(cdr (assq :colname-names params)) (cdr (assq :colnames params)))
|
|
(org-babel-pick-name
|
|
(cdr (assq :rowname-names params)) (cdr (assq :rownames params))))))
|
|
|
|
(defvar org-babel-groovy-wrapper-method
|
|
"class Runner extends Script {
|
|
def out = new PrintWriter(new ByteArrayOutputStream())
|
|
def run() { %s }
|
|
}
|
|
|
|
println(new Runner().run())
|
|
")
|
|
|
|
(defun org-babel-groovy-evaluate
|
|
(session body &optional result-type result-params)
|
|
"Evaluate BODY in external Groovy process.
|
|
If RESULT-TYPE equals `output' then return standard output as a string.
|
|
If RESULT-TYPE equals `value' then return the value of the last statement
|
|
in BODY as elisp."
|
|
(when session (error "Sessions are not (yet) supported for Groovy"))
|
|
(pcase result-type
|
|
(`output
|
|
(let ((src-file (org-babel-temp-file "groovy_")))
|
|
(progn (with-temp-file src-file (insert body))
|
|
(org-babel-eval
|
|
(concat org-babel-groovy-command " " src-file) ""))))
|
|
(`value
|
|
(let* ((src-file (org-babel-temp-file "groovy_"))
|
|
(wrapper (format org-babel-groovy-wrapper-method body)))
|
|
(with-temp-file src-file (insert wrapper))
|
|
(let ((raw (org-babel-eval
|
|
(concat org-babel-groovy-command " " src-file) "")))
|
|
(org-babel-result-cond result-params
|
|
raw
|
|
(org-babel-script-escape raw)))))))
|
|
|
|
|
|
(defun org-babel-prep-session:groovy (_session _params)
|
|
"Prepare SESSION according to the header arguments specified in PARAMS."
|
|
(error "Sessions are not (yet) supported for Groovy"))
|
|
|
|
(defun org-babel-groovy-initiate-session (&optional _session)
|
|
"If there is not a current inferior-process-buffer in SESSION
|
|
then create. Return the initialized session. Sessions are not
|
|
supported in Groovy."
|
|
nil)
|
|
|
|
(provide 'ob-groovy)
|
|
|
|
;;; ob-groovy.el ends here
|