mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-09-30 15:07:48 +00:00
6a1f6ee1f8
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
157 lines
5.1 KiB
EmacsLisp
157 lines
5.1 KiB
EmacsLisp
;;; ob-sqlite.el --- Babel Functions for SQLite Databases -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2010-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating sqlite source code.
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(declare-function org-table-convert-region "org-table"
|
|
(beg0 end0 &optional separator))
|
|
(declare-function orgtbl-to-csv "org-table" (table params))
|
|
(declare-function org-table-to-lisp "org-table" (&optional txt))
|
|
|
|
(defvar org-babel-default-header-args:sqlite '())
|
|
|
|
(defvar org-babel-header-args:sqlite
|
|
'((db . :any)
|
|
(header . :any)
|
|
(echo . :any)
|
|
(bail . :any)
|
|
(csv . :any)
|
|
(column . :any)
|
|
(html . :any)
|
|
(line . :any)
|
|
(list . :any)
|
|
(separator . :any)
|
|
(nullvalue . :any))
|
|
"Sqlite specific header args.")
|
|
|
|
(defun org-babel-expand-body:sqlite (body params)
|
|
"Expand BODY according to the values of PARAMS."
|
|
(org-babel-sqlite-expand-vars
|
|
body (org-babel--get-vars params)))
|
|
|
|
(defvar org-babel-sqlite3-command "sqlite3")
|
|
|
|
(defun org-babel-execute:sqlite (body params)
|
|
"Execute a block of Sqlite code with Babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(let ((result-params (split-string (or (cdr (assq :results params)) "")))
|
|
(db (cdr (assq :db params)))
|
|
(separator (cdr (assq :separator params)))
|
|
(nullvalue (cdr (assq :nullvalue params)))
|
|
(headers-p (equal "yes" (cdr (assq :colnames params))))
|
|
(others (delq nil (mapcar
|
|
(lambda (arg) (car (assq arg params)))
|
|
(list :header :echo :bail :column
|
|
:csv :html :line :list)))))
|
|
(unless db (error "ob-sqlite: can't evaluate without a database"))
|
|
(with-temp-buffer
|
|
(insert
|
|
(org-babel-eval
|
|
(org-fill-template
|
|
"%cmd %header %separator %nullvalue %others %csv %db "
|
|
(list
|
|
(cons "cmd" org-babel-sqlite3-command)
|
|
(cons "header" (if headers-p "-header" "-noheader"))
|
|
(cons "separator"
|
|
(if separator (format "-separator %s" separator) ""))
|
|
(cons "nullvalue"
|
|
(if nullvalue (format "-nullvalue %s" nullvalue) ""))
|
|
(cons "others"
|
|
(mapconcat
|
|
(lambda (arg) (format "-%s" (substring (symbol-name arg) 1)))
|
|
others " "))
|
|
;; for easy table parsing, default header type should be -csv
|
|
(cons "csv" (if (or (member :csv others) (member :column others)
|
|
(member :line others) (member :list others)
|
|
(member :html others) separator)
|
|
""
|
|
"-csv"))
|
|
(cons "db " db)))
|
|
;; body of the code block
|
|
(org-babel-expand-body:sqlite body params)))
|
|
(org-babel-result-cond result-params
|
|
(buffer-string)
|
|
(if (equal (point-min) (point-max))
|
|
""
|
|
(org-table-convert-region (point-min) (point-max)
|
|
(if (or (member :csv others)
|
|
(member :column others)
|
|
(member :line others)
|
|
(member :list others)
|
|
(member :html others) separator)
|
|
nil
|
|
'(4)))
|
|
(org-babel-sqlite-table-or-scalar
|
|
(org-babel-sqlite-offset-colnames
|
|
(org-table-to-lisp) headers-p)))))))
|
|
|
|
(defun org-babel-sqlite-expand-vars (body vars)
|
|
"Expand the variables held in VARS in BODY."
|
|
;; FIXME: Redundancy with org-babel-sql-expand-vars!
|
|
(mapc
|
|
(lambda (pair)
|
|
(setq body
|
|
(replace-regexp-in-string
|
|
(format "$%s" (car pair))
|
|
(let ((val (cdr pair)))
|
|
(if (listp val)
|
|
(let ((data-file (org-babel-temp-file "sqlite-data-")))
|
|
(with-temp-file data-file
|
|
(insert (orgtbl-to-csv val nil)))
|
|
data-file)
|
|
(if (stringp val) val (format "%S" val))))
|
|
body)))
|
|
vars)
|
|
body)
|
|
|
|
(defun org-babel-sqlite-table-or-scalar (result)
|
|
"If RESULT looks like a trivial table, then unwrap it."
|
|
(if (and (equal 1 (length result))
|
|
(equal 1 (length (car result))))
|
|
(org-babel-read (caar result))
|
|
(mapcar (lambda (row)
|
|
(if (eq 'hline row)
|
|
'hline
|
|
(mapcar #'org-babel-string-read row)))
|
|
result)))
|
|
|
|
(defun org-babel-sqlite-offset-colnames (table headers-p)
|
|
"If HEADERS-P is non-nil then offset the first row as column names."
|
|
(if headers-p
|
|
(cons (car table) (cons 'hline (cdr table)))
|
|
table))
|
|
|
|
(defun org-babel-prep-session:sqlite (_session _params)
|
|
"Raise an error because support for SQLite sessions isn't implemented.
|
|
Prepare SESSION according to the header arguments specified in PARAMS."
|
|
(error "SQLite sessions not yet implemented"))
|
|
|
|
(provide 'ob-sqlite)
|
|
|
|
;;; ob-sqlite.el ends here
|