mirror of
https://git.savannah.gnu.org/git/emacs/org-mode.git
synced 2024-08-25 15:02:53 +00:00
f95641c443
2013-11-12 Stefan Monnier <monnier@iro.umontreal.ca> Address some byte-compiler warnings. * ob-abc.el (org-babel-expand-body:abc): Use dolist. (org-babel-execute:abc): Fix regexp quoting. * ob-calc.el (org--var-syms): Rename from `var-syms'. * ob-lilypond.el (ly-compile-lilyfile): Remove redundant let-binding. * ob-table.el (sbe): Move debug declaration. * org-clock.el (org--msg-extra): Rename from `msg-extra'. * org.el (org-version): Avoid var name starting with _. (org-inhibit-startup, org-called-with-limited-levels) (org-link-search-inhibit-query, org-time-was-given) (org-end-time-was-given, org-def, org-defdecode, org-with-time): * org-colview.el (org-agenda-overriding-columns-format): * org-agenda.el (org-agenda-multi, org-depend-tag-blocked) (org-agenda-show-log-scoped): * ob-python.el (py-which-bufname, python-shell-buffer-name): * ob-haskell.el (org-export-copy-to-kill-ring): * ob-exp.el (org-link-search-inhibit-query): * ob-R.el (ess-eval-visibly-p): * ob-core.el (org-src-window-setup): Declare before use. (org-babel-expand-noweb-references): Remove unused `blocks-in-buffer'. * ox-odt.el (org-odt-hfy-face-to-css): * org-src.el (org-src-associate-babel-session, org-src-get-lang-mode): * org-bibtex.el (org-bibtex-get, org-bibtex-ask, org-bibtex) (org-bibtex-check): * ob-tangle.el (org-babel-tangle, org-babel-spec-to-string) (org-babel-tangle-single-block, org-babel-tangle-comment-links): * ob-table.el (sbe): * ob-sqlite.el (org-babel-sqlite-expand-vars): * ob-sql.el (org-babel-sql-expand-vars): * ob-shen.el (org-babel-execute:shen): * ob-sh.el (org-babel-execute:sh, org-babel-sh-evaluate): * ob-scala.el (org-babel-scala-evaluate): * ob-ruby.el (org-babel-ruby-table-or-string) (org-babel-ruby-evaluate): * ob-python.el (org-babel-python-table-or-string) (org-babel-python-evaluate-external-process) (org-babel-python-evaluate-session): * ob-picolisp.el (org-babel-execute:picolisp): * ob-perl.el (org-babel-perl-evaluate): * ob-maxima.el (org-babel-execute:maxima): * ob-lisp.el (org-babel-execute:lisp): * ob-java.el (org-babel-execute:java): * ob-io.el (org-babel-io-evaluate): * ob-haskell.el (org-babel-execute:haskell): * ob-fortran.el (org-babel-execute:fortran): * ob-exp.el (org-babel-exp-code): * ob-emacs-lisp.el (org-babel-execute:emacs-lisp): * ob-ditaa.el (org-babel-execute:ditaa): * ob-core.el (org-babel-execute-src-block, org-babel-sha1-hash) (org-babel-parse-header-arguments, org-babel-reassemble-table) (org-babel-goto-src-block-head, org-babel-mark-block) (org-babel-expand-noweb-references, org-babel-script-escape) (org-babel-process-file-name): * ob-clojure.el (org-babel-execute:clojure): * ob-calc.el (org-babel-execute:calc): * ob-awk.el (org-babel-execute:awk): * ob-abc.el (org-babel-execute:abc): * ob-R.el (org-babel-expand-body:R): * ob-C.el (org-babel-C-execute): Avoid deprecated ((lambda) ...). 2013-11-12 Glenn Morris <rgm@gnu.org> * ox-html.el (org-html-scripts): Add 2013 to copyright years. (org-html-infojs-template): Copyright holder to FSF.
110 lines
3.8 KiB
EmacsLisp
110 lines
3.8 KiB
EmacsLisp
;;; ob-lisp.el --- org-babel functions for common lisp evaluation
|
|
|
|
;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
|
|
|
|
;; Authors: Joel Boehland
|
|
;; Eric Schulte
|
|
;; David T. O'Toole <dto@gnu.org>
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; support for evaluating common lisp code, relies on slime for all eval
|
|
|
|
;;; Requirements:
|
|
|
|
;; Requires SLIME (Superior Lisp Interaction Mode for Emacs.)
|
|
;; See http://common-lisp.net/project/slime/
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(declare-function slime-eval "ext:slime" (sexp &optional package))
|
|
|
|
(defvar org-babel-tangle-lang-exts)
|
|
(add-to-list 'org-babel-tangle-lang-exts '("lisp" . "lisp"))
|
|
|
|
(defvar org-babel-default-header-args:lisp '())
|
|
(defvar org-babel-header-args:lisp '((package . :any)))
|
|
|
|
(defcustom org-babel-lisp-dir-fmt
|
|
"(let ((*default-pathname-defaults* #P%S)) %%s)"
|
|
"Format string used to wrap code bodies to set the current directory.
|
|
For example a value of \"(progn ;; %s\\n %%s)\" would ignore the
|
|
current directory string."
|
|
:group 'org-babel
|
|
:version "24.1"
|
|
:type 'string)
|
|
|
|
(defun org-babel-expand-body:lisp (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
|
|
(result-params (cdr (assoc :result-params params)))
|
|
(print-level nil) (print-length nil)
|
|
(body (org-babel-trim
|
|
(if (> (length vars) 0)
|
|
(concat "(let ("
|
|
(mapconcat
|
|
(lambda (var)
|
|
(format "(%S (quote %S))" (car var) (cdr var)))
|
|
vars "\n ")
|
|
")\n" body ")")
|
|
body))))
|
|
(if (or (member "code" result-params)
|
|
(member "pp" result-params))
|
|
(format "(pprint %s)" body)
|
|
body)))
|
|
|
|
(defun org-babel-execute:lisp (body params)
|
|
"Execute a block of Common Lisp code with Babel."
|
|
(require 'slime)
|
|
(org-babel-reassemble-table
|
|
(let ((result
|
|
(with-temp-buffer
|
|
(insert (org-babel-expand-body:lisp body params))
|
|
(slime-eval `(swank:eval-and-grab-output
|
|
,(let ((dir (if (assoc :dir params)
|
|
(cdr (assoc :dir params))
|
|
default-directory)))
|
|
(format
|
|
(if dir (format org-babel-lisp-dir-fmt dir)
|
|
"(progn %s)")
|
|
(buffer-substring-no-properties
|
|
(point-min) (point-max)))))
|
|
(cdr (assoc :package params))))))
|
|
(org-babel-result-cond (cdr (assoc :result-params params))
|
|
(car result)
|
|
(condition-case nil
|
|
(read (org-babel-lisp-vector-to-list (cadr result)))
|
|
(error (cadr result)))))
|
|
(org-babel-pick-name (cdr (assoc :colname-names params))
|
|
(cdr (assoc :colnames params)))
|
|
(org-babel-pick-name (cdr (assoc :rowname-names params))
|
|
(cdr (assoc :rownames params)))))
|
|
|
|
(defun org-babel-lisp-vector-to-list (results)
|
|
;; TODO: better would be to replace #(...) with [...]
|
|
(replace-regexp-in-string "#(" "(" results))
|
|
|
|
(provide 'ob-lisp)
|
|
|
|
|
|
|
|
;;; ob-lisp.el ends here
|