mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-09-30 12:27:51 +00:00
1a5e3f931c
Mainly, add the corresponding cookie, but also add various `require`s so that the compiler knows which vars should be trated as dynbound. This does not fix all the warnings, but does try to eliminate all those about "unused" variables. For the variables truly unused, the patch usually adds an underscore to their name to silence the warning. Some of the fixes affect files which already used `lexical-binding`. Not sure why the test worked before: maybe because the tests were run without compiling them first (which could cause some of the missing `require`d packages to be autoloaded before we got to the problematic code, thus hiding the problem)? I found some suspicious code, for which I added FIXMEs. There are also a few changes to the main files. * lisp/org-protocol.el (org-protocol-check-filename-for-protocol): Don't call `server-edit` if it's not yet defined. [ Needed to get the tests to pass. ] * lisp/ob-core.el (org-babel-temporary-directory) (org-babel-temporary-stable-directory): Always define (and use nil if we don't want to create a directory for it). Simplify the code based on the fact that (defvar V E) only evaluates E if V is not yet `boundp`. (org-babel-temp-file, org-babel-temp-stable-file) (org-babel-remove-temporary-directory) (org-babel-remove-temporary-stable-directory): Adjust accordingly. * lisp/org.el (org-log-beginning): Add FIXME. * testing/org-test.el: Require `org` and `org-id`. (org-id-locations-file): Don't `defconst` it. (org-test-at-id, org-test-in-example-file, org-test-at-marker) (org-test-with-temp-text, org-test-with-temp-text-in-file): Move edebug specs into `declare` (and simplify them). (org-test-with-tramp-remote-dir--worker): Declare dynbound tramp vars. (org--compile-when): Fix quoting of `exp`. (org-test-load): Tweak regexps. * testing/org-batch-test-init.el: Tweak regexp, remove dead code and add a FIXME about it. * testing/lisp/test-ox.el: Require `ox` instead of erroring out if it's not already loaded. Also require `org-inlinetask`. (org-test-with-parsed-data): Silence warnings when `info` is not used. (test-org-export/bind-keyword): Add FIXME. * testing/lisp/test-ox-publish.el: Require `org-test` and `ox-publish`. (test-org-publish/resolve-external-link): Expose lambdas to the compiler. Remove unused var `ids`. (test-org-publish/get-project-from-filename): Remove unused var `file`. * testing/lisp/test-org.el: Require `org-macs`, `org`, `org-inlinetask`, `org-refile`, and `org-agenda`. (test-org/org-read-date): Declare `org-time-was-given` as dynbound. (test-org/set-regexps-and-options): Add FIXME. * testing/lisp/test-org-timer.el: Require `org-timer`. * testing/lisp/test-org-table.el: Require `ox`. * testing/lisp/test-org-protocol.el: Require `org-protocol` instead of erroring out if it's not already loaded. Also require `capture`, and add missing `provide` statement. * testing/lisp/test-org-pcomplete.el: Require `org`. * testing/lisp/test-org-list.el: Require `org-list` and `org`. * testing/lisp/test-org-lint.el: Require `org-footnote` and `org-lint`. * testing/lisp/test-org-footnote.el: Require `org-footnote`. * testing/lisp/test-org-element.el: Require `org-element` instead of erroring out if it's not already loaded. Also require `org` and `org-inlinetask`. * testing/lisp/test-org-duration.el: Require `org-duration`. * testing/lisp/test-org-datetree.el: Require `org-datetree`. * testing/lisp/test-org-colview.el: Require `org-colview`, `org-duration`, and `org-inlinetask`. * testing/lisp/test-org-clock.el: Require `org-duration` and `org-clock`. * testing/lisp/test-org-archive.el: Require `org-archive`. * testing/lisp/test-org-agenda.el (test-org-agenda/bulk-custom-arg-func): Add FIXME. * testing/lisp/test-ol.el: Require `ol` and `org-id`. (test-org-link/store-link): Declare `org-store-link-props` and add FIXME. * testing/lisp/test-oc.el (test-org-cite/export-capability): Add FIXME. * testing/lisp/test-ob.el: Require `ob-core`, `org-src`, `ob-ref`, and `org-table`. (test-ob/eval-header-argument): Rename `foo` to `test-ob--foo` and declare it as dynbound. (test-ob/blocks-with-spaces, test-ob/specific-colnames): Add FIXME. (test-ob/noweb-expansions-in-cache): Declare `noweb-expansions-in-cache-var` as dynbound. * testing/lisp/test-ob-tangle.el: Require `org` and `ob-tangle`. * testing/lisp/test-ob-shell.el: * testing/lisp/test-ob-python.el: Require `ob-core`. * testing/lisp/test-ob-lob.el: Require `ob-lob`. (temporary-value-for-test): Declare as dynbound. * testing/lisp/test-ob-plantuml.el: Require `ob-plantuml` instead of erroring out if it's not already loaded. * testing/lisp/test-ob-lilypond.el: Require `ob-lilypond` instead of erroring out if it's not already loaded. Use `with-current-buffer`. * testing/lisp/test-ob-julia.el: Require `ob-core`. * testing/lisp/test-ob-java.el (org-babel-temporary-directory): Remove dead code now that `org-babel-temporary-directory` is always bound. * testing/lisp/test-ob-exp.el: Require `ob-exp`, `org-src`, and `org-test`. (ob-exp/evaluate-all-executables-in-order): Declare `*evaluation-collector*` as dynbound. * testing/lisp/test-ob-emacs-lisp.el (ob-emacs-lisp/dynamic-lexical-edit) (ob-emacs-lisp/dynamic-lexical-execute): Rename dynbound var to `ob-emacs--x` and declare it as such. * testing/lisp/test-ob-R.el: Require `ob-core`. (ess-ask-for-ess-directory, ess-history-file): Declare vars.
176 lines
6.3 KiB
EmacsLisp
176 lines
6.3 KiB
EmacsLisp
;;; test-org-attach.el --- tests for org-attach.el -*- lexical-binding: t; -*-
|
||
|
||
;; Copyright (C) 2017, 2019
|
||
|
||
;; Author: Marco Wahl
|
||
;; Keywords: internal
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;;
|
||
|
||
;;; Code:
|
||
|
||
(require 'org-test "../testing/org-test")
|
||
(require 'org-attach)
|
||
(eval-and-compile (require 'cl-lib))
|
||
|
||
(ert-deftest test-org-attach/dir ()
|
||
"Test `org-attach-get' specifications."
|
||
(let ((org-file-apps '((t . emacs))))
|
||
(should (equal "Text in fileA\n"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 157) ;; First attachment link
|
||
(org-open-at-point)
|
||
(buffer-string))))
|
||
(should-not (equal "Text in fileB\n"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 219) ;; Second attachment link
|
||
(let ((org-attach-use-inheritance nil))
|
||
(org-open-at-point)
|
||
(buffer-string)))))
|
||
(should (equal "Text in fileB\n"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 219) ;; Second attachment link
|
||
(let ((org-attach-use-inheritance t))
|
||
(org-open-at-point)
|
||
(buffer-string)))))
|
||
(should-not (equal "att1"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 179) ;; H1.1
|
||
(let ((org-attach-use-inheritance nil))
|
||
(org-attach-dir)))))
|
||
(should (equal "att1"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 179) ;; H1.1
|
||
(let ((org-attach-use-inheritance t))
|
||
(org-attach-dir)))))
|
||
(should (equal '("fileC" "fileD")
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 239) ;; H1.2
|
||
(org-attach-file-list (org-attach-dir)))))
|
||
(should (equal '("fileC" "fileD")
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 239) ;; H1.2
|
||
(org-attach-file-list (org-attach-dir)))))
|
||
(should (equal '("fileE")
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 289) ;; H2
|
||
(let ((org-attach-id-dir "data/"))
|
||
(org-attach-file-list (org-attach-dir))))))
|
||
(should (equal "peek-a-boo\n"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 289) ;; H2
|
||
(let ((org-attach-id-dir "data/"))
|
||
(org-attach-open-in-emacs)
|
||
(buffer-string)))))
|
||
(should (equal '("fileA" "fileB")
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 336) ;; H3
|
||
(org-attach-file-list (org-attach-dir)))))
|
||
;; Test for folder not initialized in the filesystem
|
||
(should-not (org-test-in-example-file org-test-attachments-file
|
||
(goto-char 401) ;; H3.1
|
||
(let ((org-attach-use-inheritance nil)
|
||
(org-attach-id-dir "data/"))
|
||
(org-attach-dir))))
|
||
;; Not yet initialized folder should be found if no-fs-check is
|
||
;; non-nil
|
||
(should (equal "data/ab/cd12345"
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 401) ;; H3.1
|
||
(let ((org-attach-use-inheritance nil)
|
||
(org-attach-id-dir "data/"))
|
||
(file-relative-name (org-attach-dir nil t))))))
|
||
(should (equal '("fileA" "fileB")
|
||
(org-test-in-example-file org-test-attachments-file
|
||
(goto-char 401) ;; H3.1
|
||
(let ((org-attach-use-inheritance t))
|
||
;; This is where it gets a bit sketchy...! DIR always has
|
||
;; priority over ID, even if ID is declared "higher up" in the
|
||
;; tree. This can potentially be revised. But it is also
|
||
;; pretty clean. DIR is always higher in priority than ID right
|
||
;; now, no matter the depth in the tree.
|
||
(org-attach-file-list (org-attach-dir))))))))
|
||
|
||
(ert-deftest test-org-attach/dired-attach-to-next-best-subtree/1 ()
|
||
"Attach file at point in dired to subtree."
|
||
(should
|
||
(let ((a-filename (make-temp-file "a")) ; file is an attach candidate.
|
||
(org-attach-id-dir "data/"))
|
||
(unwind-protect
|
||
(org-test-with-temp-text-in-file
|
||
"* foo :foo:"
|
||
(split-window)
|
||
(let ((org-buffer (current-buffer))
|
||
(_dired-buffer (dired temporary-file-directory)))
|
||
(cl-assert (eq 'dired-mode major-mode))
|
||
(revert-buffer)
|
||
(dired-goto-file a-filename)
|
||
; action
|
||
(call-interactively #'org-attach-dired-to-subtree)
|
||
; check
|
||
(delete-window)
|
||
(switch-to-buffer org-buffer)
|
||
(cl-assert (eq 'org-mode major-mode)))
|
||
(beginning-of-buffer)
|
||
(search-forward "* foo")
|
||
; expectation. tag ATTACH has been appended.
|
||
(cl-reduce (lambda (x y) (or x y))
|
||
(mapcar (lambda (x) (string-equal "ATTACH" x))
|
||
(plist-get
|
||
(plist-get
|
||
(org-element-at-point) 'headline)
|
||
:tags))))
|
||
(delete-file a-filename)))))
|
||
|
||
(ert-deftest test-org-attach/dired-attach-to-next-best-subtree/2 ()
|
||
"Attach 2 marked files."
|
||
(should
|
||
(let ((a-filename (make-temp-file "a"))
|
||
(b-filename (make-temp-file "b")) ; attach candidates.
|
||
(org-attach-id-dir "data/"))
|
||
(unwind-protect
|
||
(org-test-with-temp-text-in-file
|
||
"* foo"
|
||
(split-window)
|
||
(let ((org-buffer (current-buffer))
|
||
(_dired-buffer (dired temporary-file-directory)))
|
||
(cl-assert (eq 'dired-mode major-mode))
|
||
(revert-buffer)
|
||
(dired-goto-file a-filename)
|
||
(dired-mark 1)
|
||
(dired-goto-file b-filename)
|
||
(dired-mark 1)
|
||
; action
|
||
(call-interactively #'org-attach-dired-to-subtree)
|
||
; check
|
||
(delete-window)
|
||
(switch-to-buffer org-buffer))
|
||
(cl-assert (eq 'org-mode major-mode))
|
||
(beginning-of-buffer)
|
||
(search-forward "* foo")
|
||
(and (file-exists-p (concat (org-attach-dir) "/"
|
||
(file-name-nondirectory a-filename)))
|
||
(file-exists-p (concat (org-attach-dir) "/"
|
||
(file-name-nondirectory b-filename)))))
|
||
(delete-file a-filename)
|
||
(delete-file b-filename)))))
|
||
|
||
|
||
(provide 'test-org-attach)
|
||
;;; test-org-attach.el ends here
|