mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-22 04:19:05 +00:00
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
152 lines
5.2 KiB
EmacsLisp
152 lines
5.2 KiB
EmacsLisp
;;; ob-table.el --- Support for Calling Babel Functions from Tables -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Should allow calling functions from Org tables using the function
|
|
;; `org-sbe' as so...
|
|
|
|
;; #+begin_src emacs-lisp :results silent
|
|
;; (defun fibbd (n) (if (< n 2) 1 (+ (fibbd (- n 1)) (fibbd (- n 2)))))
|
|
;; #+end_src
|
|
|
|
;; #+name: fibbd
|
|
;; #+begin_src emacs-lisp :var n=2 :results silent
|
|
;; (fibbd n)
|
|
;; #+end_src
|
|
|
|
;; | original | fibbd |
|
|
;; |----------+--------|
|
|
;; | 0 | |
|
|
;; | 1 | |
|
|
;; | 2 | |
|
|
;; | 3 | |
|
|
;; | 4 | |
|
|
;; | 5 | |
|
|
;; | 6 | |
|
|
;; | 7 | |
|
|
;; | 8 | |
|
|
;; | 9 | |
|
|
;; #+TBLFM: $2='(org-sbe "fibbd" (n $1))
|
|
|
|
;; NOTE: The quotation marks around the function name, 'fibbd' here,
|
|
;; are optional.
|
|
|
|
;;; Code:
|
|
(require 'ob-core)
|
|
(require 'org-macs)
|
|
|
|
(defun org-babel-table-truncate-at-newline (string)
|
|
"Replace newline character with ellipses.
|
|
If STRING ends in a newline character, then remove the newline
|
|
character and replace it with ellipses."
|
|
(if (and (stringp string) (string-match "[\n\r]\\(.\\)?" string))
|
|
(concat (substring string 0 (match-beginning 0))
|
|
(when (match-string 1 string) "..."))
|
|
string))
|
|
|
|
(defmacro org-sbe (source-block &rest variables)
|
|
"Return the results of calling SOURCE-BLOCK with VARIABLES.
|
|
|
|
Each element of VARIABLES should be a list of two elements: the
|
|
first element is the name of the variable and second element is a
|
|
string of its value.
|
|
|
|
So this `org-sbe' construct
|
|
|
|
(org-sbe \"source-block\" (n $2) (m 3))
|
|
|
|
is the equivalent of the following source code block:
|
|
|
|
#+begin_src emacs-lisp :var results=source-block(n=val_at_col_2, m=3) :results silent
|
|
results
|
|
#+end_src
|
|
|
|
NOTE: The quotation marks around the function name,
|
|
'source-block', are optional.
|
|
|
|
NOTE: By default, string variable names are interpreted as
|
|
references to source-code blocks, to force interpretation of a
|
|
cell's value as a string, prefix the identifier a \"$\" (e.g.,
|
|
\"$$2\" instead of \"$2\" or \"$@2$2\" instead of \"@2$2\").
|
|
|
|
NOTE: It is also possible to pass header arguments to the code
|
|
block. In this case a table cell should hold the string value of
|
|
the header argument which can then be passed before all variables
|
|
as shown in the example below.
|
|
|
|
| 1 | 2 | :file nothing.png | nothing.png |
|
|
#+TBLFM: @1$4=\\='(org-sbe test-sbe $3 (x $1) (y $2))"
|
|
(declare (debug (form form)))
|
|
(let* ((header-args (if (stringp (car variables)) (car variables) ""))
|
|
(variables (if (stringp (car variables)) (cdr variables) variables)))
|
|
(let* (quote
|
|
(variables
|
|
(mapcar
|
|
(lambda (var)
|
|
;; ensure that all cells prefixed with $'s are strings
|
|
(cons (car var)
|
|
(delq nil (mapcar
|
|
(lambda (el)
|
|
(if (eq '$ el)
|
|
(prog1 nil (setq quote t))
|
|
(prog1
|
|
(cond
|
|
(quote (format "\"%s\"" el))
|
|
((stringp el) (org-no-properties el))
|
|
(t el))
|
|
(setq quote nil))))
|
|
(cdr var)))))
|
|
variables)))
|
|
(unless (stringp source-block)
|
|
(setq source-block (symbol-name source-block)))
|
|
(let ((result
|
|
(if (and source-block (> (length source-block) 0))
|
|
(let ((params
|
|
;; FIXME: Why `eval'?!?!?
|
|
(eval `(org-babel-parse-header-arguments
|
|
(concat
|
|
":var results="
|
|
,source-block
|
|
"[" ,header-args "]"
|
|
"("
|
|
(mapconcat
|
|
(lambda (var-spec)
|
|
(if (> (length (cdr var-spec)) 1)
|
|
(format "%S='%S"
|
|
(car var-spec)
|
|
(mapcar #'read (cdr var-spec)))
|
|
(format "%S=%s"
|
|
(car var-spec) (cadr var-spec))))
|
|
',variables ", ")
|
|
")")))))
|
|
(org-babel-execute-src-block
|
|
nil (list "emacs-lisp" "results" params)
|
|
'((:results . "silent"))))
|
|
"")))
|
|
(org-trim (if (stringp result) result (format "%S" result)))))))
|
|
|
|
(provide 'ob-table)
|
|
|
|
;;; ob-table.el ends here
|