forked from mirrors/org-mode
* org-exp.el (org-export-kill-product-buffer-when-displayed) (org-export-initial-scope, org-export-date-timestamp-format) (org-export-with-tasks, org-export-email-info) (org-export-table-remove-empty-lines): Add version tag. * org-mobile.el (org-mobile-files-exclude-regexp) (org-mobile-use-encryption, org-mobile-encryption-tempfile) (org-mobile-encryption-password, org-mobile-agendas): Add version tag. * ob-plantuml.el (org-plantuml-jar-path): Add version tag. * org.el (org-babel-load-languages, org-clone-delete-id) (org-log-buffer-setup-hook) (org-loop-over-headlines-in-active-region) (org-use-sub-superscripts, org-startup-with-beamer-mode) (org-startup-with-inline-images, org-ctrl-k-protect-subtree) (org-catch-invisible-edits) (org-link-search-must-match-exact-headline) (org-confirm-shell-link-not-regexp) (org-confirm-elisp-link-not-regexp, org-log-refile) (org-refile-use-cache) (org-refile-active-region-within-subtree) (org-todo-repeat-to-state, org-get-priority-function) (org-agenda-jump-prefer-future) (org-read-date-force-compatible-dates) (org-use-effective-time) (org-complete-tags-always-offer-all-agenda-tags) (org-properties-postprocess-alist) (org-format-latex-signal-error) (org-latex-to-mathml-jar-file) (org-latex-to-mathml-convert-command) (org-export-latex-default-packages-alist) (org-hidden-keywords, org-pretty-entities) (org-pretty-entities-include-sub-superscripts) (org-src-fontify-natively, org-effort-durations) (org-speed-command-hook): Add version tag. * org-html.el (org-export-html-footnote-separator) (org-export-html-mathjax-options) (org-export-html-mathjax-template) (org-export-html-headline-anchor-format) (org-export-html-preamble-format) (org-export-html-postamble-format) (org-export-html-table-align-individual-fields) (org-export-html-protect-char-alist, org-export-html-divs): Add version tag. * org-ctags.el (org-ctags-path-to-ctags) (org-ctags-open-link-functions) (org-ctags-new-topic-template): Add version tag. * ob-exp.el (org-export-babel-evaluate): Add version tag. * org-beamer.el (org-beamer-use-parts) (org-beamer-frame-level, org-beamer-frame-default-options) (org-beamer-column-view-format, org-beamer-themes) (org-beamer-environments-extra, org-beamer-fragile-re) (org-beamer-outline-frame-title) (org-beamer-outline-frame-options): Add version tag. * org-wl.el (org-wl-link-remove-filter) (org-wl-shimbun-prefer-web-links) (org-wl-nntp-prefer-web-links, org-wl-disable-folder-check) (org-wl-namazu-default-index): Add version tag. * org-clock.el (org-task-overrun-text) (org-clocktable-defaults, org-clock-clocktable-formatter) (org-clock-clocktable-language-setup) (org-clock-report-include-clocking-task) (org-clock-resolve-expert): Add version tag. * ob-lob.el (org-babel-lob-files): Add version tag. * org-freemind.el (org-freemind-node-css-style): Add version tag. * org-archive.el (org-archive-reversed-order) (org-archive-subtree-add-inherited-tags): Add version tag. * org-bibtex.el (org-bibtex-autogen-keys, org-bibtex-prefix) (org-bibtex-treat-headline-as-title) (org-bibtex-export-arbitrary-fields) (org-bibtex-key-property, org-bibtex-tags) (org-bibtex-tags-are-keywords, org-bibtex-no-export-tags) (org-bibtex-type-property-name): Add version tag. * org-timer.el (org-timer-default-timer): Add version tag. * org-taskjuggler.el (org-export-taskjuggler-extension) (org-export-taskjuggler-project-tag) (org-export-taskjuggler-resource-tag) (org-export-taskjuggler-target-version) (org-export-taskjuggler-default-project-version) (org-export-taskjuggler-default-project-duration) (org-export-taskjuggler-default-reports) (org-export-taskjuggler-default-global-properties): Add version tag. * org-habit.el (org-habit-today-glyph) (org-habit-completed-glyph): Add version tag. * org-list.el (org-alphabetical-lists) (org-list-ending-method, org-list-end-regexp) (org-list-automatic-rules, org-list-use-circular-motion) (org-list-indent-offset): Add version tag. * ob-picolisp.el (org-babel-picolisp-cmd): Add version tag. * org-icalendar.el (org-icalendar-alarm-time) (org-icalendar-combined-description) (org-icalendar-honor-noexport-tag) (org-icalendar-date-time-format): Add version tag. * org-src.el (org-src-tab-acts-natively): Add version tag. * org-exp-blocks.el (org-export-blocks-postblock-hook): Add version tag. * org-table.el (org-table-exit-follow-field-mode-when-leaving-table) (org-table-fix-formulas-confirm) (org-table-duration-custom-format) (org-table-formula-field-format): Add version tag. * org-publish.el (org-publish-sitemap-sort-files) (org-publish-sitemap-sort-folders) (org-publish-sitemap-sort-ignore-case) (org-publish-sitemap-date-format) (org-publish-sitemap-file-entry-format): Add version tag. * ob-js.el (org-babel-js-cmd): Add version tag. * org-docbook.el (org-export-docbook-footnote-separator) (org-export-docbook-xslt-stylesheet): Add version tag. * org-entities.el (org-entities-ascii-explanatory) (org-entities-user): Add version tag. * ob.el (org-confirm-babel-evaluate) (org-babel-no-eval-on-ctrl-c-ctrl-c): Add version tag. * ob-tangle.el (org-babel-tangle-lang-exts) (org-babel-post-tangle-hook, org-babel-pre-tangle-hook) (org-babel-tangle-body-hook) (org-babel-tangle-comment-format-beg) (org-babel-tangle-comment-format-end) (org-babel-process-comment-text): Add version tag. * org-gnus.el (org-gnus-nnimap-query-article-no-from-file): Add version tag. * org-crypt.el (org-crypt-disable-auto-save): Add version tag. * org-inlinetask.el (org-inlinetask-default-state): Add version tag. * ob-scheme.el (org-babel-scheme-cmd): Add version tag. * ob-lisp.el (org-babel-lisp-dir-fmt): Add version tag. * org-attach.el (org-attach-store-link-p): Add version tag. * org-capture.el (org-capture-templates) (org-capture-before-finalize-hook) (org-capture-after-finalize-hook): Add version tag. * org-agenda.el (org-agenda-skip-deadline-prewarning-if-scheduled) (org-agenda-time-leading-zero, org-agenda-follow-indirect) (org-agenda-menu-two-column, org-agenda-menu-show-matcher) (org-agenda-timegrid-use-ampm) (org-agenda-remove-timeranges-from-blocks) (org-agenda-inactive-leader, org-agenda-current-time-string) (org-agenda-show-current-time-in-grid) (org-agenda-search-view-force-full-words) (org-agenda-search-view-always-boolean) (org-agenda-clock-consistency-checks) (org-agenda-include-deadlines) (org-agenda-move-date-from-past-immediately-to-today) (org-agenda-day-face-function) (org-agenda-category-icon-alist) (org-agenda-bulk-custom-functions) (org-agenda-insert-diary-extract-time): Add version tag. * org-latex.el (org-export-latex-inputenc-alist) (org-export-latex-tag-markup) (org-export-latex-timestamp-inactive-markup) (org-export-latex-href-format) (org-export-latex-hyperref-format) (org-export-latex-footnote-separator) (org-export-latex-quotes) (org-export-latex-table-caption-above) (org-export-latex-listings-w-names) (org-export-latex-minted-langs) (org-export-latex-listings-options) (org-export-latex-minted-options) (org-latex-default-figure-position, org-export-pdf-logfiles): Add version tag. * org-faces.el (org-faces-easy-properties) (org-fontify-quote-and-verse-blocks, org-cycle-level-faces): Add version tag. * ob-ditaa.el (org-ditaa-jar-option): Add version tag. Thanks to Glenn Morris for reporting this.
373 lines
13 KiB
EmacsLisp
373 lines
13 KiB
EmacsLisp
;;; org-habit.el --- The habit tracking code for Org-mode
|
|
|
|
;; Copyright (C) 2009-2012 Free Software Foundation, Inc.
|
|
|
|
;; Author: John Wiegley <johnw at gnu dot org>
|
|
;; Keywords: outlines, hypermedia, calendar, wp
|
|
;; Homepage: http://orgmode.org
|
|
;;
|
|
;; This file is part of GNU Emacs.
|
|
;;
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;;
|
|
;;; Commentary:
|
|
|
|
;; This file contains the habit tracking code for Org-mode
|
|
|
|
;;; Code:
|
|
|
|
(require 'org)
|
|
(require 'org-agenda)
|
|
|
|
(eval-when-compile
|
|
(require 'cl))
|
|
|
|
(defgroup org-habit nil
|
|
"Options concerning habit tracking in Org-mode."
|
|
:tag "Org Habit"
|
|
:group 'org-progress)
|
|
|
|
(defcustom org-habit-graph-column 40
|
|
"The absolute column at which to insert habit consistency graphs.
|
|
Note that consistency graphs will overwrite anything else in the buffer."
|
|
:group 'org-habit
|
|
:type 'integer)
|
|
|
|
(defcustom org-habit-preceding-days 21
|
|
"Number of days before today to appear in consistency graphs."
|
|
:group 'org-habit
|
|
:type 'integer)
|
|
|
|
(defcustom org-habit-following-days 7
|
|
"Number of days after today to appear in consistency graphs."
|
|
:group 'org-habit
|
|
:type 'integer)
|
|
|
|
(defcustom org-habit-show-habits t
|
|
"If non-nil, show habits in agenda buffers."
|
|
:group 'org-habit
|
|
:type 'boolean)
|
|
|
|
(defcustom org-habit-show-habits-only-for-today t
|
|
"If non-nil, only show habits on today's agenda, and not for future days.
|
|
Note that even when shown for future days, the graph is always
|
|
relative to the current effective date."
|
|
:group 'org-habit
|
|
:type 'boolean)
|
|
|
|
(defcustom org-habit-today-glyph ?!
|
|
"Glyph character used to identify today."
|
|
:group 'org-habit
|
|
:version "24.1"
|
|
:type 'character)
|
|
|
|
(defcustom org-habit-completed-glyph ?*
|
|
"Glyph character used to show completed days on which a task was done."
|
|
:group 'org-habit
|
|
:version "24.1"
|
|
:type 'character)
|
|
|
|
(defface org-habit-clear-face
|
|
'((((background light)) (:background "#8270f9"))
|
|
(((background dark)) (:background "blue")))
|
|
"Face for days on which a task shouldn't be done yet."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
(defface org-habit-clear-future-face
|
|
'((((background light)) (:background "#d6e4fc"))
|
|
(((background dark)) (:background "midnightblue")))
|
|
"Face for future days on which a task shouldn't be done yet."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
|
|
(defface org-habit-ready-face
|
|
'((((background light)) (:background "#4df946"))
|
|
(((background dark)) (:background "forestgreen")))
|
|
"Face for days on which a task should start to be done."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
(defface org-habit-ready-future-face
|
|
'((((background light)) (:background "#acfca9"))
|
|
(((background dark)) (:background "darkgreen")))
|
|
"Face for days on which a task should start to be done."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
|
|
(defface org-habit-alert-face
|
|
'((((background light)) (:background "#f5f946"))
|
|
(((background dark)) (:background "gold")))
|
|
"Face for days on which a task is due."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
(defface org-habit-alert-future-face
|
|
'((((background light)) (:background "#fafca9"))
|
|
(((background dark)) (:background "darkgoldenrod")))
|
|
"Face for days on which a task is due."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
|
|
(defface org-habit-overdue-face
|
|
'((((background light)) (:background "#f9372d"))
|
|
(((background dark)) (:background "firebrick")))
|
|
"Face for days on which a task is overdue."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
(defface org-habit-overdue-future-face
|
|
'((((background light)) (:background "#fc9590"))
|
|
(((background dark)) (:background "darkred")))
|
|
"Face for days on which a task is overdue."
|
|
:group 'org-habit
|
|
:group 'org-faces)
|
|
|
|
(defun org-habit-duration-to-days (ts)
|
|
(if (string-match "\\([0-9]+\\)\\([dwmy]\\)" ts)
|
|
;; lead time is specified.
|
|
(floor (* (string-to-number (match-string 1 ts))
|
|
(cdr (assoc (match-string 2 ts)
|
|
'(("d" . 1) ("w" . 7)
|
|
("m" . 30.4) ("y" . 365.25))))))
|
|
(error "Invalid duration string: %s" ts)))
|
|
|
|
(defun org-is-habit-p (&optional pom)
|
|
"Is the task at POM or point a habit?"
|
|
(string= "habit" (org-entry-get (or pom (point)) "STYLE")))
|
|
|
|
(defun org-habit-parse-todo (&optional pom)
|
|
"Parse the TODO surrounding point for its habit-related data.
|
|
Returns a list with the following elements:
|
|
|
|
0: Scheduled date for the habit (may be in the past)
|
|
1: \".+\"-style repeater for the schedule, in days
|
|
2: Optional deadline (nil if not present)
|
|
3: If deadline, the repeater for the deadline, otherwise nil
|
|
4: A list of all the past dates this todo was mark closed
|
|
|
|
This list represents a \"habit\" for the rest of this module."
|
|
(save-excursion
|
|
(if pom (goto-char pom))
|
|
(assert (org-is-habit-p (point)))
|
|
(let* ((scheduled (org-get-scheduled-time (point)))
|
|
(scheduled-repeat (org-get-repeat org-scheduled-string))
|
|
(end (org-entry-end-position))
|
|
(habit-entry (org-no-properties (nth 4 (org-heading-components))))
|
|
closed-dates deadline dr-days sr-days)
|
|
(if scheduled
|
|
(setq scheduled (time-to-days scheduled))
|
|
(error "Habit %s has no scheduled date" habit-entry))
|
|
(unless scheduled-repeat
|
|
(error
|
|
"Habit '%s' has no scheduled repeat period or has an incorrect one"
|
|
habit-entry))
|
|
(setq sr-days (org-habit-duration-to-days scheduled-repeat))
|
|
(unless (> sr-days 0)
|
|
(error "Habit %s scheduled repeat period is less than 1d" habit-entry))
|
|
(when (string-match "/\\([0-9]+[dwmy]\\)" scheduled-repeat)
|
|
(setq dr-days (org-habit-duration-to-days
|
|
(match-string-no-properties 1 scheduled-repeat)))
|
|
(if (<= dr-days sr-days)
|
|
(error "Habit %s deadline repeat period is less than or equal to scheduled (%s)"
|
|
habit-entry scheduled-repeat))
|
|
(setq deadline (+ scheduled (- dr-days sr-days))))
|
|
(org-back-to-heading t)
|
|
(let* ((maxdays (+ org-habit-preceding-days org-habit-following-days))
|
|
(reversed org-log-states-order-reversed)
|
|
(search (if reversed 're-search-forward 're-search-backward))
|
|
(limit (if reversed end (point)))
|
|
(count 0))
|
|
(unless reversed (goto-char end))
|
|
(while (and (< count maxdays)
|
|
(funcall search "- State \"DONE\".*\\[\\([^]]+\\)\\]" limit t))
|
|
(push (time-to-days
|
|
(org-time-string-to-time (match-string-no-properties 1)))
|
|
closed-dates)
|
|
(setq count (1+ count))))
|
|
(list scheduled sr-days deadline dr-days closed-dates))))
|
|
|
|
(defsubst org-habit-scheduled (habit)
|
|
(nth 0 habit))
|
|
(defsubst org-habit-scheduled-repeat (habit)
|
|
(nth 1 habit))
|
|
(defsubst org-habit-deadline (habit)
|
|
(let ((deadline (nth 2 habit)))
|
|
(or deadline
|
|
(if (nth 3 habit)
|
|
(+ (org-habit-scheduled habit)
|
|
(1- (org-habit-scheduled-repeat habit)))
|
|
(org-habit-scheduled habit)))))
|
|
(defsubst org-habit-deadline-repeat (habit)
|
|
(or (nth 3 habit)
|
|
(org-habit-scheduled-repeat habit)))
|
|
(defsubst org-habit-done-dates (habit)
|
|
(nth 4 habit))
|
|
|
|
(defsubst org-habit-get-priority (habit &optional moment)
|
|
"Determine the relative priority of a habit.
|
|
This must take into account not just urgency, but consistency as well."
|
|
(let ((pri 1000)
|
|
(now (if moment (time-to-days moment) (org-today)))
|
|
(scheduled (org-habit-scheduled habit))
|
|
(deadline (org-habit-deadline habit)))
|
|
;; add 10 for every day past the scheduled date, and subtract for every
|
|
;; day before it
|
|
(setq pri (+ pri (* (- now scheduled) 10)))
|
|
;; add 50 if the deadline is today
|
|
(if (and (/= scheduled deadline)
|
|
(= now deadline))
|
|
(setq pri (+ pri 50)))
|
|
;; add 100 for every day beyond the deadline date, and subtract 10 for
|
|
;; every day before it
|
|
(let ((slip (- now (1- deadline))))
|
|
(if (> slip 0)
|
|
(setq pri (+ pri (* slip 100)))
|
|
(setq pri (+ pri (* slip 10)))))
|
|
pri))
|
|
|
|
(defun org-habit-get-faces (habit &optional now-days scheduled-days donep)
|
|
"Return faces for HABIT relative to NOW-DAYS and SCHEDULED-DAYS.
|
|
NOW-DAYS defaults to the current time's days-past-the-epoch if nil.
|
|
SCHEDULED-DAYS defaults to the habit's actual scheduled days if nil.
|
|
|
|
Habits are assigned colors on the following basis:
|
|
Blue Task is before the scheduled date.
|
|
Green Task is on or after scheduled date, but before the
|
|
end of the schedule's repeat period.
|
|
Yellow If the task has a deadline, then it is after schedule's
|
|
repeat period, but before the deadline.
|
|
Orange The task has reached the deadline day, or if there is
|
|
no deadline, the end of the schedule's repeat period.
|
|
Red The task has gone beyond the deadline day or the
|
|
schedule's repeat period."
|
|
(let* ((scheduled (or scheduled-days (org-habit-scheduled habit)))
|
|
(s-repeat (org-habit-scheduled-repeat habit))
|
|
(scheduled-end (+ scheduled (1- s-repeat)))
|
|
(d-repeat (org-habit-deadline-repeat habit))
|
|
(deadline (if scheduled-days
|
|
(+ scheduled-days (- d-repeat s-repeat))
|
|
(org-habit-deadline habit)))
|
|
(m-days (or now-days (time-to-days (current-time)))))
|
|
(cond
|
|
((< m-days scheduled)
|
|
'(org-habit-clear-face . org-habit-clear-future-face))
|
|
((< m-days deadline)
|
|
'(org-habit-ready-face . org-habit-ready-future-face))
|
|
((= m-days deadline)
|
|
(if donep
|
|
'(org-habit-ready-face . org-habit-ready-future-face)
|
|
'(org-habit-alert-face . org-habit-alert-future-face)))
|
|
(t
|
|
'(org-habit-overdue-face . org-habit-overdue-future-face)))))
|
|
|
|
(defun org-habit-build-graph (habit starting current ending)
|
|
"Build a graph for the given HABIT, from STARTING to ENDING.
|
|
CURRENT gives the current time between STARTING and ENDING, for
|
|
the purpose of drawing the graph. It need not be the actual
|
|
current time."
|
|
(let* ((done-dates (sort (org-habit-done-dates habit) '<))
|
|
(scheduled (org-habit-scheduled habit))
|
|
(s-repeat (org-habit-scheduled-repeat habit))
|
|
(start (time-to-days starting))
|
|
(now (time-to-days current))
|
|
(end (time-to-days ending))
|
|
(graph (make-string (1+ (- end start)) ?\ ))
|
|
(index 0)
|
|
last-done-date)
|
|
(while (and done-dates (< (car done-dates) start))
|
|
(setq last-done-date (car done-dates)
|
|
done-dates (cdr done-dates)))
|
|
(while (< start end)
|
|
(let* ((in-the-past-p (< start now))
|
|
(todayp (= start now))
|
|
(donep (and done-dates
|
|
(= start (car done-dates))))
|
|
(faces (if (and in-the-past-p
|
|
(not last-done-date)
|
|
(not (< scheduled now)))
|
|
'(org-habit-clear-face . org-habit-clear-future-face)
|
|
(org-habit-get-faces
|
|
habit start (and in-the-past-p
|
|
(if last-done-date
|
|
(+ last-done-date s-repeat)
|
|
scheduled))
|
|
donep)))
|
|
markedp face)
|
|
(if donep
|
|
(let ((done-time (time-add
|
|
starting
|
|
(days-to-time
|
|
(- start (time-to-days starting))))))
|
|
|
|
(aset graph index org-habit-completed-glyph)
|
|
(setq markedp t)
|
|
(put-text-property
|
|
index (1+ index) 'help-echo
|
|
(format-time-string (org-time-stamp-format) done-time) graph)
|
|
(while (and done-dates
|
|
(= start (car done-dates)))
|
|
(setq last-done-date (car done-dates)
|
|
done-dates (cdr done-dates))))
|
|
(if todayp
|
|
(aset graph index org-habit-today-glyph)))
|
|
(setq face (if (or in-the-past-p todayp)
|
|
(car faces)
|
|
(cdr faces)))
|
|
(if (and in-the-past-p
|
|
(not (eq face 'org-habit-overdue-face))
|
|
(not markedp))
|
|
(setq face (cdr faces)))
|
|
(put-text-property index (1+ index) 'face face graph))
|
|
(setq start (1+ start)
|
|
index (1+ index)))
|
|
graph))
|
|
|
|
(defun org-habit-insert-consistency-graphs (&optional line)
|
|
"Insert consistency graph for any habitual tasks."
|
|
(let ((inhibit-read-only t) l c
|
|
(buffer-invisibility-spec '(org-link))
|
|
(moment (time-subtract (current-time)
|
|
(list 0 (* 3600 org-extend-today-until) 0))))
|
|
(save-excursion
|
|
(goto-char (if line (point-at-bol) (point-min)))
|
|
(while (not (eobp))
|
|
(let ((habit (get-text-property (point) 'org-habit-p)))
|
|
(when habit
|
|
(move-to-column org-habit-graph-column t)
|
|
(delete-char (min (+ 1 org-habit-preceding-days
|
|
org-habit-following-days)
|
|
(- (line-end-position) (point))))
|
|
(insert (org-habit-build-graph
|
|
habit
|
|
(time-subtract moment
|
|
(days-to-time org-habit-preceding-days))
|
|
moment
|
|
(time-add moment
|
|
(days-to-time org-habit-following-days))))))
|
|
(forward-line)))))
|
|
|
|
(defun org-habit-toggle-habits ()
|
|
"Toggle display of habits in an agenda buffer."
|
|
(interactive)
|
|
(org-agenda-check-type t 'agenda)
|
|
(setq org-habit-show-habits (not org-habit-show-habits))
|
|
(org-agenda-redo)
|
|
(org-agenda-set-mode-name)
|
|
(message "Habits turned %s"
|
|
(if org-habit-show-habits "on" "off")))
|
|
|
|
(org-defkey org-agenda-mode-map "K" 'org-habit-toggle-habits)
|
|
|
|
(provide 'org-habit)
|
|
|
|
;;; org-habit.el ends here
|