forked from mirrors/org-mode
* lisp/ob-core.el (org-babel--get-vars): New function. (org-babel-get-header): Delete. * lisp/ob-C.el (org-babel-C-expand-C): (org-babel-C-expand-D): * lisp/ob-R.el (org-babel-variable-assignments:R): * lisp/ob-abc.el (org-babel-expand-body:abc): * lisp/ob-asymptote.el (org-babel-variable-assignments:asymptote): * lisp/ob-awk.el (org-babel-execute:awk): * lisp/ob-calc.el (org-babel-execute:calc): * lisp/ob-clojure.el (org-babel-expand-body:clojure): * lisp/ob-dot.el (org-babel-expand-body:dot): * lisp/ob-emacs-lisp.el (org-babel-expand-body:emacs-lisp): * lisp/ob-fortran.el (org-babel-expand-body:fortran): (org-babel-fortran-ensure-main-wrap): * lisp/ob-gnuplot.el (org-babel-gnuplot-process-vars): * lisp/ob-haskell.el (org-babel-variable-assignments:haskell): * lisp/ob-js.el (org-babel-variable-assignments:js): * lisp/ob-latex.el (org-babel-expand-body:latex): * lisp/ob-lilypond.el (org-babel-expand-body:lilypond): * lisp/ob-lisp.el (org-babel-expand-body:lisp): * lisp/ob-maxima.el (org-babel-maxima-expand): * lisp/ob-ocaml.el (org-babel-variable-assignments:ocaml): * lisp/ob-octave.el (org-babel-variable-assignments:octave): * lisp/ob-org.el (org-babel-expand-body:org): * lisp/ob-perl.el (org-babel-variable-assignments:perl): * lisp/ob-picolisp.el (org-babel-expand-body:picolisp): * lisp/ob-processing.el (org-babel-variable-assignments:processing): * lisp/ob-python.el (org-babel-variable-assignments:python): * lisp/ob-ruby.el (org-babel-variable-assignments:ruby): * lisp/ob-scheme.el (org-babel-expand-body:scheme): * lisp/ob-shell.el (org-babel-variable-assignments:shell): * lisp/ob-shen.el (org-babel-expand-body:shen): * lisp/ob-sql.el (org-babel-expand-body:sql): * lisp/ob-sqlite.el (org-babel-expand-body:sqlite): Adapt to change. * etc/ORG-NEWS: Document change.
93 lines
3.5 KiB
EmacsLisp
93 lines
3.5 KiB
EmacsLisp
;;; ob-abc.el --- Org Babel Functions for ABC -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) Free Software Foundation
|
|
|
|
;; Author: William Waites
|
|
;; Keywords: literate programming, music
|
|
;; Homepage: http://www.tardis.ed.ac.uk/wwaites
|
|
;; Version: 0.01
|
|
|
|
;;; License:
|
|
|
|
;; This program is free software; you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation; either version 3, or (at your option)
|
|
;; any later version.
|
|
;;
|
|
;; This program is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
;;
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs; see the file COPYING. If not, write to the
|
|
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
|
|
;; Boston, MA 02110-1301, USA.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; This file adds support to Org Babel for music in ABC notation.
|
|
;;; It requires that the abcm2ps program is installed.
|
|
;;; See http://moinejf.free.fr/
|
|
|
|
(require 'ob)
|
|
|
|
;; optionally define a file extension for this language
|
|
(add-to-list 'org-babel-tangle-lang-exts '("abc" . "abc"))
|
|
|
|
;; optionally declare default header arguments for this language
|
|
(defvar org-babel-default-header-args:abc
|
|
'((:results . "file") (:exports . "results"))
|
|
"Default arguments to use when evaluating an ABC source block.")
|
|
|
|
(defun org-babel-expand-body:abc (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let ((vars (org-babel--get-vars params)))
|
|
(mapc
|
|
(lambda (pair)
|
|
(let ((name (symbol-name (car pair)))
|
|
(value (cdr pair)))
|
|
(setq body
|
|
(replace-regexp-in-string
|
|
(concat "\$" (regexp-quote name))
|
|
(if (stringp value) value (format "%S" value))
|
|
body))))
|
|
vars)
|
|
body))
|
|
|
|
(defun org-babel-execute:abc (body params)
|
|
"Execute a block of ABC code with org-babel. This function is
|
|
called by `org-babel-execute-src-block'"
|
|
(message "executing Abc source code block")
|
|
(let* ((cmdline (cdr (assoc :cmdline params)))
|
|
(out-file (let ((file (cdr (assq :file params))))
|
|
(if file (replace-regexp-in-string "\.pdf$" ".ps" file)
|
|
(error "abc code block requires :file header argument"))))
|
|
(in-file (org-babel-temp-file "abc-"))
|
|
(render (concat "abcm2ps" " " cmdline
|
|
" -O " (org-babel-process-file-name out-file)
|
|
" " (org-babel-process-file-name in-file))))
|
|
(with-temp-file in-file (insert (org-babel-expand-body:abc body params)))
|
|
(org-babel-eval render "")
|
|
;;; handle where abcm2ps changes the file name (to support multiple files
|
|
(when (or (string= (file-name-extension out-file) "eps")
|
|
(string= (file-name-extension out-file) "svg"))
|
|
(rename-file (concat
|
|
(file-name-sans-extension out-file) "001."
|
|
(file-name-extension out-file))
|
|
out-file t))
|
|
;;; if we were asked for a pdf...
|
|
(when (string= (file-name-extension (cdr (assoc :file params))) "pdf")
|
|
(org-babel-eval (concat "ps2pdf" " " out-file " " (cdr (assoc :file params))) ""))
|
|
;;; indicate that the file has been written
|
|
nil))
|
|
|
|
;; This function should be used to assign any variables in params in
|
|
;; the context of the session environment.
|
|
(defun org-babel-prep-session:abc (_session _params)
|
|
"Return an error because abc does not support sessions."
|
|
(error "ABC does not support sessions"))
|
|
|
|
(provide 'ob-abc)
|
|
;;; ob-abc.el ends here
|