mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-09-13 03:40:06 +00:00
f0bf77e82a
* lisp/ob-C.el (org-babel-prep-session:C): (org-babel-load-session:C): * lisp/ob-J.el: (org-babel-expand-body:J): (org-babel-execute:J): * lisp/ob-R.el: (org-babel-expand-body:R): * lisp/ob-abc.el: (org-babel-execute:abc): (org-babel-prep-session:abc): * lisp/ob-asymptote.el: (org-babel-execute:asymptote): (org-babel-prep-session:asymptote): * lisp/ob-awk.el: (org-babel-expand-body:awk): * lisp/ob-calc.el: (org-babel-expand-body:calc): * lisp/ob-clojure.el: * lisp/ob-comint.el: (org-babel-comint-in-buffer): (org-babel-comint-with-output): (org-babel-comint-eval-invisibly-and-wait-for-file): * lisp/ob-coq.el: * lisp/ob-css.el: (org-babel-execute:css): (org-babel-prep-session:css): * lisp/ob-ditaa.el: (org-babel-execute:ditaa): (org-babel-prep-session:ditaa): * lisp/ob-dot.el: (org-babel-execute:dot): (org-babel-prep-session:dot): * lisp/ob-ebnf.el: * lisp/ob-emacs-lisp.el: * lisp/ob-eval.el: * lisp/ob-forth.el: * lisp/ob-fortran.el: (org-babel-execute:fortran): (org-babel-prep-session:fortran): (org-babel-load-session:fortran): * lisp/ob-gnuplot.el: (org-babel-expand-body:gnuplot): (org-babel-prep-session:gnuplot): (org-babel-gnuplot-initiate-session): * lisp/ob-groovy.el: (org-babel-prep-session:groovy): (org-babel-groovy-initiate-session): * lisp/ob-haskell.el: (org-babel-haskell-initiate-session): * lisp/ob-io.el: (org-babel-prep-session:io): (org-babel-io-initiate-session): * lisp/ob-java.el: (org-babel-execute:java): * lisp/ob-js.el: * lisp/ob-keys.el: * lisp/ob-latex.el: (org-babel-prep-session:latex): * lisp/ob-ledger.el: (org-babel-execute:ledger): (org-babel-prep-session:ledger): * lisp/ob-lilypond.el: (org-babel-lilypond-commands): (org-babel-lilypond-process-basic): (org-babel-prep-session:lilypond): (org-babel-lilypond-parse-line-num): * lisp/ob-lisp.el: * lisp/ob-makefile.el: (org-babel-execute:makefile): (org-babel-prep-session:makefile): * lisp/ob-matlab.el: * lisp/ob-maxima.el: (org-babel-prep-session:maxima): * lisp/ob-mscgen.el: (org-babel-prep-session:mscgen): * lisp/ob-ocaml.el: (org-babel-execute:ocaml): (org-babel-prep-session:ocaml): * lisp/ob-octave.el: (org-babel-execute:octave): (org-babel-octave-initiate-session): * lisp/ob-org.el: (org-babel-prep-session:org): * lisp/ob-perl.el: (org-babel-prep-session:perl): (org-babel-perl--var-to-perl): (org-babel-perl-initiate-session): * lisp/ob-picolisp.el: (org-babel-expand-body:picolisp): (org-babel-execute:picolisp): * lisp/ob-plantuml.el: (org-babel-execute:plantuml): (org-babel-prep-session:plantuml): * lisp/ob-processing.el: (org-babel-prep-session:processing): * lisp/ob-python.el: (org-babel-python-initiate-session): * lisp/ob-ref.el: (org-babel-ref-resolve): * lisp/ob-ruby.el: (org-babel-ruby-initiate-session): * lisp/ob-sass.el: (org-babel-execute:sass): (org-babel-prep-session:sass): * lisp/ob-scala.el: (org-babel-execute:scala): (org-babel-prep-session:scala): (org-babel-scala-initiate-session): * lisp/ob-scheme.el: * lisp/ob-screen.el: (org-babel-prep-session:screen): (org-babel-screen-session-write-temp-file): (org-babel-screen-test): * lisp/ob.el: * lisp/org-colview.el: (org-columns-todo): (org-columns-set-tags-or-toggle): (org-columns-new): (org-columns-uncompile-format): (org-agenda-colview-summarize): * lisp/org-footnote.el: (electric-indent-mode): * lisp/org-indent.el: (org-indent-refresh-maybe): * lisp/org-list.el: * lisp/org-macro.el: (org-macro--collect-macros): * lisp/org-src.el: * lisp/org-table.el: (sort-fold-case): (org-table-create): (org-table-field-info): (org-table-transpose-table-at-point): (org-table-remove-rectangle-highlight): (orgtbl-create-or-convert-from-region): (org-define-lookup-function): * lisp/ox-ascii.el: (org-ascii-format-drawer-function): (org-ascii--has-caption-p): (org-ascii-bold): (org-ascii-center-block): (org-ascii-clock): (org-ascii-code): (org-ascii-dynamic-block): (org-ascii-entity): (org-ascii-example-block): (org-ascii-export-snippet): (org-ascii-export-block): (org-ascii-fixed-width): (org-ascii-footnote-reference): (org-ascii-horizontal-rule): (org-ascii-inline-src-block): (org-ascii-format-inlinetask-default): (org-ascii-italic): (org-ascii-keyword): (org-ascii-latex-environment): (org-ascii-latex-fragment): (org-ascii-line-break): (org-ascii-node-property): (org-ascii-planning): (org-ascii-quote-block): (org-ascii-radio-target): (org-ascii-special-block): (org-ascii-src-block): (org-ascii-statistics-cookie): (org-ascii-subscript): (org-ascii-superscript): (org-ascii-strike-through): (org-ascii-timestamp): (org-ascii-underline): (org-ascii-verbatim): (org-ascii-verse-block): (org-ascii-filter-headline-blank-lines): (org-ascii-filter-paragraph-spacing): (org-ascii-filter-comment-spacing): Use lexical binding.
208 lines
7.5 KiB
EmacsLisp
208 lines
7.5 KiB
EmacsLisp
;;; ob-scheme.el --- Babel Functions for Scheme -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2010-2015 Free Software Foundation, Inc.
|
|
|
|
;; Authors: Eric Schulte
|
|
;; Michael Gauland
|
|
;; Keywords: literate programming, reproducible research, scheme
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Now working with SBCL for both session and external evaluation.
|
|
;;
|
|
;; This certainly isn't optimally robust, but it seems to be working
|
|
;; for the basic use cases.
|
|
|
|
;;; Requirements:
|
|
|
|
;; - a working scheme implementation
|
|
;; (e.g. guile http://www.gnu.org/software/guile/guile.html)
|
|
;;
|
|
;; - for session based evaluation geiser is required, which is available from
|
|
;; ELPA.
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'geiser nil t)
|
|
(defvar geiser-repl--repl) ; Defined in geiser-repl.el
|
|
(defvar geiser-impl--implementation) ; Defined in geiser-impl.el
|
|
(defvar geiser-default-implementation) ; Defined in geiser-impl.el
|
|
(defvar geiser-active-implementations) ; Defined in geiser-impl.el
|
|
|
|
(declare-function run-geiser "geiser-repl" (impl))
|
|
(declare-function geiser-mode "geiser-mode" ())
|
|
(declare-function geiser-eval-region "geiser-mode" (start end &optional and-go raw nomsg))
|
|
(declare-function geiser-repl-exit "geiser-repl" (&optional arg))
|
|
|
|
(defvar org-babel-default-header-args:scheme '()
|
|
"Default header arguments for scheme code blocks.")
|
|
|
|
(defun org-babel-expand-body:scheme (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
|
|
(if (> (length vars) 0)
|
|
(concat "(let ("
|
|
(mapconcat
|
|
(lambda (var) (format "%S" (print `(,(car var) ',(cdr var)))))
|
|
vars "\n ")
|
|
")\n" body ")")
|
|
body)))
|
|
|
|
|
|
(defvar org-babel-scheme-repl-map (make-hash-table :test 'equal)
|
|
"Map of scheme sessions to session names.")
|
|
|
|
(defun org-babel-scheme-cleanse-repl-map ()
|
|
"Remove dead buffers from the REPL map."
|
|
(maphash
|
|
(lambda (x y)
|
|
(when (not (buffer-name y))
|
|
(remhash x org-babel-scheme-repl-map)))
|
|
org-babel-scheme-repl-map))
|
|
|
|
(defun org-babel-scheme-get-session-buffer (session-name)
|
|
"Look up the scheme buffer for a session; return nil if it doesn't exist."
|
|
(org-babel-scheme-cleanse-repl-map) ; Prune dead sessions
|
|
(gethash session-name org-babel-scheme-repl-map))
|
|
|
|
(defun org-babel-scheme-set-session-buffer (session-name buffer)
|
|
"Record the scheme buffer used for a given session."
|
|
(puthash session-name buffer org-babel-scheme-repl-map))
|
|
|
|
(defun org-babel-scheme-get-buffer-impl (buffer)
|
|
"Returns the scheme implementation geiser associates with the buffer."
|
|
(with-current-buffer (set-buffer buffer)
|
|
geiser-impl--implementation))
|
|
|
|
(defun org-babel-scheme-get-repl (impl name)
|
|
"Switch to a scheme REPL, creating it if it doesn't exist:"
|
|
(let ((buffer (org-babel-scheme-get-session-buffer name)))
|
|
(or buffer
|
|
(progn
|
|
(run-geiser impl)
|
|
(if name
|
|
(progn
|
|
(rename-buffer name t)
|
|
(org-babel-scheme-set-session-buffer name (current-buffer))))
|
|
(current-buffer)))))
|
|
|
|
(defun org-babel-scheme-make-session-name (buffer name impl)
|
|
"Generate a name for the session buffer.
|
|
|
|
For a named session, the buffer name will be the session name.
|
|
|
|
If the session is unnamed (nil), generate a name.
|
|
|
|
If the session is `none', use nil for the session name, and
|
|
org-babel-scheme-execute-with-geiser will use a temporary session."
|
|
(let ((result
|
|
(cond ((not name)
|
|
(concat buffer " " (symbol-name impl) " REPL"))
|
|
((string= name "none") nil)
|
|
(name))))
|
|
result))
|
|
|
|
(defmacro org-babel-scheme-capture-current-message (&rest body)
|
|
"Capture current message in both interactive and noninteractive mode"
|
|
`(if noninteractive
|
|
(let ((original-message (symbol-function 'message))
|
|
(current-message nil))
|
|
(unwind-protect
|
|
(progn
|
|
(defun message (&rest args)
|
|
(setq current-message (apply original-message args)))
|
|
,@body
|
|
current-message)
|
|
(fset 'message original-message)))
|
|
(progn
|
|
,@body
|
|
(current-message))))
|
|
|
|
(defun org-babel-scheme-execute-with-geiser (code output impl repl)
|
|
"Execute code in specified REPL. If the REPL doesn't exist, create it
|
|
using the given scheme implementation.
|
|
|
|
Returns the output of executing the code if the output parameter
|
|
is true; otherwise returns the last value."
|
|
(let ((result nil))
|
|
(with-temp-buffer
|
|
(insert (format ";; -*- geiser-scheme-implementation: %s -*-" impl))
|
|
(newline)
|
|
(insert (if output
|
|
(format "(with-output-to-string (lambda () %s))" code)
|
|
code))
|
|
(geiser-mode)
|
|
(let ((repl-buffer (save-current-buffer
|
|
(org-babel-scheme-get-repl impl repl))))
|
|
(when (not (eq impl (org-babel-scheme-get-buffer-impl
|
|
(current-buffer))))
|
|
(message "Implementation mismatch: %s (%s) %s (%s)" impl (symbolp impl)
|
|
(org-babel-scheme-get-buffer-impl (current-buffer))
|
|
(symbolp (org-babel-scheme-get-buffer-impl
|
|
(current-buffer)))))
|
|
(setq geiser-repl--repl repl-buffer)
|
|
(setq geiser-impl--implementation nil)
|
|
(setq result (org-babel-scheme-capture-current-message
|
|
(geiser-eval-region (point-min) (point-max))))
|
|
(setq result
|
|
(if (and (stringp result) (equal (substring result 0 3) "=> "))
|
|
(replace-regexp-in-string "^=> " "" result)
|
|
"\"An error occurred.\""))
|
|
(when (not repl)
|
|
(save-current-buffer (set-buffer repl-buffer)
|
|
(geiser-repl-exit))
|
|
(set-process-query-on-exit-flag (get-buffer-process repl-buffer) nil)
|
|
(kill-buffer repl-buffer))
|
|
(setq result (if (or (string= result "#<void>")
|
|
(string= result "#<unspecified>"))
|
|
nil
|
|
(read result)))))
|
|
result))
|
|
|
|
(defun org-babel-execute:scheme (body params)
|
|
"Execute a block of Scheme code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'"
|
|
(let* ((source-buffer (current-buffer))
|
|
(source-buffer-name (replace-regexp-in-string ;; zap surrounding *
|
|
"^ ?\\*\\([^*]+\\)\\*" "\\1"
|
|
(buffer-name source-buffer))))
|
|
(save-excursion
|
|
(org-babel-reassemble-table
|
|
(let* ((result-type (cdr (assoc :result-type params)))
|
|
(impl (or (when (cdr (assoc :scheme params))
|
|
(intern (cdr (assoc :scheme params))))
|
|
geiser-default-implementation
|
|
(car geiser-active-implementations)))
|
|
(session (org-babel-scheme-make-session-name
|
|
source-buffer-name (cdr (assoc :session params)) impl))
|
|
(full-body (org-babel-expand-body:scheme body params)))
|
|
(org-babel-scheme-execute-with-geiser
|
|
full-body ; code
|
|
(string= result-type "output") ; output?
|
|
impl ; implementation
|
|
(and (not (string= session "none")) session))) ; session
|
|
(org-babel-pick-name (cdr (assoc :colname-names params))
|
|
(cdr (assoc :colnames params)))
|
|
(org-babel-pick-name (cdr (assoc :rowname-names params))
|
|
(cdr (assoc :rownames params)))))))
|
|
|
|
(provide 'ob-scheme)
|
|
|
|
;;; ob-scheme.el ends here
|