mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-21 12:18:36 +00:00
* org-exp.el (org-export-kill-product-buffer-when-displayed) (org-export-initial-scope, org-export-date-timestamp-format) (org-export-with-tasks, org-export-email-info) (org-export-table-remove-empty-lines): Add version tag. * org-mobile.el (org-mobile-files-exclude-regexp) (org-mobile-use-encryption, org-mobile-encryption-tempfile) (org-mobile-encryption-password, org-mobile-agendas): Add version tag. * ob-plantuml.el (org-plantuml-jar-path): Add version tag. * org.el (org-babel-load-languages, org-clone-delete-id) (org-log-buffer-setup-hook) (org-loop-over-headlines-in-active-region) (org-use-sub-superscripts, org-startup-with-beamer-mode) (org-startup-with-inline-images, org-ctrl-k-protect-subtree) (org-catch-invisible-edits) (org-link-search-must-match-exact-headline) (org-confirm-shell-link-not-regexp) (org-confirm-elisp-link-not-regexp, org-log-refile) (org-refile-use-cache) (org-refile-active-region-within-subtree) (org-todo-repeat-to-state, org-get-priority-function) (org-agenda-jump-prefer-future) (org-read-date-force-compatible-dates) (org-use-effective-time) (org-complete-tags-always-offer-all-agenda-tags) (org-properties-postprocess-alist) (org-format-latex-signal-error) (org-latex-to-mathml-jar-file) (org-latex-to-mathml-convert-command) (org-export-latex-default-packages-alist) (org-hidden-keywords, org-pretty-entities) (org-pretty-entities-include-sub-superscripts) (org-src-fontify-natively, org-effort-durations) (org-speed-command-hook): Add version tag. * org-html.el (org-export-html-footnote-separator) (org-export-html-mathjax-options) (org-export-html-mathjax-template) (org-export-html-headline-anchor-format) (org-export-html-preamble-format) (org-export-html-postamble-format) (org-export-html-table-align-individual-fields) (org-export-html-protect-char-alist, org-export-html-divs): Add version tag. * org-ctags.el (org-ctags-path-to-ctags) (org-ctags-open-link-functions) (org-ctags-new-topic-template): Add version tag. * ob-exp.el (org-export-babel-evaluate): Add version tag. * org-beamer.el (org-beamer-use-parts) (org-beamer-frame-level, org-beamer-frame-default-options) (org-beamer-column-view-format, org-beamer-themes) (org-beamer-environments-extra, org-beamer-fragile-re) (org-beamer-outline-frame-title) (org-beamer-outline-frame-options): Add version tag. * org-wl.el (org-wl-link-remove-filter) (org-wl-shimbun-prefer-web-links) (org-wl-nntp-prefer-web-links, org-wl-disable-folder-check) (org-wl-namazu-default-index): Add version tag. * org-clock.el (org-task-overrun-text) (org-clocktable-defaults, org-clock-clocktable-formatter) (org-clock-clocktable-language-setup) (org-clock-report-include-clocking-task) (org-clock-resolve-expert): Add version tag. * ob-lob.el (org-babel-lob-files): Add version tag. * org-freemind.el (org-freemind-node-css-style): Add version tag. * org-archive.el (org-archive-reversed-order) (org-archive-subtree-add-inherited-tags): Add version tag. * org-bibtex.el (org-bibtex-autogen-keys, org-bibtex-prefix) (org-bibtex-treat-headline-as-title) (org-bibtex-export-arbitrary-fields) (org-bibtex-key-property, org-bibtex-tags) (org-bibtex-tags-are-keywords, org-bibtex-no-export-tags) (org-bibtex-type-property-name): Add version tag. * org-timer.el (org-timer-default-timer): Add version tag. * org-taskjuggler.el (org-export-taskjuggler-extension) (org-export-taskjuggler-project-tag) (org-export-taskjuggler-resource-tag) (org-export-taskjuggler-target-version) (org-export-taskjuggler-default-project-version) (org-export-taskjuggler-default-project-duration) (org-export-taskjuggler-default-reports) (org-export-taskjuggler-default-global-properties): Add version tag. * org-habit.el (org-habit-today-glyph) (org-habit-completed-glyph): Add version tag. * org-list.el (org-alphabetical-lists) (org-list-ending-method, org-list-end-regexp) (org-list-automatic-rules, org-list-use-circular-motion) (org-list-indent-offset): Add version tag. * ob-picolisp.el (org-babel-picolisp-cmd): Add version tag. * org-icalendar.el (org-icalendar-alarm-time) (org-icalendar-combined-description) (org-icalendar-honor-noexport-tag) (org-icalendar-date-time-format): Add version tag. * org-src.el (org-src-tab-acts-natively): Add version tag. * org-exp-blocks.el (org-export-blocks-postblock-hook): Add version tag. * org-table.el (org-table-exit-follow-field-mode-when-leaving-table) (org-table-fix-formulas-confirm) (org-table-duration-custom-format) (org-table-formula-field-format): Add version tag. * org-publish.el (org-publish-sitemap-sort-files) (org-publish-sitemap-sort-folders) (org-publish-sitemap-sort-ignore-case) (org-publish-sitemap-date-format) (org-publish-sitemap-file-entry-format): Add version tag. * ob-js.el (org-babel-js-cmd): Add version tag. * org-docbook.el (org-export-docbook-footnote-separator) (org-export-docbook-xslt-stylesheet): Add version tag. * org-entities.el (org-entities-ascii-explanatory) (org-entities-user): Add version tag. * ob.el (org-confirm-babel-evaluate) (org-babel-no-eval-on-ctrl-c-ctrl-c): Add version tag. * ob-tangle.el (org-babel-tangle-lang-exts) (org-babel-post-tangle-hook, org-babel-pre-tangle-hook) (org-babel-tangle-body-hook) (org-babel-tangle-comment-format-beg) (org-babel-tangle-comment-format-end) (org-babel-process-comment-text): Add version tag. * org-gnus.el (org-gnus-nnimap-query-article-no-from-file): Add version tag. * org-crypt.el (org-crypt-disable-auto-save): Add version tag. * org-inlinetask.el (org-inlinetask-default-state): Add version tag. * ob-scheme.el (org-babel-scheme-cmd): Add version tag. * ob-lisp.el (org-babel-lisp-dir-fmt): Add version tag. * org-attach.el (org-attach-store-link-p): Add version tag. * org-capture.el (org-capture-templates) (org-capture-before-finalize-hook) (org-capture-after-finalize-hook): Add version tag. * org-agenda.el (org-agenda-skip-deadline-prewarning-if-scheduled) (org-agenda-time-leading-zero, org-agenda-follow-indirect) (org-agenda-menu-two-column, org-agenda-menu-show-matcher) (org-agenda-timegrid-use-ampm) (org-agenda-remove-timeranges-from-blocks) (org-agenda-inactive-leader, org-agenda-current-time-string) (org-agenda-show-current-time-in-grid) (org-agenda-search-view-force-full-words) (org-agenda-search-view-always-boolean) (org-agenda-clock-consistency-checks) (org-agenda-include-deadlines) (org-agenda-move-date-from-past-immediately-to-today) (org-agenda-day-face-function) (org-agenda-category-icon-alist) (org-agenda-bulk-custom-functions) (org-agenda-insert-diary-extract-time): Add version tag. * org-latex.el (org-export-latex-inputenc-alist) (org-export-latex-tag-markup) (org-export-latex-timestamp-inactive-markup) (org-export-latex-href-format) (org-export-latex-hyperref-format) (org-export-latex-footnote-separator) (org-export-latex-quotes) (org-export-latex-table-caption-above) (org-export-latex-listings-w-names) (org-export-latex-minted-langs) (org-export-latex-listings-options) (org-export-latex-minted-options) (org-latex-default-figure-position, org-export-pdf-logfiles): Add version tag. * org-faces.el (org-faces-easy-properties) (org-fontify-quote-and-verse-blocks, org-cycle-level-faces): Add version tag. * ob-ditaa.el (org-ditaa-jar-option): Add version tag. Thanks to Glenn Morris for reporting this.
164 lines
5.7 KiB
EmacsLisp
164 lines
5.7 KiB
EmacsLisp
;;; ob-js.el --- org-babel functions for Javascript
|
|
|
|
;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research, js
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Now working with SBCL for both session and external evaluation.
|
|
;;
|
|
;; This certainly isn't optimally robust, but it seems to be working
|
|
;; for the basic use cases.
|
|
|
|
;;; Requirements:
|
|
|
|
;; - a non-browser javascript engine such as node.js http://nodejs.org/
|
|
;; or mozrepl http://wiki.github.com/bard/mozrepl/
|
|
;;
|
|
;; - for session based evaluation mozrepl and moz.el are required see
|
|
;; http://wiki.github.com/bard/mozrepl/emacs-integration for
|
|
;; configuration instructions
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'ob-ref)
|
|
(require 'ob-comint)
|
|
(require 'ob-eval)
|
|
(eval-when-compile (require 'cl))
|
|
|
|
(declare-function run-mozilla "ext:moz" (arg))
|
|
|
|
(defvar org-babel-default-header-args:js '()
|
|
"Default header arguments for js code blocks.")
|
|
|
|
(defvar org-babel-js-eoe "org-babel-js-eoe"
|
|
"String to indicate that evaluation has completed.")
|
|
|
|
(defcustom org-babel-js-cmd "node"
|
|
"Name of command used to evaluate js blocks."
|
|
:group 'org-babel
|
|
:version "24.1"
|
|
:type 'string)
|
|
|
|
(defvar org-babel-js-function-wrapper
|
|
"require('sys').print(require('sys').inspect(function(){%s}()));"
|
|
"Javascript code to print value of body.")
|
|
|
|
(defun org-babel-execute:js (body params)
|
|
"Execute a block of Javascript code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'"
|
|
(let* ((org-babel-js-cmd (or (cdr (assoc :cmd params)) org-babel-js-cmd))
|
|
(result-type (cdr (assoc :result-type params)))
|
|
(full-body (org-babel-expand-body:generic
|
|
body params (org-babel-variable-assignments:js params))))
|
|
(org-babel-js-read
|
|
(if (not (string= (cdr (assoc :session params)) "none"))
|
|
;; session evaluation
|
|
(let ((session (org-babel-prep-session:js
|
|
(cdr (assoc :session params)) params)))
|
|
(nth 1
|
|
(org-babel-comint-with-output
|
|
(session (format "%S" org-babel-js-eoe) t body)
|
|
(mapc
|
|
(lambda (line)
|
|
(insert (org-babel-chomp line)) (comint-send-input nil t))
|
|
(list body (format "%S" org-babel-js-eoe))))))
|
|
;; external evaluation
|
|
(let ((script-file (org-babel-temp-file "js-script-")))
|
|
(with-temp-file script-file
|
|
(insert
|
|
;; return the value or the output
|
|
(if (string= result-type "value")
|
|
(format org-babel-js-function-wrapper full-body)
|
|
full-body)))
|
|
(org-babel-eval
|
|
(format "%s %s" org-babel-js-cmd
|
|
(org-babel-process-file-name script-file)) ""))))))
|
|
|
|
(defun org-babel-js-read (results)
|
|
"Convert RESULTS into an appropriate elisp value.
|
|
If RESULTS look like a table, then convert them into an
|
|
Emacs-lisp table, otherwise return the results as a string."
|
|
(org-babel-read
|
|
(if (and (stringp results) (string-match "^\\[.+\\]$" results))
|
|
(org-babel-read
|
|
(concat "'"
|
|
(replace-regexp-in-string
|
|
"\\[" "(" (replace-regexp-in-string
|
|
"\\]" ")" (replace-regexp-in-string
|
|
", " " " (replace-regexp-in-string
|
|
"'" "\"" results))))))
|
|
results)))
|
|
|
|
(defun org-babel-js-var-to-js (var)
|
|
"Convert VAR into a js variable.
|
|
Convert an elisp value into a string of js source code
|
|
specifying a variable of the same value."
|
|
(if (listp var)
|
|
(concat "[" (mapconcat #'org-babel-js-var-to-js var ", ") "]")
|
|
(format "%S" var)))
|
|
|
|
(defun org-babel-prep-session:js (session params)
|
|
"Prepare SESSION according to the header arguments specified in PARAMS."
|
|
(let* ((session (org-babel-js-initiate-session session))
|
|
(var-lines (org-babel-variable-assignments:js params)))
|
|
(when session
|
|
(org-babel-comint-in-buffer session
|
|
(sit-for .5) (goto-char (point-max))
|
|
(mapc (lambda (var)
|
|
(insert var) (comint-send-input nil t)
|
|
(org-babel-comint-wait-for-output session)
|
|
(sit-for .1) (goto-char (point-max))) var-lines)))
|
|
session))
|
|
|
|
(defun org-babel-variable-assignments:js (params)
|
|
"Return list of Javascript statements assigning the block's variables"
|
|
(mapcar
|
|
(lambda (pair) (format "var %s=%s;"
|
|
(car pair) (org-babel-js-var-to-js (cdr pair))))
|
|
(mapcar #'cdr (org-babel-get-header params :var))))
|
|
|
|
(defun org-babel-js-initiate-session (&optional session)
|
|
"If there is not a current inferior-process-buffer in SESSION
|
|
then create. Return the initialized session."
|
|
(unless (string= session "none")
|
|
(cond
|
|
((string= "mozrepl" org-babel-js-cmd)
|
|
(require 'moz)
|
|
(let ((session-buffer (save-window-excursion
|
|
(run-mozilla nil)
|
|
(rename-buffer session)
|
|
(current-buffer))))
|
|
(if (org-babel-comint-buffer-livep session-buffer)
|
|
(progn (sit-for .25) session-buffer)
|
|
(sit-for .5)
|
|
(org-babel-js-initiate-session session))))
|
|
((string= "node" org-babel-js-cmd )
|
|
(error "session evaluation with node.js is not supported"))
|
|
(t
|
|
(error "sessions are only supported with mozrepl add \":cmd mozrepl\"")))))
|
|
|
|
(provide 'ob-js)
|
|
|
|
|
|
|
|
;;; ob-js.el ends here
|