forked from mirrors/org-mode
* lisp/ox.el (org-export-table-dimensions): * lisp/ox-texinfo.el (org-texinfo-template): * lisp/ox-md.el (org-md-link): * lisp/ox-icalendar.el (org-icalendar-use-UTC-date-time-p): * lisp/ox-ascii.el (org-ascii-fixed-width): * lisp/org.el (org-context): * lisp/org-table.el (org-table-eval-formula) (org-table-export): * lisp/org-refile.el: * lisp/org-plot.el (org-plot/gnuplot-to-grid-data): * lisp/org-num.el (org-num): * lisp/org-mouse.el (org-mouse-popup-global-menu) (org-mouse-context-menu): * lisp/org-macro.el (org-macro): * lisp/org-lint.el (org-lint): * lisp/org-keys.el (org-keys): * lisp/org-duration.el: * lisp/org-clock.el (org-clock-get-last-clock-out-time) (org-clock-update-mode-line, org-find-open-clocks): * lisp/org-agenda.el (org-diary) (org-agenda-check-for-timestamp-as-reason-to-ignore-todo-item) (org-agenda-highlight-todo, org-cmp-alpha) (org-agenda-filter-by-category): * lisp/ol.el (org-link-expand-abbrev, ol): * lisp/ol-docview.el (ol-docview): * lisp/ol-bibtex.el (org-execute-file-search-in-bibtex) (org-bibtex, org-bibtex-read): * lisp/ol-bbdb.el (org-bbdb-anniversary-description): * lisp/ob-tangle.el (org-babel-tangle-jump-to-org): * lisp/ob-table.el (org-babel-table-truncate-at-newline): * lisp/ob-stan.el: * lisp/ob-sqlite.el (org-babel-sqlite-table-or-scalar): * lisp/ob-sql.el: * lisp/ob-shen.el: * lisp/ob-shell.el (org-babel-prep-session:shell) (org-babel-prep-session:shell): * lisp/ob-sed.el (org-babel-execute:sed) (org-babel-execute:sed): * lisp/ob-screen.el: * lisp/ob-sass.el: * lisp/ob-ruby.el (org-babel-prep-session:ruby) (org-babel-prep-session:ruby): * lisp/ob-ref.el (org-babel-ref-resolve, ob-ref): * lisp/ob-python.el (org-babel-prep-session:python) (org-babel-prep-session:python): * lisp/ob-plantuml.el: * lisp/ob-picolisp.el: * lisp/ob-perl.el: * lisp/ob-org.el: * lisp/ob-octave.el (org-babel-prep-session:octave) (org-babel-prep-session:octave) (org-babel-octave-evaluate-session): * lisp/ob-ocaml.el: * lisp/ob-mscgen.el (org-babel-execute:mscgen) (org-babel-execute:mscgen): * lisp/ob-maxima.el: (ob-maxima): * lisp/ob-matlab.el: * lisp/ob-makefile.el: * lisp/ob-lua.el (org-babel-prep-session:lua) (org-babel-prep-session:lua): * lisp/ob-lisp.el: * lisp/ob-ledger.el: * lisp/ob-latex.el (org-babel-expand-body:latex) (org-babel-expand-body:latex, ob-latex): * lisp/ob-js.el: * lisp/ob-java.el: * lisp/ob-io.el (org-babel-prep-session:io) (org-babel-prep-session:io): * lisp/ob-hledger.el: * lisp/ob-haskell.el: * lisp/ob-groovy.el (org-babel-groovy-wrapper-method) (org-babel-groovy-evaluate): * lisp/ob-gnuplot.el: * lisp/ob-fortran.el (org-babel-expand-body:fortran) (org-babel-expand-body:fortran): * lisp/ob-forth.el (org-babel-forth-session-execute): * lisp/ob-exp.el (ob-exp): * lisp/ob-eval.el: * lisp/ob-emacs-lisp.el: * lisp/ob-ebnf.el: * lisp/ob-dot.el: * lisp/ob-ditaa.el: * lisp/ob-css.el: * lisp/ob-core.el (org-babel-put-rownames): * lisp/ob-coq.el: * lisp/ob-comint.el: * lisp/ob-calc.el: * lisp/ob-awk.el: * lisp/ob-asymptote.el: * lisp/ob-abc.el: * lisp/ob-R.el (org-babel-prep-session:R): Formatting fixes.
129 lines
4.5 KiB
EmacsLisp
129 lines
4.5 KiB
EmacsLisp
;;; ob-maxima.el --- Babel Functions for Maxima -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2009-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric S Fraga
|
|
;; Eric Schulte
|
|
;; Keywords: literate programming, reproducible research, maxima
|
|
;; Homepage: https://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating maxima entries.
|
|
;;
|
|
;; This differs from most standard languages in that
|
|
;; 1) there is no such thing as a "session" in maxima
|
|
;; 2) we are adding the "cmdline" header argument
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(defvar org-babel-tangle-lang-exts)
|
|
(add-to-list 'org-babel-tangle-lang-exts '("maxima" . "max"))
|
|
|
|
(defvar org-babel-default-header-args:maxima '())
|
|
|
|
(defcustom org-babel-maxima-command
|
|
(if (boundp 'maxima-command) maxima-command "maxima")
|
|
"Command used to call maxima on the shell."
|
|
:group 'org-babel
|
|
:type 'string)
|
|
|
|
(defun org-babel-maxima-expand (body params)
|
|
"Expand a block of Maxima code according to its header arguments."
|
|
(let ((vars (org-babel--get-vars params))
|
|
(epilogue (cdr (assq :epilogue params)))
|
|
(prologue (cdr (assq :prologue params))))
|
|
(mapconcat 'identity
|
|
(list
|
|
;; Any code from the specified prologue at the start.
|
|
prologue
|
|
;; graphic output
|
|
(let ((graphic-file (ignore-errors (org-babel-graphical-output-file params))))
|
|
(if graphic-file
|
|
(format
|
|
"set_plot_option ([gnuplot_term, png]); set_plot_option ([gnuplot_out_file, %S]);"
|
|
graphic-file)
|
|
""))
|
|
;; variables
|
|
(mapconcat 'org-babel-maxima-var-to-maxima vars "\n")
|
|
;; body
|
|
body
|
|
;; Any code from the specified epilogue at the end.
|
|
epilogue
|
|
"gnuplot_close ()$")
|
|
"\n")))
|
|
|
|
(defun org-babel-execute:maxima (body params)
|
|
"Execute a block of Maxima entries with org-babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(message "executing Maxima source code block")
|
|
(let ((result-params (split-string (or (cdr (assq :results params)) "")))
|
|
(result
|
|
(let* ((cmdline (or (cdr (assq :cmdline params)) ""))
|
|
(in-file (org-babel-temp-file "maxima-" ".max"))
|
|
(cmd (format "%s --very-quiet -r 'batchload(%S)$' %s"
|
|
org-babel-maxima-command in-file cmdline)))
|
|
(with-temp-file in-file (insert (org-babel-maxima-expand body params)))
|
|
(message cmd)
|
|
;; " | grep -v batch | grep -v 'replaced' | sed '/^$/d' "
|
|
(let ((raw (org-babel-eval cmd "")))
|
|
(mapconcat
|
|
#'identity
|
|
(delq nil
|
|
(mapcar (lambda (line)
|
|
(unless (or (string-match "batch" line)
|
|
(string-match "^rat: replaced .*$" line)
|
|
(string-match "^;;; Loading #P" line)
|
|
(= 0 (length line)))
|
|
line))
|
|
(split-string raw "[\r\n]"))) "\n")))))
|
|
(if (ignore-errors (org-babel-graphical-output-file params))
|
|
nil
|
|
(org-babel-result-cond result-params
|
|
result
|
|
(let ((tmp-file (org-babel-temp-file "maxima-res-")))
|
|
(with-temp-file tmp-file (insert result))
|
|
(org-babel-import-elisp-from-file tmp-file))))))
|
|
|
|
|
|
(defun org-babel-prep-session:maxima (_session _params)
|
|
(error "Maxima does not support sessions"))
|
|
|
|
(defun org-babel-maxima-var-to-maxima (pair)
|
|
"Convert an elisp val into a string of maxima code specifying a var
|
|
of the same value."
|
|
(let ((var (car pair))
|
|
(val (cdr pair)))
|
|
(when (symbolp val)
|
|
(setq val (symbol-name val))
|
|
(when (= (length val) 1)
|
|
(setq val (string-to-char val))))
|
|
(format "%S: %s$" var
|
|
(org-babel-maxima-elisp-to-maxima val))))
|
|
|
|
(defun org-babel-maxima-elisp-to-maxima (val)
|
|
"Return a string of maxima code which evaluates to VAL."
|
|
(if (listp val)
|
|
(concat "[" (mapconcat #'org-babel-maxima-elisp-to-maxima val ", ") "]")
|
|
(format "%s" val)))
|
|
|
|
(provide 'ob-maxima)
|
|
|
|
;;; ob-maxima.el ends here
|