mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-20 19:18:46 +00:00
* lisp/ob-C.el (org-babel-C-execute): * lisp/ob-J.el (org-babel-execute:J): * lisp/ob-R.el (org-babel-edit-prep:R): (org-babel-expand-body:R): (org-babel-execute:R): (org-babel-variable-assignments:R): (org-babel-R-initiate-session): * lisp/ob-abc.el (org-babel-execute:abc): * lisp/ob-asymptote.el (org-babel-execute:asymptote): * lisp/ob-awk.el (org-babel-execute:awk): * lisp/ob-clojure.el (org-babel-expand-body:clojure): (org-babel-execute:clojure): * lisp/ob-core.el (org-babel-expand-body:generic): (org-babel-load-in-session): (org-babel-initiate-session): (org-babel-open-src-block-result): (org-babel-process-params): (org-babel-insert-result): (org-babel-expand-noweb-references): * lisp/ob-ditaa.el (org-babel-execute:ditaa): * lisp/ob-dot.el (org-babel-execute:dot): * lisp/ob-ebnf.el (org-babel-execute:ebnf): * lisp/ob-emacs-lisp.el (org-babel-expand-body:emacs-lisp): (org-babel-execute:emacs-lisp): * lisp/ob-exp.el (org-babel-exp-process-buffer): (org-babel-exp-do-export): (org-babel-exp-code): * lisp/ob-forth.el (org-babel-execute:forth): * lisp/ob-fortran.el (org-babel-execute:fortran): * lisp/ob-gnuplot.el (org-babel-gnuplot-process-vars): (org-babel-expand-body:gnuplot): (org-babel-execute:gnuplot): * lisp/ob-groovy.el (org-babel-execute:groovy): * lisp/ob-haskell.el (org-babel-execute:haskell): * lisp/ob-io.el (org-babel-execute:io): * lisp/ob-java.el (org-babel-execute:java): * lisp/ob-js.el (org-babel-execute:js): * lisp/ob-latex.el (org-babel-execute:latex): * lisp/ob-ledger.el (org-babel-execute:ledger): * lisp/ob-lilypond.el (org-babel-lilypond-process-basic): * lisp/ob-lisp.el (org-babel-expand-body:lisp): (org-babel-execute:lisp): * lisp/ob-lua.el (org-babel-execute:lua): * lisp/ob-maxima.el (org-babel-execute:maxima): * lisp/ob-mscgen.el (org-babel-execute:mscgen): * lisp/ob-ocaml.el (org-babel-execute:ocaml): * lisp/ob-octave.el (org-babel-execute:octave): * lisp/ob-org.el (org-babel-execute:org): * lisp/ob-perl.el (org-babel-execute:perl): * lisp/ob-picolisp.el (org-babel-execute:picolisp): * lisp/ob-plantuml.el (org-babel-execute:plantuml): * lisp/ob-python.el (org-babel-execute:python): * lisp/ob-ruby.el (org-babel-execute:ruby): * lisp/ob-sass.el (org-babel-execute:sass): * lisp/ob-scala.el (org-babel-execute:scala): * lisp/ob-scheme.el (org-babel-execute:scheme): * lisp/ob-screen.el (org-babel-execute:screen): (org-babel-prep-session:screen): * lisp/ob-shell.el (org-babel-execute:shell): (org-babel-variable-assignments:shell): (org-babel-sh-evaluate): * lisp/ob-shen.el (org-babel-execute:shen): * lisp/ob-sql.el (org-babel-execute:sql): * lisp/ob-sqlite.el (org-babel-execute:sqlite): * lisp/ob-tangle.el (org-babel-tangle): (org-babel-tangle-single-block): * lisp/org-src.el (org-src-associate-babel-session): * lisp/org.el (org-next-link): Use `assq' instead of `assoc' with :keyword keys.
95 lines
3.2 KiB
EmacsLisp
95 lines
3.2 KiB
EmacsLisp
;;; ob-emacs-lisp.el --- Babel Functions for Emacs-lisp Code -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating emacs-lisp code
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(defconst org-babel-header-args:emacs-lisp '((lexical . :any))
|
|
"Emacs-lisp specific header arguments.")
|
|
|
|
(defvar org-babel-default-header-args:emacs-lisp '((:lexical . "no"))
|
|
"Default arguments for evaluating an emacs-lisp source block.
|
|
|
|
A value of \"yes\" or t causes src blocks to be eval'd using
|
|
lexical scoping. It can also be an alist mapping symbols to
|
|
their value. It is used as the optional LEXICAL argument to
|
|
`eval', which see.")
|
|
|
|
(defun org-babel-expand-body:emacs-lisp (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let* ((vars (org-babel--get-vars params))
|
|
(result-params (cdr (assq :result-params params)))
|
|
(print-level nil) (print-length nil)
|
|
(body (if (> (length vars) 0)
|
|
(concat "(let ("
|
|
(mapconcat
|
|
(lambda (var)
|
|
(format "%S" (print `(,(car var) ',(cdr var)))))
|
|
vars "\n ")
|
|
")\n" body "\n)")
|
|
(concat body "\n"))))
|
|
(if (or (member "code" result-params)
|
|
(member "pp" result-params))
|
|
(concat "(pp " body ")") body)))
|
|
|
|
(defun org-babel-execute:emacs-lisp (body params)
|
|
"Execute a block of emacs-lisp code with Babel."
|
|
(save-window-excursion
|
|
(let* ((lexical (cdr (assq :lexical params)))
|
|
(result
|
|
(eval (read (format (if (member "output"
|
|
(cdr (assq :result-params params)))
|
|
"(with-output-to-string %s)"
|
|
"(progn %s)")
|
|
(org-babel-expand-body:emacs-lisp
|
|
body params)))
|
|
|
|
(if (listp lexical)
|
|
lexical
|
|
(member lexical '("yes" "t"))))))
|
|
(org-babel-result-cond (cdr (assq :result-params params))
|
|
(let ((print-level nil)
|
|
(print-length nil))
|
|
(if (or (member "scalar" (cdr (assq :result-params params)))
|
|
(member "verbatim" (cdr (assq :result-params params))))
|
|
(format "%S" result)
|
|
(format "%s" result)))
|
|
(org-babel-reassemble-table
|
|
result
|
|
(org-babel-pick-name (cdr (assq :colname-names params))
|
|
(cdr (assq :colnames params)))
|
|
(org-babel-pick-name (cdr (assq :rowname-names params))
|
|
(cdr (assq :rownames params))))))))
|
|
|
|
(org-babel-make-language-alias "elisp" "emacs-lisp")
|
|
|
|
(provide 'ob-emacs-lisp)
|
|
|
|
|
|
|
|
;;; ob-emacs-lisp.el ends here
|