mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-25 01:02:52 +00:00
Mainly, add the corresponding cookie, but also add various `require`s so that the compiler knows which vars should be trated as dynbound. This does not fix all the warnings, but does try to eliminate all those about "unused" variables. For the variables truly unused, the patch usually adds an underscore to their name to silence the warning. Some of the fixes affect files which already used `lexical-binding`. Not sure why the test worked before: maybe because the tests were run without compiling them first (which could cause some of the missing `require`d packages to be autoloaded before we got to the problematic code, thus hiding the problem)? I found some suspicious code, for which I added FIXMEs. There are also a few changes to the main files. * lisp/org-protocol.el (org-protocol-check-filename-for-protocol): Don't call `server-edit` if it's not yet defined. [ Needed to get the tests to pass. ] * lisp/ob-core.el (org-babel-temporary-directory) (org-babel-temporary-stable-directory): Always define (and use nil if we don't want to create a directory for it). Simplify the code based on the fact that (defvar V E) only evaluates E if V is not yet `boundp`. (org-babel-temp-file, org-babel-temp-stable-file) (org-babel-remove-temporary-directory) (org-babel-remove-temporary-stable-directory): Adjust accordingly. * lisp/org.el (org-log-beginning): Add FIXME. * testing/org-test.el: Require `org` and `org-id`. (org-id-locations-file): Don't `defconst` it. (org-test-at-id, org-test-in-example-file, org-test-at-marker) (org-test-with-temp-text, org-test-with-temp-text-in-file): Move edebug specs into `declare` (and simplify them). (org-test-with-tramp-remote-dir--worker): Declare dynbound tramp vars. (org--compile-when): Fix quoting of `exp`. (org-test-load): Tweak regexps. * testing/org-batch-test-init.el: Tweak regexp, remove dead code and add a FIXME about it. * testing/lisp/test-ox.el: Require `ox` instead of erroring out if it's not already loaded. Also require `org-inlinetask`. (org-test-with-parsed-data): Silence warnings when `info` is not used. (test-org-export/bind-keyword): Add FIXME. * testing/lisp/test-ox-publish.el: Require `org-test` and `ox-publish`. (test-org-publish/resolve-external-link): Expose lambdas to the compiler. Remove unused var `ids`. (test-org-publish/get-project-from-filename): Remove unused var `file`. * testing/lisp/test-org.el: Require `org-macs`, `org`, `org-inlinetask`, `org-refile`, and `org-agenda`. (test-org/org-read-date): Declare `org-time-was-given` as dynbound. (test-org/set-regexps-and-options): Add FIXME. * testing/lisp/test-org-timer.el: Require `org-timer`. * testing/lisp/test-org-table.el: Require `ox`. * testing/lisp/test-org-protocol.el: Require `org-protocol` instead of erroring out if it's not already loaded. Also require `capture`, and add missing `provide` statement. * testing/lisp/test-org-pcomplete.el: Require `org`. * testing/lisp/test-org-list.el: Require `org-list` and `org`. * testing/lisp/test-org-lint.el: Require `org-footnote` and `org-lint`. * testing/lisp/test-org-footnote.el: Require `org-footnote`. * testing/lisp/test-org-element.el: Require `org-element` instead of erroring out if it's not already loaded. Also require `org` and `org-inlinetask`. * testing/lisp/test-org-duration.el: Require `org-duration`. * testing/lisp/test-org-datetree.el: Require `org-datetree`. * testing/lisp/test-org-colview.el: Require `org-colview`, `org-duration`, and `org-inlinetask`. * testing/lisp/test-org-clock.el: Require `org-duration` and `org-clock`. * testing/lisp/test-org-archive.el: Require `org-archive`. * testing/lisp/test-org-agenda.el (test-org-agenda/bulk-custom-arg-func): Add FIXME. * testing/lisp/test-ol.el: Require `ol` and `org-id`. (test-org-link/store-link): Declare `org-store-link-props` and add FIXME. * testing/lisp/test-oc.el (test-org-cite/export-capability): Add FIXME. * testing/lisp/test-ob.el: Require `ob-core`, `org-src`, `ob-ref`, and `org-table`. (test-ob/eval-header-argument): Rename `foo` to `test-ob--foo` and declare it as dynbound. (test-ob/blocks-with-spaces, test-ob/specific-colnames): Add FIXME. (test-ob/noweb-expansions-in-cache): Declare `noweb-expansions-in-cache-var` as dynbound. * testing/lisp/test-ob-tangle.el: Require `org` and `ob-tangle`. * testing/lisp/test-ob-shell.el: * testing/lisp/test-ob-python.el: Require `ob-core`. * testing/lisp/test-ob-lob.el: Require `ob-lob`. (temporary-value-for-test): Declare as dynbound. * testing/lisp/test-ob-plantuml.el: Require `ob-plantuml` instead of erroring out if it's not already loaded. * testing/lisp/test-ob-lilypond.el: Require `ob-lilypond` instead of erroring out if it's not already loaded. Use `with-current-buffer`. * testing/lisp/test-ob-julia.el: Require `ob-core`. * testing/lisp/test-ob-java.el (org-babel-temporary-directory): Remove dead code now that `org-babel-temporary-directory` is always bound. * testing/lisp/test-ob-exp.el: Require `ob-exp`, `org-src`, and `org-test`. (ob-exp/evaluate-all-executables-in-order): Declare `*evaluation-collector*` as dynbound. * testing/lisp/test-ob-emacs-lisp.el (ob-emacs-lisp/dynamic-lexical-edit) (ob-emacs-lisp/dynamic-lexical-execute): Rename dynbound var to `ob-emacs--x` and declare it as such. * testing/lisp/test-ob-R.el: Require `ob-core`. (ess-ask-for-ess-directory, ess-history-file): Declare vars.
183 lines
6.7 KiB
EmacsLisp
183 lines
6.7 KiB
EmacsLisp
;;; test-org-archive.el --- Test for Org Archive -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2017, 2019 Jay Kamat
|
|
|
|
;; Author: Jay Kamat <jaygkamat@gmail.com>
|
|
|
|
;; This program is free software; you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; This program is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Code:
|
|
|
|
(require 'org-archive)
|
|
|
|
(ert-deftest test-org-archive/update-status-cookie ()
|
|
"Test archiving properly updating status cookies."
|
|
;; Test org-archive-subtree with two children.
|
|
(should
|
|
(equal
|
|
"Top [0%]"
|
|
(org-test-with-temp-text-in-file
|
|
"* Top [%]\n** DONE One\n** TODO Two"
|
|
(forward-line)
|
|
(org-archive-subtree)
|
|
(forward-line -1)
|
|
(org-element-property :raw-value (org-element-at-point)))))
|
|
;; Test org-archive-subtree with one child.
|
|
(should
|
|
(equal
|
|
"Top [100%]"
|
|
(org-test-with-temp-text-in-file "* Top [%]\n** TODO Two"
|
|
(forward-line)
|
|
(org-archive-subtree)
|
|
(forward-line -1)
|
|
(org-element-property :raw-value (org-element-at-point)))))
|
|
;; Test org-archive-to-archive-sibling with two children.
|
|
(should
|
|
(equal
|
|
"Top [100%]"
|
|
(org-test-with-temp-text "* Top [%]\n<point>** TODO One\n** DONE Two"
|
|
(org-archive-to-archive-sibling)
|
|
(forward-line -1)
|
|
(org-element-property :raw-value (org-element-at-point)))))
|
|
;; Test org-archive-to-archive-sibling with two children.
|
|
(should
|
|
(equal
|
|
"Top [0%]"
|
|
(org-test-with-temp-text "* Top [%]\n<point>** DONE Two"
|
|
(org-archive-to-archive-sibling)
|
|
(forward-line -1)
|
|
(org-element-property :raw-value (org-element-at-point))))))
|
|
|
|
(ert-deftest test-org-archive/datetree ()
|
|
"Test `org-archive-subtree' with a datetree target."
|
|
(org-test-at-time "<2020-07-05 Sun>"
|
|
;; Test in buffer target with no additional subheadings...
|
|
(should
|
|
(string-match-p
|
|
(regexp-quote (format-time-string "*** 2020-07-05 %A\n**** a"))
|
|
(org-test-with-temp-text-in-file "* a\n"
|
|
(let ((org-archive-location "::datetree/"))
|
|
(org-archive-subtree)
|
|
(buffer-string)))))
|
|
;; ... and with `org-odd-levels-only' non-nil.
|
|
(should
|
|
(string-match-p
|
|
(regexp-quote (format-time-string "***** 2020-07-05 %A\n******* a"))
|
|
(org-test-with-temp-text-in-file "* a\n"
|
|
(let ((org-archive-location "::datetree/")
|
|
(org-odd-levels-only t))
|
|
(org-archive-subtree)
|
|
(buffer-string)))))
|
|
;; Test in buffer target with an additional subheading...
|
|
(should
|
|
(string-match-p
|
|
(regexp-quote (format-time-string "*** 2020-07-05 %A\n**** a\n***** b"))
|
|
(org-test-with-temp-text-in-file "* b\n"
|
|
(let ((org-archive-location "::datetree/* a"))
|
|
(org-archive-subtree)
|
|
(buffer-string)))))
|
|
;; ... and with `org-odd-levels-only' non-nil.
|
|
(should
|
|
(string-match-p
|
|
(regexp-quote (format-time-string "***** 2020-07-05 %A\n******* a\n********* b"))
|
|
(org-test-with-temp-text-in-file "* b\n"
|
|
(let ((org-archive-location "::datetree/* a")
|
|
(org-odd-levels-only t))
|
|
(org-archive-subtree)
|
|
(buffer-string)))))))
|
|
|
|
(ert-deftest test-org-archive/to-archive-sibling ()
|
|
"Test `org-archive-to-archive-sibling' specifications."
|
|
;; Archive sibling before or after archive heading.
|
|
(should
|
|
(equal "* Archive :ARCHIVE:\n** H\n"
|
|
(org-test-with-temp-text "* H\n* Archive :ARCHIVE:\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE"))
|
|
(org-archive-to-archive-sibling)
|
|
(goto-char (point-min))
|
|
(buffer-substring-no-properties
|
|
(point) (line-beginning-position 3))))))
|
|
(should
|
|
(equal "* Archive :ARCHIVE:\n** H\n"
|
|
(org-test-with-temp-text "* Archive :ARCHIVE:\n<point>* H\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE"))
|
|
(org-archive-to-archive-sibling)
|
|
(goto-char (point-min))
|
|
(buffer-substring-no-properties
|
|
(point) (line-beginning-position 3))))))
|
|
;; When there is no sibling archive heading, create it.
|
|
(should
|
|
(equal "* Archive :ARCHIVE:\n** H\n"
|
|
(org-test-with-temp-text "* H\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE")
|
|
(org-tags-column 1))
|
|
(org-archive-to-archive-sibling)
|
|
(goto-char (point-min))
|
|
(buffer-substring-no-properties
|
|
(point) (line-beginning-position 3))))))
|
|
;; Ignore non-sibling archive headings.
|
|
(should
|
|
(equal "* Archive :ARCHIVE:\n* Top\n** Archive :ARCHIVE:\n*** H\n"
|
|
(org-test-with-temp-text "* Archive :ARCHIVE:\n* Top\n<point>** H\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE")
|
|
(org-tags-column 0))
|
|
(org-archive-to-archive-sibling)
|
|
(goto-char (point-min))
|
|
(buffer-substring-no-properties
|
|
(point) (line-beginning-position 5))))))
|
|
;; When archiving a heading, leave point on next heading.
|
|
(should
|
|
(equal "* H2"
|
|
(org-test-with-temp-text "* H1\n* H2\n* Archive :ARCHIVE:\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE"))
|
|
(org-archive-to-archive-sibling)
|
|
(buffer-substring-no-properties (point) (line-end-position))))))
|
|
(should
|
|
(equal "* H2"
|
|
(org-test-with-temp-text "* Archive :ARCHIVE:\n<point>* H1\n* H2\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE"))
|
|
(org-archive-to-archive-sibling)
|
|
(buffer-substring-no-properties (point) (line-end-position))))))
|
|
;; If `org-archive-reversed-order' is nil, archive as the last
|
|
;; child. Otherwise, archive as the first one.
|
|
(should
|
|
(equal "* Archive :ARCHIVE:\n** A\n"
|
|
(org-test-with-temp-text "* H\n* Archive :ARCHIVE:\n** A\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE")
|
|
(org-archive-reversed-order nil))
|
|
(org-archive-to-archive-sibling)
|
|
(goto-char (point-min))
|
|
(buffer-substring-no-properties
|
|
(point) (line-beginning-position 3))))))
|
|
(should
|
|
(equal "* Archive :ARCHIVE:\n** H\n"
|
|
(org-test-with-temp-text "* H\n* Archive :ARCHIVE:\n** A\n"
|
|
(let ((org-archive-sibling-heading "Archive")
|
|
(org-archive-tag "ARCHIVE")
|
|
(org-archive-reversed-order t))
|
|
(org-archive-to-archive-sibling)
|
|
(goto-char (point-min))
|
|
(buffer-substring-no-properties
|
|
(point) (line-beginning-position 3)))))))
|
|
|
|
(provide 'test-org-archive)
|
|
;;; test-org-archive.el ends here
|