mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-22 12:18:40 +00:00
2013-11-12 Stefan Monnier <monnier@iro.umontreal.ca> Address some byte-compiler warnings. * ob-abc.el (org-babel-expand-body:abc): Use dolist. (org-babel-execute:abc): Fix regexp quoting. * ob-calc.el (org--var-syms): Rename from `var-syms'. * ob-lilypond.el (ly-compile-lilyfile): Remove redundant let-binding. * ob-table.el (sbe): Move debug declaration. * org-clock.el (org--msg-extra): Rename from `msg-extra'. * org.el (org-version): Avoid var name starting with _. (org-inhibit-startup, org-called-with-limited-levels) (org-link-search-inhibit-query, org-time-was-given) (org-end-time-was-given, org-def, org-defdecode, org-with-time): * org-colview.el (org-agenda-overriding-columns-format): * org-agenda.el (org-agenda-multi, org-depend-tag-blocked) (org-agenda-show-log-scoped): * ob-python.el (py-which-bufname, python-shell-buffer-name): * ob-haskell.el (org-export-copy-to-kill-ring): * ob-exp.el (org-link-search-inhibit-query): * ob-R.el (ess-eval-visibly-p): * ob-core.el (org-src-window-setup): Declare before use. (org-babel-expand-noweb-references): Remove unused `blocks-in-buffer'. * ox-odt.el (org-odt-hfy-face-to-css): * org-src.el (org-src-associate-babel-session, org-src-get-lang-mode): * org-bibtex.el (org-bibtex-get, org-bibtex-ask, org-bibtex) (org-bibtex-check): * ob-tangle.el (org-babel-tangle, org-babel-spec-to-string) (org-babel-tangle-single-block, org-babel-tangle-comment-links): * ob-table.el (sbe): * ob-sqlite.el (org-babel-sqlite-expand-vars): * ob-sql.el (org-babel-sql-expand-vars): * ob-shen.el (org-babel-execute:shen): * ob-sh.el (org-babel-execute:sh, org-babel-sh-evaluate): * ob-scala.el (org-babel-scala-evaluate): * ob-ruby.el (org-babel-ruby-table-or-string) (org-babel-ruby-evaluate): * ob-python.el (org-babel-python-table-or-string) (org-babel-python-evaluate-external-process) (org-babel-python-evaluate-session): * ob-picolisp.el (org-babel-execute:picolisp): * ob-perl.el (org-babel-perl-evaluate): * ob-maxima.el (org-babel-execute:maxima): * ob-lisp.el (org-babel-execute:lisp): * ob-java.el (org-babel-execute:java): * ob-io.el (org-babel-io-evaluate): * ob-haskell.el (org-babel-execute:haskell): * ob-fortran.el (org-babel-execute:fortran): * ob-exp.el (org-babel-exp-code): * ob-emacs-lisp.el (org-babel-execute:emacs-lisp): * ob-ditaa.el (org-babel-execute:ditaa): * ob-core.el (org-babel-execute-src-block, org-babel-sha1-hash) (org-babel-parse-header-arguments, org-babel-reassemble-table) (org-babel-goto-src-block-head, org-babel-mark-block) (org-babel-expand-noweb-references, org-babel-script-escape) (org-babel-process-file-name): * ob-clojure.el (org-babel-execute:clojure): * ob-calc.el (org-babel-execute:calc): * ob-awk.el (org-babel-execute:awk): * ob-abc.el (org-babel-execute:abc): * ob-R.el (org-babel-expand-body:R): * ob-C.el (org-babel-C-execute): Avoid deprecated ((lambda) ...). 2013-11-12 Glenn Morris <rgm@gnu.org> * ox-html.el (org-html-scripts): Add 2013 to copyright years. (org-html-infojs-template): Copyright holder to FSF.
190 lines
7.9 KiB
EmacsLisp
190 lines
7.9 KiB
EmacsLisp
;;; ob-picolisp.el --- org-babel functions for picolisp evaluation
|
|
|
|
;; Copyright (C) 2010-2013 Free Software Foundation, Inc.
|
|
|
|
;; Authors: Thorsten Jolitz
|
|
;; Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; This library enables the use of PicoLisp in the multi-language
|
|
;; programming framework Org-Babel. PicoLisp is a minimal yet
|
|
;; fascinating lisp dialect and a highly productive application
|
|
;; framework for web-based client-server applications on top of
|
|
;; object-oriented databases. A good way to learn PicoLisp is to first
|
|
;; read Paul Grahams essay "The hundred year language"
|
|
;; (http://www.paulgraham.com/hundred.html) and then study the various
|
|
;; documents and essays published in the PicoLisp wiki
|
|
;; (http://picolisp.com/5000/-2.html). PicoLisp is included in some
|
|
;; GNU/Linux Distributions, and can be downloaded here:
|
|
;; http://software-lab.de/down.html. It ships with a picolisp-mode and
|
|
;; a inferior-picolisp-mode for Emacs (to be found in the /lib/el/
|
|
;; directory).
|
|
|
|
;; Although it might seem more natural to use Emacs Lisp for most
|
|
;; Lisp-based programming tasks inside Org-Mode, an Emacs library
|
|
;; written in Emacs Lisp, PicoLisp has at least two outstanding
|
|
;; features that make it a valuable addition to Org-Babel:
|
|
|
|
;; PicoLisp _is_ an object-oriented database with a Prolog-based query
|
|
;; language implemented in PicoLisp (Pilog). Database objects are
|
|
;; first-class members of the language.
|
|
|
|
;; PicoLisp is an extremely productive framework for the development
|
|
;; of interactive web-applications (on top of a database).
|
|
|
|
;;; Requirements:
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'comint)
|
|
(eval-when-compile (require 'cl))
|
|
|
|
(declare-function run-picolisp "ext:inferior-picolisp" (cmd))
|
|
(defvar org-babel-tangle-lang-exts) ;; Autoloaded
|
|
|
|
;; optionally define a file extension for this language
|
|
(add-to-list 'org-babel-tangle-lang-exts '("picolisp" . "l"))
|
|
|
|
;;; interferes with settings in org-babel buffer?
|
|
;; optionally declare default header arguments for this language
|
|
;; (defvar org-babel-default-header-args:picolisp
|
|
;; '((:colnames . "no"))
|
|
;; "Default arguments for evaluating a picolisp source block.")
|
|
|
|
(defvar org-babel-picolisp-eoe "org-babel-picolisp-eoe"
|
|
"String to indicate that evaluation has completed.")
|
|
|
|
(defcustom org-babel-picolisp-cmd "pil"
|
|
"Name of command used to evaluate picolisp blocks."
|
|
:group 'org-babel
|
|
:version "24.1"
|
|
:type 'string)
|
|
|
|
(defun org-babel-expand-body:picolisp (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let ((vars (mapcar #'cdr (org-babel-get-header params :var)))
|
|
(result-params (cdr (assoc :result-params params)))
|
|
(print-level nil) (print-length nil))
|
|
(if (> (length vars) 0)
|
|
(concat "(prog (let ("
|
|
(mapconcat
|
|
(lambda (var)
|
|
(format "%S '%S)"
|
|
(print (car var))
|
|
(print (cdr var))))
|
|
vars "\n ")
|
|
" \n" body ") )")
|
|
body)))
|
|
|
|
(defun org-babel-execute:picolisp (body params)
|
|
"Execute a block of Picolisp code with org-babel. This function is
|
|
called by `org-babel-execute-src-block'"
|
|
(message "executing Picolisp source code block")
|
|
(let* (
|
|
;; Name of the session or "none".
|
|
(session-name (cdr (assoc :session params)))
|
|
;; Set the session if the session variable is non-nil.
|
|
(session (org-babel-picolisp-initiate-session session-name))
|
|
;; Either OUTPUT or VALUE which should behave as described above.
|
|
(result-type (cdr (assoc :result-type params)))
|
|
(result-params (cdr (assoc :result-params params)))
|
|
;; Expand the body with `org-babel-expand-body:picolisp'.
|
|
(full-body (org-babel-expand-body:picolisp body params))
|
|
;; Wrap body appropriately for the type of evaluation and results.
|
|
(wrapped-body
|
|
(cond
|
|
((or (member "code" result-params)
|
|
(member "pp" result-params))
|
|
(format "(pretty (out \"/dev/null\" %s))" full-body))
|
|
((and (member "value" result-params) (not session))
|
|
(format "(print (out \"/dev/null\" %s))" full-body))
|
|
((member "value" result-params)
|
|
(format "(out \"/dev/null\" %s)" full-body))
|
|
(t full-body)))
|
|
(result
|
|
(if (not (string= session-name "none"))
|
|
;; Session based evaluation.
|
|
(mapconcat ;; <- joins the list back into a single string
|
|
#'identity
|
|
(butlast ;; <- remove the org-babel-picolisp-eoe line
|
|
(delq nil
|
|
(mapcar
|
|
(lambda (line)
|
|
(org-babel-chomp ;; Remove trailing newlines.
|
|
(when (> (length line) 0) ;; Remove empty lines.
|
|
(cond
|
|
;; Remove leading "-> " from return values.
|
|
((and (>= (length line) 3)
|
|
(string= "-> " (substring line 0 3)))
|
|
(substring line 3))
|
|
;; Remove trailing "-> <<return-value>>" on the
|
|
;; last line of output.
|
|
((and (member "output" result-params)
|
|
(string-match-p "->" line))
|
|
(substring line 0 (string-match "->" line)))
|
|
(t line)
|
|
)
|
|
;;(if (and (>= (length line) 3);Remove leading "<-"
|
|
;; (string= "-> " (substring line 0 3)))
|
|
;; (substring line 3)
|
|
;; line)
|
|
)))
|
|
;; Returns a list of the output of each evaluated exp.
|
|
(org-babel-comint-with-output
|
|
(session org-babel-picolisp-eoe)
|
|
(insert wrapped-body) (comint-send-input)
|
|
(insert "'" org-babel-picolisp-eoe)
|
|
(comint-send-input)))))
|
|
"\n")
|
|
;; external evaluation
|
|
(let ((script-file (org-babel-temp-file "picolisp-script-")))
|
|
(with-temp-file script-file
|
|
(insert (concat wrapped-body "(bye)")))
|
|
(org-babel-eval
|
|
(format "%s %s"
|
|
org-babel-picolisp-cmd
|
|
(org-babel-process-file-name script-file))
|
|
"")))))
|
|
(org-babel-result-cond result-params
|
|
result
|
|
(read result))))
|
|
|
|
(defun org-babel-picolisp-initiate-session (&optional session-name)
|
|
"If there is not a current inferior-process-buffer in SESSION
|
|
then create. Return the initialized session."
|
|
(unless (string= session-name "none")
|
|
(require 'inferior-picolisp)
|
|
;; provide a reasonable default session name
|
|
(let ((session (or session-name "*inferior-picolisp*")))
|
|
;; check if we already have a live session by this name
|
|
(if (org-babel-comint-buffer-livep session)
|
|
(get-buffer session)
|
|
(save-window-excursion
|
|
(run-picolisp org-babel-picolisp-cmd)
|
|
(rename-buffer session-name)
|
|
(current-buffer))))))
|
|
|
|
(provide 'ob-picolisp)
|
|
|
|
|
|
|
|
;;; ob-picolisp.el ends here
|