forked from mirrors/org-mode
6a1f6ee1f8
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
104 lines
3.5 KiB
EmacsLisp
104 lines
3.5 KiB
EmacsLisp
;;; ol-docview.el --- Links to Docview mode buffers -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Jan Böcker <jan.boecker at jboecker dot de>
|
|
;; Keywords: outlines, hypermedia, calendar, wp
|
|
;; Homepage: https://orgmode.org
|
|
;;
|
|
;; This file is part of GNU Emacs.
|
|
;;
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;;
|
|
;;; Commentary:
|
|
|
|
;; This file implements links to open files in doc-view-mode.
|
|
;; Org mode loads this module by default - if this is not what you want,
|
|
;; configure the variable `org-modules'.
|
|
|
|
;; The links take the form
|
|
;;
|
|
;; docview:<file path>::<page number>
|
|
;;
|
|
;; for example: [[docview:~/.elisp/org/doc/org.pdf::1][Org-Mode Manual]]
|
|
;;
|
|
;; Autocompletion for inserting links is supported; you will be
|
|
;; prompted for a file and a page number.
|
|
;;
|
|
;; If you use org-store-link in a doc-view mode buffer, the stored
|
|
;; link will point to the current page.
|
|
|
|
;;; Code:
|
|
|
|
|
|
(require 'doc-view)
|
|
(require 'ol)
|
|
|
|
(declare-function doc-view-goto-page "doc-view" (page))
|
|
(declare-function image-mode-window-get "image-mode" (prop &optional winprops))
|
|
(declare-function org-open-file "org" (path &optional in-emacs line search))
|
|
|
|
(org-link-set-parameters "docview"
|
|
:follow #'org-docview-open
|
|
:export #'org-docview-export
|
|
:store #'org-docview-store-link)
|
|
|
|
(defun org-docview-export (link description format)
|
|
"Export a docview link from Org files."
|
|
(let ((path (if (string-match "\\(.+\\)::.+" link) (match-string 1 link)
|
|
link))
|
|
(desc (or description link)))
|
|
(when (stringp path)
|
|
(setq path (expand-file-name path))
|
|
(cond
|
|
((eq format 'html) (format "<a href=\"%s\">%s</a>" path desc))
|
|
((eq format 'latex) (format "\\href{%s}{%s}" path desc))
|
|
((eq format 'ascii) (format "%s (%s)" desc path))
|
|
(t path)))))
|
|
|
|
(defun org-docview-open (link)
|
|
(string-match "\\(.*?\\)\\(?:::\\([0-9]+\\)\\)?$" link)
|
|
(let ((path (match-string 1 link))
|
|
(page (and (match-beginning 2)
|
|
(string-to-number (match-string 2 link)))))
|
|
;; Let Org mode open the file (in-emacs = 1) to ensure
|
|
;; org-link-frame-setup is respected.
|
|
(org-open-file path 1)
|
|
(when page (doc-view-goto-page page))))
|
|
|
|
(defun org-docview-store-link ()
|
|
"Store a link to a docview buffer."
|
|
(when (eq major-mode 'doc-view-mode)
|
|
;; This buffer is in doc-view-mode
|
|
(let* ((path buffer-file-name)
|
|
(page (image-mode-window-get 'page))
|
|
(link (concat "docview:" path "::" (number-to-string page))))
|
|
(org-link-store-props
|
|
:type "docview"
|
|
:link link
|
|
:description path))))
|
|
|
|
(defun org-docview-complete-link ()
|
|
"Use the existing file name completion for file.
|
|
Links to get the file name, then ask the user for the page number
|
|
and append it."
|
|
(concat (replace-regexp-in-string "^file:" "docview:" (org-link-complete-file))
|
|
"::"
|
|
(read-from-minibuffer "Page:" "1")))
|
|
|
|
(provide 'ol-docview)
|
|
|
|
;;; ol-docview.el ends here
|