mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-07-16 09:46:27 +00:00
6a1f6ee1f8
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
123 lines
4 KiB
EmacsLisp
123 lines
4 KiB
EmacsLisp
;;; ob-ditaa.el --- Babel Functions for ditaa -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating ditaa source code.
|
|
;;
|
|
;; This differs from most standard languages in that
|
|
;;
|
|
;; 1) there is no such thing as a "session" in ditaa
|
|
;;
|
|
;; 2) we are generally only going to return results of type "file"
|
|
;;
|
|
;; 3) we are adding the "file" and "cmdline" header arguments
|
|
;;
|
|
;; 4) there are no variables (at least for now)
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'org-compat)
|
|
|
|
(defvar org-babel-default-header-args:ditaa
|
|
'((:results . "file")
|
|
(:exports . "results")
|
|
(:java . "-Dfile.encoding=UTF-8"))
|
|
"Default arguments for evaluating a ditaa source block.")
|
|
|
|
(defcustom org-ditaa-jar-path (expand-file-name
|
|
"ditaa.jar"
|
|
(file-name-as-directory
|
|
(expand-file-name
|
|
"scripts"
|
|
(file-name-as-directory
|
|
(expand-file-name
|
|
"../contrib"
|
|
(file-name-directory (org-find-library-dir "org")))))))
|
|
"Path to the ditaa jar executable."
|
|
:group 'org-babel
|
|
:type 'string)
|
|
|
|
(defcustom org-babel-ditaa-java-cmd "java"
|
|
"Java executable to use when evaluating ditaa blocks."
|
|
:group 'org-babel
|
|
:type 'string)
|
|
|
|
(defcustom org-ditaa-eps-jar-path
|
|
(expand-file-name "DitaaEps.jar" (file-name-directory org-ditaa-jar-path))
|
|
"Path to the DitaaEps.jar executable."
|
|
:group 'org-babel
|
|
:version "24.4"
|
|
:package-version '(Org . "8.0")
|
|
:type 'string)
|
|
|
|
(defcustom org-ditaa-jar-option "-jar"
|
|
"Option for the ditaa jar file.
|
|
Do not leave leading or trailing spaces in this string."
|
|
:group 'org-babel
|
|
:version "24.1"
|
|
:type 'string)
|
|
|
|
(defun org-babel-execute:ditaa (body params)
|
|
"Execute a block of Ditaa code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(let* ((out-file (or (cdr (assq :file params))
|
|
(error
|
|
"ditaa code block requires :file header argument")))
|
|
(cmdline (cdr (assq :cmdline params)))
|
|
(java (cdr (assq :java params)))
|
|
(in-file (org-babel-temp-file "ditaa-"))
|
|
(eps (cdr (assq :eps params)))
|
|
(eps-file (when eps
|
|
(org-babel-process-file-name (concat in-file ".eps"))))
|
|
(pdf-cmd (when (and (or (string= (file-name-extension out-file) "pdf")
|
|
(cdr (assq :pdf params))))
|
|
(concat
|
|
"epstopdf"
|
|
" " eps-file
|
|
" -o=" (org-babel-process-file-name out-file))))
|
|
(cmd (concat org-babel-ditaa-java-cmd
|
|
" " java " " org-ditaa-jar-option " "
|
|
(shell-quote-argument
|
|
(expand-file-name
|
|
(if eps org-ditaa-eps-jar-path org-ditaa-jar-path)))
|
|
" " cmdline
|
|
" " (org-babel-process-file-name in-file)
|
|
" " (if pdf-cmd
|
|
eps-file
|
|
(org-babel-process-file-name out-file)))))
|
|
(unless (file-exists-p org-ditaa-jar-path)
|
|
(error "Could not find ditaa.jar at %s" org-ditaa-jar-path))
|
|
(with-temp-file in-file (insert body))
|
|
(message cmd) (shell-command cmd)
|
|
(when pdf-cmd (message pdf-cmd) (shell-command pdf-cmd))
|
|
nil)) ;; signal that output has already been written to file
|
|
|
|
(defun org-babel-prep-session:ditaa (_session _params)
|
|
"Return an error because ditaa does not support sessions."
|
|
(error "Ditaa does not support sessions"))
|
|
|
|
(provide 'ob-ditaa)
|
|
|
|
;;; ob-ditaa.el ends here
|