mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-09-30 11:57:47 +00:00
1a5e3f931c
Mainly, add the corresponding cookie, but also add various `require`s so that the compiler knows which vars should be trated as dynbound. This does not fix all the warnings, but does try to eliminate all those about "unused" variables. For the variables truly unused, the patch usually adds an underscore to their name to silence the warning. Some of the fixes affect files which already used `lexical-binding`. Not sure why the test worked before: maybe because the tests were run without compiling them first (which could cause some of the missing `require`d packages to be autoloaded before we got to the problematic code, thus hiding the problem)? I found some suspicious code, for which I added FIXMEs. There are also a few changes to the main files. * lisp/org-protocol.el (org-protocol-check-filename-for-protocol): Don't call `server-edit` if it's not yet defined. [ Needed to get the tests to pass. ] * lisp/ob-core.el (org-babel-temporary-directory) (org-babel-temporary-stable-directory): Always define (and use nil if we don't want to create a directory for it). Simplify the code based on the fact that (defvar V E) only evaluates E if V is not yet `boundp`. (org-babel-temp-file, org-babel-temp-stable-file) (org-babel-remove-temporary-directory) (org-babel-remove-temporary-stable-directory): Adjust accordingly. * lisp/org.el (org-log-beginning): Add FIXME. * testing/org-test.el: Require `org` and `org-id`. (org-id-locations-file): Don't `defconst` it. (org-test-at-id, org-test-in-example-file, org-test-at-marker) (org-test-with-temp-text, org-test-with-temp-text-in-file): Move edebug specs into `declare` (and simplify them). (org-test-with-tramp-remote-dir--worker): Declare dynbound tramp vars. (org--compile-when): Fix quoting of `exp`. (org-test-load): Tweak regexps. * testing/org-batch-test-init.el: Tweak regexp, remove dead code and add a FIXME about it. * testing/lisp/test-ox.el: Require `ox` instead of erroring out if it's not already loaded. Also require `org-inlinetask`. (org-test-with-parsed-data): Silence warnings when `info` is not used. (test-org-export/bind-keyword): Add FIXME. * testing/lisp/test-ox-publish.el: Require `org-test` and `ox-publish`. (test-org-publish/resolve-external-link): Expose lambdas to the compiler. Remove unused var `ids`. (test-org-publish/get-project-from-filename): Remove unused var `file`. * testing/lisp/test-org.el: Require `org-macs`, `org`, `org-inlinetask`, `org-refile`, and `org-agenda`. (test-org/org-read-date): Declare `org-time-was-given` as dynbound. (test-org/set-regexps-and-options): Add FIXME. * testing/lisp/test-org-timer.el: Require `org-timer`. * testing/lisp/test-org-table.el: Require `ox`. * testing/lisp/test-org-protocol.el: Require `org-protocol` instead of erroring out if it's not already loaded. Also require `capture`, and add missing `provide` statement. * testing/lisp/test-org-pcomplete.el: Require `org`. * testing/lisp/test-org-list.el: Require `org-list` and `org`. * testing/lisp/test-org-lint.el: Require `org-footnote` and `org-lint`. * testing/lisp/test-org-footnote.el: Require `org-footnote`. * testing/lisp/test-org-element.el: Require `org-element` instead of erroring out if it's not already loaded. Also require `org` and `org-inlinetask`. * testing/lisp/test-org-duration.el: Require `org-duration`. * testing/lisp/test-org-datetree.el: Require `org-datetree`. * testing/lisp/test-org-colview.el: Require `org-colview`, `org-duration`, and `org-inlinetask`. * testing/lisp/test-org-clock.el: Require `org-duration` and `org-clock`. * testing/lisp/test-org-archive.el: Require `org-archive`. * testing/lisp/test-org-agenda.el (test-org-agenda/bulk-custom-arg-func): Add FIXME. * testing/lisp/test-ol.el: Require `ol` and `org-id`. (test-org-link/store-link): Declare `org-store-link-props` and add FIXME. * testing/lisp/test-oc.el (test-org-cite/export-capability): Add FIXME. * testing/lisp/test-ob.el: Require `ob-core`, `org-src`, `ob-ref`, and `org-table`. (test-ob/eval-header-argument): Rename `foo` to `test-ob--foo` and declare it as dynbound. (test-ob/blocks-with-spaces, test-ob/specific-colnames): Add FIXME. (test-ob/noweb-expansions-in-cache): Declare `noweb-expansions-in-cache-var` as dynbound. * testing/lisp/test-ob-tangle.el: Require `org` and `ob-tangle`. * testing/lisp/test-ob-shell.el: * testing/lisp/test-ob-python.el: Require `ob-core`. * testing/lisp/test-ob-lob.el: Require `ob-lob`. (temporary-value-for-test): Declare as dynbound. * testing/lisp/test-ob-plantuml.el: Require `ob-plantuml` instead of erroring out if it's not already loaded. * testing/lisp/test-ob-lilypond.el: Require `ob-lilypond` instead of erroring out if it's not already loaded. Use `with-current-buffer`. * testing/lisp/test-ob-julia.el: Require `ob-core`. * testing/lisp/test-ob-java.el (org-babel-temporary-directory): Remove dead code now that `org-babel-temporary-directory` is always bound. * testing/lisp/test-ob-exp.el: Require `ob-exp`, `org-src`, and `org-test`. (ob-exp/evaluate-all-executables-in-order): Declare `*evaluation-collector*` as dynbound. * testing/lisp/test-ob-emacs-lisp.el (ob-emacs-lisp/dynamic-lexical-edit) (ob-emacs-lisp/dynamic-lexical-execute): Rename dynbound var to `ob-emacs--x` and declare it as such. * testing/lisp/test-ob-R.el: Require `ob-core`. (ess-ask-for-ess-directory, ess-history-file): Declare vars.
302 lines
9.4 KiB
EmacsLisp
302 lines
9.4 KiB
EmacsLisp
;;; test-org-timer.el --- Tests for org-timer.el -*- lexical-binding: t; -*-
|
||
|
||
;; Copyright (C) 2014-2015, 2019 Kyle Meyer
|
||
|
||
;; Author: Kyle Meyer <kyle@kyleam.com>
|
||
|
||
;; This file is not part of GNU Emacs.
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Code:
|
||
|
||
(eval-and-compile (require 'cl-lib))
|
||
(require 'org-timer)
|
||
|
||
(defmacro test-org-timer/with-temp-text (text &rest body)
|
||
"Like `org-test-with-temp-text', but set timer-specific variables.
|
||
Also, mute output from `message'."
|
||
(declare (indent 1))
|
||
`(cl-letf (((symbol-function 'message) (lambda (&rest _args) nil)))
|
||
(org-test-with-temp-text ,text
|
||
(let (org-timer-start-time
|
||
org-timer-pause-time
|
||
org-timer-countdown-timer
|
||
org-timer-display)
|
||
(unwind-protect (progn ,@body)
|
||
(when (timerp org-timer-countdown-timer)
|
||
(cancel-timer org-timer-countdown-timer)))))))
|
||
|
||
(defmacro test-org-timer/with-current-time (time &rest body)
|
||
"Run BODY, setting `current-time' output to TIME."
|
||
(declare (indent 1))
|
||
`(org-test-at-time ,time ,@body))
|
||
|
||
|
||
;;; Time conversion and formatting
|
||
|
||
(ert-deftest test-org-timer/secs-to-hms ()
|
||
"Test conversion between HMS format and seconds."
|
||
;; Seconds to HMS, and back again
|
||
(should
|
||
(equal "0:00:30"
|
||
(org-timer-secs-to-hms 30)))
|
||
(should
|
||
(equal 30
|
||
(org-timer-hms-to-secs (org-timer-secs-to-hms 30))))
|
||
;; Minutes to HMS, and back again
|
||
(should
|
||
(equal "0:02:10"
|
||
(org-timer-secs-to-hms 130)))
|
||
(should
|
||
(equal 130
|
||
(org-timer-hms-to-secs (org-timer-secs-to-hms 130))))
|
||
;; Hours to HMS, and back again
|
||
(should
|
||
(equal "1:01:30"
|
||
(org-timer-secs-to-hms 3690)))
|
||
(should
|
||
(equal 3690
|
||
(org-timer-hms-to-secs (org-timer-secs-to-hms 3690))))
|
||
;; Negative seconds to HMS, and back again
|
||
(should
|
||
(equal "-1:01:30"
|
||
(org-timer-secs-to-hms -3690)))
|
||
(should
|
||
(equal -3690
|
||
(org-timer-hms-to-secs (org-timer-secs-to-hms -3690)))))
|
||
|
||
(ert-deftest test-org-timer/fix-incomplete ()
|
||
"Test conversion to complete HMS format."
|
||
;; No fix is needed.
|
||
(should
|
||
(equal "1:02:03"
|
||
(org-timer-fix-incomplete "1:02:03")))
|
||
;; Hour is missing.
|
||
(should
|
||
(equal "0:02:03"
|
||
(org-timer-fix-incomplete "02:03")))
|
||
;; Minute is missing.
|
||
(should
|
||
(equal "0:00:03"
|
||
(org-timer-fix-incomplete "03"))))
|
||
|
||
(ert-deftest test-org-timer/change-times ()
|
||
"Test changing HMS format by offset."
|
||
;; Add time.
|
||
(should
|
||
(equal "
|
||
1:31:15
|
||
4:00:55"
|
||
(org-test-with-temp-text "
|
||
0:00:25
|
||
2:30:05"
|
||
(org-timer-change-times-in-region (point-min) (point-max)
|
||
"1:30:50")
|
||
(buffer-string))))
|
||
;; Subtract time.
|
||
(should
|
||
(equal "
|
||
-1:30:25
|
||
0:59:15"
|
||
(org-test-with-temp-text "
|
||
0:00:25
|
||
2:30:05"
|
||
(org-timer-change-times-in-region (point-min) (point-max)
|
||
"-1:30:50")
|
||
(buffer-string)))))
|
||
|
||
|
||
;;; Timers
|
||
|
||
;; Dummy times for overriding `current-time'
|
||
(defvar test-org-timer/time0 '(21635 62793 797149 675000))
|
||
;; Add 3 minutes and 26 seconds.
|
||
(defvar test-org-timer/time1
|
||
(time-add test-org-timer/time0 (seconds-to-time 206)))
|
||
;; Add 2 minutes and 41 seconds (6 minutes and 7 seconds total).
|
||
(defvar test-org-timer/time2
|
||
(time-add test-org-timer/time1 (seconds-to-time 161)))
|
||
;; Add 4 minutes and 55 seconds (11 minutes and 2 seconds total).
|
||
(defvar test-org-timer/time3
|
||
(time-add test-org-timer/time2 (seconds-to-time 295)))
|
||
|
||
(ert-deftest test-org-timer/start-relative ()
|
||
"Test starting relative timer."
|
||
;; Insert plain timer string, starting with `org-timer-start'.
|
||
(should
|
||
(equal "0:03:26"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer))
|
||
(org-trim (buffer-string)))))
|
||
;; Insert item timer string.
|
||
(should
|
||
(equal "- 0:03:26 ::"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-item))
|
||
(org-trim (buffer-string)))))
|
||
;; Start with `org-timer'.
|
||
(should
|
||
(equal "0:00:00 0:03:26"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer))
|
||
(org-trim (buffer-string)))))
|
||
;; Restart with `org-timer'.
|
||
(should
|
||
(equal "0:00:00"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer '(4)))
|
||
(org-trim (buffer-string))))))
|
||
|
||
(ert-deftest test-org-timer/set-timer ()
|
||
"Test setting countdown timer."
|
||
(should
|
||
(equal "0:06:34"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-set-timer 10))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer))
|
||
(org-trim (buffer-string)))))
|
||
(should
|
||
(equal "0:00:04"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-set-timer "3:30"))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer))
|
||
(org-trim (buffer-string))))))
|
||
|
||
(ert-deftest test-org-timer/pause-timer ()
|
||
"Test pausing relative and countdown timers."
|
||
;; Pause relative timer.
|
||
(should
|
||
(equal "0:03:26"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-pause-or-continue))
|
||
(org-timer)
|
||
(org-trim (buffer-string)))))
|
||
;; Pause then continue relative timer.
|
||
(should
|
||
(equal "0:08:21"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-pause-or-continue))
|
||
(test-org-timer/with-current-time test-org-timer/time2
|
||
(org-timer-pause-or-continue))
|
||
(test-org-timer/with-current-time test-org-timer/time3
|
||
(org-timer))
|
||
(org-trim (buffer-string)))))
|
||
;; Pause then continue countdown timer.
|
||
(should
|
||
(equal "0:01:39"
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-set-timer 10))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-pause-or-continue))
|
||
(test-org-timer/with-current-time test-org-timer/time2
|
||
(org-timer-pause-or-continue))
|
||
(test-org-timer/with-current-time test-org-timer/time3
|
||
(org-timer))
|
||
(org-trim (buffer-string))))))
|
||
|
||
(ert-deftest test-org-timer/stop ()
|
||
"Test stopping relative and countdown timers."
|
||
;; Stop running relative timer.
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-stop))
|
||
(should-not org-timer-start-time))
|
||
;; Stop paused relative timer.
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-start))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-pause-or-continue)
|
||
(org-timer-stop))
|
||
(should-not org-timer-start-time)
|
||
(should-not org-timer-pause-time))
|
||
;; Stop running countdown timer.
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-set-timer 10))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-stop))
|
||
(should-not org-timer-start-time)
|
||
(should-not org-timer-countdown-timer))
|
||
;; Stop paused countdown timer.
|
||
(test-org-timer/with-temp-text ""
|
||
(test-org-timer/with-current-time test-org-timer/time0
|
||
(org-timer-set-timer 10))
|
||
(test-org-timer/with-current-time test-org-timer/time1
|
||
(org-timer-pause-or-continue)
|
||
(org-timer-stop))
|
||
(should-not org-timer-start-time)
|
||
(should-not org-timer-pause-time)
|
||
(should-not org-timer-countdown-timer)))
|
||
|
||
(ert-deftest test-org-timer/other-timer-error ()
|
||
"Test for error when other timer running."
|
||
;; Relative timer is running.
|
||
(should-error
|
||
(test-org-timer/with-temp-text ""
|
||
(org-timer-start)
|
||
(org-timer-set-timer 10))
|
||
:type (list 'error 'user-error))
|
||
;; Countdown timer is running.
|
||
(should-error
|
||
(test-org-timer/with-temp-text ""
|
||
(org-timer-set-timer 10)
|
||
(org-timer-start))
|
||
:type (list 'error 'user-error)))
|
||
|
||
(ert-deftest test-org-timer/set-timer-from-effort-prop ()
|
||
"Test timer setting from effort property."
|
||
(should
|
||
(< (* 60 9) ; 9m
|
||
(test-org-timer/with-temp-text
|
||
"* foo
|
||
:PROPERTIES:
|
||
:Effort: 10
|
||
:END:"
|
||
(org-mode)
|
||
(org-timer-set-timer)
|
||
(org-timer-hms-to-secs (org-timer nil t)))
|
||
(1+ (* 60 10)) ; 10m 1s
|
||
)))
|
||
|
||
|
||
(provide 'test-org-timer)
|
||
;;; test-org-timer.el end here
|