40 lines
1.2 KiB
EmacsLisp
40 lines
1.2 KiB
EmacsLisp
|
;;; org-man.el - Support for links to manpages in Org-mode
|
||
|
|
|
||
|
|
(require 'org)
|
||
|
|
|
||
|
|
(org-add-link-type "man" 'org-man-open)
|
||
|
|
(add-hook 'org-store-link-functions 'org-man-store-link)
|
||
|
|
|
||
|
|
(defcustom org-man-command 'man
|
||
|
|
"The Emacs command to be used to display a man page."
|
||
|
|
:group 'org-link
|
||
|
|
:type '(choice (const man) (const woman)))
|
||
|
|
|
||
|
|
(defun org-man-open (path)
|
||
|
|
"Visit the manpage on PATH.
|
||
|
|
PATH should be a topic that can be thrown at the man command."
|
||
|
|
(funcall org-man-command path))
|
||
|
|
|
||
|
|
(defun org-man-store-link ()
|
||
|
|
"Store a link to a README file."
|
||
|
|
(when (memq major-mode '(Man-mode woman-mode))
|
||
|
|
;; This is a man page, we do make this link
|
||
|
|
(let* ((page (org-man-get-page-name))
|
||
|
|
(link (concat "man:" page))
|
||
|
|
(description (format "Manpage for %s" page)))
|
||
|
|
(org-store-link-props
|
||
|
|
:type "man"
|
||
|
|
:link link
|
||
|
|
:description description))))
|
||
|
|
|
||
|
|
(defun org-man-get-page-name ()
|
||
|
|
"Extract the page name from the buffer name."
|
||
|
|
;; This works for both `Man-mode' and `woman-mode'.
|
||
|
|
(if (string-match " \\(\\S-+\\)\\*" (buffer-name))
|
||
|
|
(match-string 1 (buffer-name))
|
||
|
|
(error "Cannot create link to this man page")))
|
||
|
|
|
||
|
|
(provide 'org-man)
|
||
|
|
|
||
|
|
;;; org-man.el ends here
|