mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-25 20:02:51 +00:00
* lisp/org.el (org-format-latex-header-extra, org-export-have-math): Removed variables. (org-latex-default-packages-alist): Renamed from `org-export-latex-default-packages-alist'. (org-latex-packages-alist): Renamed from `org-export-latex-packages-alist'. (org-try-cdlatex-tab, org-cdlatex-underscore-caret, org-cdlatex-math-modify): Reorder in file. (org-format-latex): Remove `org-format-latex-header-extra'. (org-create-formula-image-with-dvipng, org-create-formula-image-with-imagemagick): Apply variables renaming and removal. * lisp/org-entities.el (org-entities-user): Update docstring. * lisp/ox-latex.el (org-latex-classes, org-latex-listings): Update docstring. (org-latex-guess-inputenc): Renamed from `org-latex--guess-inputenc'. (org-latex-guess-babel-language): Renamed from `org-latex--guess-babel-language'. (org-latex-template): Apply renaming. * lisp/ox-beamer.el (org-beamer-template): Apply renaming. * lisp/ob-latex.el (org-babel-execute:latex): Apply variable renaming and removal. (org-babel-latex-tex-to-pdf): Call `org-latex-compile' instead of copying it.
152 lines
5.9 KiB
EmacsLisp
152 lines
5.9 KiB
EmacsLisp
;;; ob-latex.el --- org-babel functions for latex "evaluation"
|
|
|
|
;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating LaTeX source code.
|
|
;;
|
|
;; Currently on evaluation this returns raw LaTeX code, unless a :file
|
|
;; header argument is given in which case small png or pdf files will
|
|
;; be created directly form the latex source code.
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(declare-function org-create-formula-image "org" (string tofile options buffer))
|
|
(declare-function org-splice-latex-header "org"
|
|
(tpl def-pkg pkg snippets-p &optional extra))
|
|
(declare-function org-latex-guess-inputenc "ox-latex" (header))
|
|
(declare-function org-latex-compile "ox-latex" (file))
|
|
|
|
(defvar org-babel-tangle-lang-exts)
|
|
(add-to-list 'org-babel-tangle-lang-exts '("latex" . "tex"))
|
|
|
|
(defvar org-format-latex-header) ; From org.el
|
|
(defvar org-format-latex-options) ; From org.el
|
|
(defvar org-latex-default-packages-alist) ; From org.el
|
|
(defvar org-latex-packages-alist) ; From org.el
|
|
|
|
(defvar org-babel-default-header-args:latex
|
|
'((:results . "latex") (:exports . "results"))
|
|
"Default arguments to use when evaluating a LaTeX source block.")
|
|
|
|
(defun org-babel-expand-body:latex (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(mapc (lambda (pair) ;; replace variables
|
|
(setq body
|
|
(replace-regexp-in-string
|
|
(regexp-quote (format "%S" (car pair)))
|
|
(if (stringp (cdr pair))
|
|
(cdr pair) (format "%S" (cdr pair)))
|
|
body))) (mapcar #'cdr (org-babel-get-header params :var)))
|
|
(org-babel-trim body))
|
|
|
|
(defun org-babel-execute:latex (body params)
|
|
"Execute a block of Latex code with Babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(setq body (org-babel-expand-body:latex body params))
|
|
(if (cdr (assoc :file params))
|
|
(let* ((out-file (cdr (assoc :file params)))
|
|
(tex-file (org-babel-temp-file "latex-" ".tex"))
|
|
(border (cdr (assoc :border params)))
|
|
(imagemagick (cdr (assoc :imagemagick params)))
|
|
(im-in-options (cdr (assoc :iminoptions params)))
|
|
(im-out-options (cdr (assoc :imoutoptions params)))
|
|
(pdfpng (cdr (assoc :pdfpng params)))
|
|
(fit (or (cdr (assoc :fit params)) border))
|
|
(height (and fit (cdr (assoc :pdfheight params))))
|
|
(width (and fit (cdr (assoc :pdfwidth params))))
|
|
(headers (cdr (assoc :headers params)))
|
|
(in-buffer (not (string= "no" (cdr (assoc :buffer params)))))
|
|
(org-latex-packages-alist
|
|
(append (cdr (assoc :packages params)) org-latex-packages-alist)))
|
|
(cond
|
|
((and (string-match "\\.png$" out-file) (not imagemagick))
|
|
(org-create-formula-image
|
|
body out-file org-format-latex-options in-buffer))
|
|
((or (string-match "\\.pdf$" out-file) imagemagick)
|
|
(with-temp-file tex-file
|
|
(require 'ox-latex)
|
|
(insert
|
|
(org-latex-guess-inputenc
|
|
(org-splice-latex-header
|
|
org-format-latex-header
|
|
(delq
|
|
nil
|
|
(mapcar
|
|
(lambda (el)
|
|
(unless (and (listp el) (string= "hyperref" (cadr el)))
|
|
el))
|
|
org-latex-default-packages-alist))
|
|
org-latex-packages-alist
|
|
nil))
|
|
(if fit "\n\\usepackage[active, tightpage]{preview}\n" "")
|
|
(if border (format "\\setlength{\\PreviewBorder}{%s}" border) "")
|
|
(if height (concat "\n" (format "\\pdfpageheight %s" height)) "")
|
|
(if width (concat "\n" (format "\\pdfpagewidth %s" width)) "")
|
|
(if headers
|
|
(concat "\n"
|
|
(if (listp headers)
|
|
(mapconcat #'identity headers "\n")
|
|
headers) "\n")
|
|
"")
|
|
(if fit
|
|
(concat "\n\\begin{document}\n\\begin{preview}\n" body
|
|
"\n\\end{preview}\n\\end{document}\n")
|
|
(concat "\n\\begin{document}\n" body "\n\\end{document}\n"))))
|
|
(when (file-exists-p out-file) (delete-file out-file))
|
|
(let ((transient-pdf-file (org-babel-latex-tex-to-pdf tex-file)))
|
|
(cond
|
|
((string-match "\\.pdf$" out-file)
|
|
(rename-file transient-pdf-file out-file))
|
|
(imagemagick
|
|
(convert-pdf
|
|
transient-pdf-file out-file im-in-options im-out-options)
|
|
(when (file-exists-p transient-pdf-file)
|
|
(delete-file transient-pdf-file))))))
|
|
((string-match "\\.\\([^\\.]+\\)$" out-file)
|
|
(error "Can not create %s files, please specify a .png or .pdf file or try the :imagemagick header argument"
|
|
(match-string 1 out-file))))
|
|
nil) ;; signal that output has already been written to file
|
|
body))
|
|
|
|
(defun convert-pdf (pdffile out-file im-in-options im-out-options)
|
|
"Generate a file from a pdf file using imagemagick."
|
|
(let ((cmd (concat "convert " im-in-options " " pdffile " "
|
|
im-out-options " " out-file)))
|
|
(message (concat "Converting pdffile file " cmd "..."))
|
|
(shell-command cmd)))
|
|
|
|
(defun org-babel-latex-tex-to-pdf (file)
|
|
"Generate a pdf file according to the contents FILE."
|
|
(require 'ox-latex)
|
|
(org-latex-compile file))
|
|
|
|
(defun org-babel-prep-session:latex (session params)
|
|
"Return an error because LaTeX doesn't support sessions."
|
|
(error "LaTeX does not support sessions"))
|
|
|
|
|
|
(provide 'ob-latex)
|
|
;;; ob-latex.el ends here
|