mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-22 12:18:40 +00:00
* lisp/ob-core.el (org-babel--get-vars): New function. (org-babel-get-header): Delete. * lisp/ob-C.el (org-babel-C-expand-C): (org-babel-C-expand-D): * lisp/ob-R.el (org-babel-variable-assignments:R): * lisp/ob-abc.el (org-babel-expand-body:abc): * lisp/ob-asymptote.el (org-babel-variable-assignments:asymptote): * lisp/ob-awk.el (org-babel-execute:awk): * lisp/ob-calc.el (org-babel-execute:calc): * lisp/ob-clojure.el (org-babel-expand-body:clojure): * lisp/ob-dot.el (org-babel-expand-body:dot): * lisp/ob-emacs-lisp.el (org-babel-expand-body:emacs-lisp): * lisp/ob-fortran.el (org-babel-expand-body:fortran): (org-babel-fortran-ensure-main-wrap): * lisp/ob-gnuplot.el (org-babel-gnuplot-process-vars): * lisp/ob-haskell.el (org-babel-variable-assignments:haskell): * lisp/ob-js.el (org-babel-variable-assignments:js): * lisp/ob-latex.el (org-babel-expand-body:latex): * lisp/ob-lilypond.el (org-babel-expand-body:lilypond): * lisp/ob-lisp.el (org-babel-expand-body:lisp): * lisp/ob-maxima.el (org-babel-maxima-expand): * lisp/ob-ocaml.el (org-babel-variable-assignments:ocaml): * lisp/ob-octave.el (org-babel-variable-assignments:octave): * lisp/ob-org.el (org-babel-expand-body:org): * lisp/ob-perl.el (org-babel-variable-assignments:perl): * lisp/ob-picolisp.el (org-babel-expand-body:picolisp): * lisp/ob-processing.el (org-babel-variable-assignments:processing): * lisp/ob-python.el (org-babel-variable-assignments:python): * lisp/ob-ruby.el (org-babel-variable-assignments:ruby): * lisp/ob-scheme.el (org-babel-expand-body:scheme): * lisp/ob-shell.el (org-babel-variable-assignments:shell): * lisp/ob-shen.el (org-babel-expand-body:shen): * lisp/ob-sql.el (org-babel-expand-body:sql): * lisp/ob-sqlite.el (org-babel-expand-body:sqlite): Adapt to change. * etc/ORG-NEWS: Document change.
91 lines
2.8 KiB
EmacsLisp
91 lines
2.8 KiB
EmacsLisp
;;; ob-dot.el --- Babel Functions for dot -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating dot source code.
|
|
;;
|
|
;; For information on dot see http://www.graphviz.org/
|
|
;;
|
|
;; This differs from most standard languages in that
|
|
;;
|
|
;; 1) there is no such thing as a "session" in dot
|
|
;;
|
|
;; 2) we are generally only going to return results of type "file"
|
|
;;
|
|
;; 3) we are adding the "file" and "cmdline" header arguments
|
|
;;
|
|
;; 4) there are no variables (at least for now)
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(defvar org-babel-default-header-args:dot
|
|
'((:results . "file") (:exports . "results"))
|
|
"Default arguments to use when evaluating a dot source block.")
|
|
|
|
(defun org-babel-expand-body:dot (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let ((vars (org-babel--get-vars params)))
|
|
(mapc
|
|
(lambda (pair)
|
|
(let ((name (symbol-name (car pair)))
|
|
(value (cdr pair)))
|
|
(setq body
|
|
(replace-regexp-in-string
|
|
(concat "$" (regexp-quote name))
|
|
(if (stringp value) value (format "%S" value))
|
|
body
|
|
t
|
|
t))))
|
|
vars)
|
|
body))
|
|
|
|
(defun org-babel-execute:dot (body params)
|
|
"Execute a block of Dot code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(let* ((out-file (cdr (or (assoc :file params)
|
|
(error "You need to specify a :file parameter"))))
|
|
(cmdline (or (cdr (assoc :cmdline params))
|
|
(format "-T%s" (file-name-extension out-file))))
|
|
(cmd (or (cdr (assoc :cmd params)) "dot"))
|
|
(in-file (org-babel-temp-file "dot-")))
|
|
(with-temp-file in-file
|
|
(insert (org-babel-expand-body:dot body params)))
|
|
(org-babel-eval
|
|
(concat cmd
|
|
" " (org-babel-process-file-name in-file)
|
|
" " cmdline
|
|
" -o " (org-babel-process-file-name out-file)) "")
|
|
nil)) ;; signal that output has already been written to file
|
|
|
|
(defun org-babel-prep-session:dot (_session _params)
|
|
"Return an error because Dot does not support sessions."
|
|
(error "Dot does not support sessions"))
|
|
|
|
(provide 'ob-dot)
|
|
|
|
|
|
|
|
;;; ob-dot.el ends here
|