mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-09-29 19:37:52 +00:00
f0bf77e82a
* lisp/ob-C.el (org-babel-prep-session:C): (org-babel-load-session:C): * lisp/ob-J.el: (org-babel-expand-body:J): (org-babel-execute:J): * lisp/ob-R.el: (org-babel-expand-body:R): * lisp/ob-abc.el: (org-babel-execute:abc): (org-babel-prep-session:abc): * lisp/ob-asymptote.el: (org-babel-execute:asymptote): (org-babel-prep-session:asymptote): * lisp/ob-awk.el: (org-babel-expand-body:awk): * lisp/ob-calc.el: (org-babel-expand-body:calc): * lisp/ob-clojure.el: * lisp/ob-comint.el: (org-babel-comint-in-buffer): (org-babel-comint-with-output): (org-babel-comint-eval-invisibly-and-wait-for-file): * lisp/ob-coq.el: * lisp/ob-css.el: (org-babel-execute:css): (org-babel-prep-session:css): * lisp/ob-ditaa.el: (org-babel-execute:ditaa): (org-babel-prep-session:ditaa): * lisp/ob-dot.el: (org-babel-execute:dot): (org-babel-prep-session:dot): * lisp/ob-ebnf.el: * lisp/ob-emacs-lisp.el: * lisp/ob-eval.el: * lisp/ob-forth.el: * lisp/ob-fortran.el: (org-babel-execute:fortran): (org-babel-prep-session:fortran): (org-babel-load-session:fortran): * lisp/ob-gnuplot.el: (org-babel-expand-body:gnuplot): (org-babel-prep-session:gnuplot): (org-babel-gnuplot-initiate-session): * lisp/ob-groovy.el: (org-babel-prep-session:groovy): (org-babel-groovy-initiate-session): * lisp/ob-haskell.el: (org-babel-haskell-initiate-session): * lisp/ob-io.el: (org-babel-prep-session:io): (org-babel-io-initiate-session): * lisp/ob-java.el: (org-babel-execute:java): * lisp/ob-js.el: * lisp/ob-keys.el: * lisp/ob-latex.el: (org-babel-prep-session:latex): * lisp/ob-ledger.el: (org-babel-execute:ledger): (org-babel-prep-session:ledger): * lisp/ob-lilypond.el: (org-babel-lilypond-commands): (org-babel-lilypond-process-basic): (org-babel-prep-session:lilypond): (org-babel-lilypond-parse-line-num): * lisp/ob-lisp.el: * lisp/ob-makefile.el: (org-babel-execute:makefile): (org-babel-prep-session:makefile): * lisp/ob-matlab.el: * lisp/ob-maxima.el: (org-babel-prep-session:maxima): * lisp/ob-mscgen.el: (org-babel-prep-session:mscgen): * lisp/ob-ocaml.el: (org-babel-execute:ocaml): (org-babel-prep-session:ocaml): * lisp/ob-octave.el: (org-babel-execute:octave): (org-babel-octave-initiate-session): * lisp/ob-org.el: (org-babel-prep-session:org): * lisp/ob-perl.el: (org-babel-prep-session:perl): (org-babel-perl--var-to-perl): (org-babel-perl-initiate-session): * lisp/ob-picolisp.el: (org-babel-expand-body:picolisp): (org-babel-execute:picolisp): * lisp/ob-plantuml.el: (org-babel-execute:plantuml): (org-babel-prep-session:plantuml): * lisp/ob-processing.el: (org-babel-prep-session:processing): * lisp/ob-python.el: (org-babel-python-initiate-session): * lisp/ob-ref.el: (org-babel-ref-resolve): * lisp/ob-ruby.el: (org-babel-ruby-initiate-session): * lisp/ob-sass.el: (org-babel-execute:sass): (org-babel-prep-session:sass): * lisp/ob-scala.el: (org-babel-execute:scala): (org-babel-prep-session:scala): (org-babel-scala-initiate-session): * lisp/ob-scheme.el: * lisp/ob-screen.el: (org-babel-prep-session:screen): (org-babel-screen-session-write-temp-file): (org-babel-screen-test): * lisp/ob.el: * lisp/org-colview.el: (org-columns-todo): (org-columns-set-tags-or-toggle): (org-columns-new): (org-columns-uncompile-format): (org-agenda-colview-summarize): * lisp/org-footnote.el: (electric-indent-mode): * lisp/org-indent.el: (org-indent-refresh-maybe): * lisp/org-list.el: * lisp/org-macro.el: (org-macro--collect-macros): * lisp/org-src.el: * lisp/org-table.el: (sort-fold-case): (org-table-create): (org-table-field-info): (org-table-transpose-table-at-point): (org-table-remove-rectangle-highlight): (orgtbl-create-or-convert-from-region): (org-define-lookup-function): * lisp/ox-ascii.el: (org-ascii-format-drawer-function): (org-ascii--has-caption-p): (org-ascii-bold): (org-ascii-center-block): (org-ascii-clock): (org-ascii-code): (org-ascii-dynamic-block): (org-ascii-entity): (org-ascii-example-block): (org-ascii-export-snippet): (org-ascii-export-block): (org-ascii-fixed-width): (org-ascii-footnote-reference): (org-ascii-horizontal-rule): (org-ascii-inline-src-block): (org-ascii-format-inlinetask-default): (org-ascii-italic): (org-ascii-keyword): (org-ascii-latex-environment): (org-ascii-latex-fragment): (org-ascii-line-break): (org-ascii-node-property): (org-ascii-planning): (org-ascii-quote-block): (org-ascii-radio-target): (org-ascii-special-block): (org-ascii-src-block): (org-ascii-statistics-cookie): (org-ascii-subscript): (org-ascii-superscript): (org-ascii-strike-through): (org-ascii-timestamp): (org-ascii-underline): (org-ascii-verbatim): (org-ascii-verse-block): (org-ascii-filter-headline-blank-lines): (org-ascii-filter-paragraph-spacing): (org-ascii-filter-comment-spacing): Use lexical binding.
177 lines
5.7 KiB
EmacsLisp
177 lines
5.7 KiB
EmacsLisp
;;; ob-J.el --- Babel Functions for J -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2011-2013 Free Software Foundation, Inc.
|
|
|
|
;; Author: Oleh Krehel
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating J code.
|
|
;;
|
|
;; Session interaction depends on `j-console' from package `j-mode'
|
|
;; (available in MELPA).
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(declare-function org-trim "org" (S))
|
|
(declare-function j-console-ensure-session "ext:j-console" ())
|
|
|
|
(defun org-babel-expand-body:J (body _params &optional _processed-params)
|
|
"Expand BODY according to PARAMS, return the expanded body.
|
|
PROCESSED-PARAMS isn't used yet."
|
|
(org-babel-J-interleave-echos-except-functions body))
|
|
|
|
(defun org-babel-J-interleave-echos (body)
|
|
"Interleave echo',' between each source line of BODY."
|
|
(mapconcat #'identity (split-string body "\n") "\necho','\n"))
|
|
|
|
(defun org-babel-J-interleave-echos-except-functions (body)
|
|
"Interleave echo',' between source lines of BODY that aren't functions."
|
|
(if (obj-string-match-m "\\(?:^\\|\n\\)[^\n]*\\(?:0\\|1\\|2\\|3\\|4\\|dyad\\) : 0\n.*\n)\\(?:\n\\|$\\)" body)
|
|
(let ((s1 (substring body 0 (match-beginning 0)))
|
|
(s2 (match-string 0 body))
|
|
(s3 (substring body (match-end 0))))
|
|
(concat
|
|
(if (string= s1 "")
|
|
""
|
|
(concat (org-babel-J-interleave-echos s1)
|
|
"\necho','\n"))
|
|
s2
|
|
"\necho','\n"
|
|
(org-babel-J-interleave-echos-except-functions s3)))
|
|
(org-babel-J-interleave-echos body)))
|
|
|
|
(defun org-babel-execute:J (body params)
|
|
"Execute a block of J code BODY.
|
|
PARAMS are given by org-babel.
|
|
This function is called by `org-babel-execute-src-block'"
|
|
(message "executing J source code block")
|
|
(let* ((processed-params (org-babel-process-params params))
|
|
(sessionp (cdr (assoc :session params)))
|
|
(full-body (org-babel-expand-body:J
|
|
body params processed-params))
|
|
(tmp-script-file (org-babel-temp-file "J-src")))
|
|
(org-babel-j-initiate-session sessionp)
|
|
(org-babel-J-strip-whitespace
|
|
(if (string= sessionp "none")
|
|
(progn
|
|
(with-temp-file tmp-script-file
|
|
(insert full-body))
|
|
(org-babel-eval (format "jconsole < %s" tmp-script-file) ""))
|
|
(org-babel-J-eval-string full-body)))))
|
|
|
|
(defun org-babel-J-eval-string (str)
|
|
"Sends STR to the `j-console-cmd' session and exectues it."
|
|
(let ((session (j-console-ensure-session)))
|
|
(with-current-buffer (process-buffer session)
|
|
(goto-char (point-max))
|
|
(insert (format "\n%s\n" str))
|
|
(let ((beg (point)))
|
|
(comint-send-input)
|
|
(sit-for .1)
|
|
(buffer-substring-no-properties
|
|
beg (point-max))))))
|
|
|
|
(defun org-babel-J-strip-whitespace (str)
|
|
"Remove whitespace from jconsole output STR."
|
|
(mapconcat
|
|
#'identity
|
|
(delete "" (mapcar
|
|
#'org-babel-J-print-block
|
|
(split-string str "^ *,\n" t)))
|
|
"\n\n"))
|
|
|
|
(defun obj-get-string-alignment (str)
|
|
"Return a number to describe STR alignment.
|
|
STR represents a table.
|
|
Positive/negative/zero result means right/left/undetermined.
|
|
Don't trust first line."
|
|
(let* ((str (org-trim str))
|
|
(lines (split-string str "\n" t))
|
|
n1 n2)
|
|
(cond ((<= (length lines) 1)
|
|
0)
|
|
((= (length lines) 2)
|
|
;; numbers are right-aligned
|
|
(if (and
|
|
(numberp (read (car lines)))
|
|
(numberp (read (cadr lines)))
|
|
(setq n1 (obj-match-second-space-right (nth 0 lines)))
|
|
(setq n2 (obj-match-second-space-right (nth 1 lines))))
|
|
n2
|
|
0))
|
|
((not (obj-match-second-space-left (nth 0 lines)))
|
|
0)
|
|
((and
|
|
(setq n1 (obj-match-second-space-left (nth 1 lines)))
|
|
(setq n2 (obj-match-second-space-left (nth 2 lines)))
|
|
(= n1 n2))
|
|
n1)
|
|
((and
|
|
(setq n1 (obj-match-second-space-right (nth 1 lines)))
|
|
(setq n2 (obj-match-second-space-right (nth 2 lines)))
|
|
(= n1 n2))
|
|
(- n1))
|
|
(t 0))))
|
|
|
|
(defun org-babel-J-print-block (x)
|
|
"Prettify jconsole output X."
|
|
(let* ((x (org-trim x))
|
|
(a (obj-get-string-alignment x))
|
|
(lines (split-string x "\n" t))
|
|
b)
|
|
(cond ((< a 0)
|
|
(setq b (obj-match-second-space-right (nth 0 lines)))
|
|
(concat (make-string (+ a b) ? ) x))
|
|
((> a 0)
|
|
(setq b (obj-match-second-space-left (nth 0 lines)))
|
|
(concat (make-string (- a b) ? ) x))
|
|
(t x))))
|
|
|
|
(defun obj-match-second-space-left (s)
|
|
"Return position of leftmost space in second space block of S or nil."
|
|
(and (string-match "^ *[^ ]+\\( \\)" s)
|
|
(match-beginning 1)))
|
|
|
|
(defun obj-match-second-space-right (s)
|
|
"Return position of rightmost space in second space block of S or nil."
|
|
(and (string-match "^ *[^ ]+ *\\( \\)[^ ]" s)
|
|
(match-beginning 1)))
|
|
|
|
(defun obj-string-match-m (regexp string &optional start)
|
|
"Call (string-match REGEXP STRING START).
|
|
REGEXP is modified so that .* matches newlines as well."
|
|
(string-match
|
|
(replace-regexp-in-string "\\.\\*" "[\0-\377[:nonascii:]]*" regexp)
|
|
string
|
|
start))
|
|
|
|
(defun org-babel-j-initiate-session (&optional session)
|
|
"Initiate a J session.
|
|
SESSION is a parameter given by org-babel."
|
|
(unless (string= session "none")
|
|
(require 'j-console)
|
|
(j-console-ensure-session)))
|
|
|
|
(provide 'ob-J)
|
|
|
|
;;; ob-J.el ends here
|