forked from mirrors/org-mode
* lisp/org-capture.el (org-capture-member): Make obsolete; the old definition was identical to ‘org-capture-get’ anyway. (org-capture-mode-map): Move the calls to ‘define-key’ up to where the variable is defined. (org-capture-mode-hook): Small docstring tweak. (org-capture-mode): Fix typo in mode lighter. (org-capture-set-target-location, org-capture-place-item): (org-capture-place-plain-text, org-capture-narrow): (org-capture-empty-lines-after): (org-capture-import-remember-templates): ‘if’ without else -> ‘when’ * lisp/org-colview.el (org-columns-edit-value): Change an error to a user-error. (org-columns-uncompile-format): Improve docstring. * lisp/org-compat.el (org-remove-from-invisibility-spec): Make obsolete, the underlying emacs function exists since 1997, commit 31aa282e. (org-in-invisibility-spec-p, org-count-lines): ‘if’ without else -> ‘when’. * lisp/org-element.el (org-element-swap-A-B): * lisp/org-entities.el (org-entities-create-table): * lisp/org-list.el (org-insert-item): * lisp/org-macs.el (org-with-point-at, org-base-buffer): (org-preserve-local-variables, org-overlay-display): (org-overlay-before-string): ‘if’ without else -> ‘when’. * lisp/org-eshell.el (org-eshell-open): Fix docstring typo. * lisp/org-pcomplete.el (pcomplete/org-mode/file-option/language): (pcomplete/org-mode/file-option/startup): (pcomplete/org-mode/file-option/options): (pcomplete/org-mode/file-option/infojs_opt): (pcomplete/org-mode/link, pcomplete/org-mode/tex): (pcomplete/org-mode/todo, pcomplete/org-mode/searchhead): (pcomplete/org-mode/tag, pcomplete/org-mode/prop): Avoid the formerly misspelled ‘pcomplete-uniqify-list’ function. It has a defalias in emacs >= 27; we add our own for older emacsen. (pcomplete/org-mode/file-option/bind): ‘if’ without else -> ‘when’. * lisp/org-protocol.el (org-protocol-capture): (org-protocol-convert-query-to-plist): ‘if’ without else -> ‘when’. (org-protocol-do-capture): Pacify byte compiler, simplify conditional logic. * lisp/org-table.el (org-table-create-with-table.el): Simplify conditional logic. (org-table-create, org-table-convert-region, org-table-next-field): (org-table-beginning-of-field, org-table-end-of-field): * lisp/org-w3m.el (org-w3m-copy-for-org-mode): ‘if’ without else -> ‘when’. * lisp/org.el (org-babel-do-load-languages, org-previous-link): (org-refile): Use ‘(foo ...)’ instead of ‘(funcall 'foo ...)’. (org-add-log-note): Convert a long cond into a cl-case. (org-priority): Improve docstring, show a deprecation warning if the ‘show’ argument is passed (which was previously silently ignored). Also, use ?\s instead of ?\ as a character literal for space. (org-fast-tag-insert): Fix docstring typo. (org-fill-element): ‘if’ without else -> ‘when’. (org-on-target-p): Remove ancient compatibility alias.
185 lines
7.3 KiB
EmacsLisp
185 lines
7.3 KiB
EmacsLisp
;;; org-w3m.el --- Support from Copy and Paste From w3m -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2008-2018 Free Software Foundation, Inc.
|
|
|
|
;; Author: Andy Stewart <lazycat dot manatee at gmail dot com>
|
|
;; Keywords: outlines, hypermedia, calendar, wp
|
|
;; Homepage: https://orgmode.org
|
|
;;
|
|
;; This file is part of GNU Emacs.
|
|
;;
|
|
;; This program is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; This program is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;;
|
|
;;; Commentary:
|
|
|
|
;; This file implements copying HTML content from a w3m buffer and
|
|
;; transforming the text on the fly so that it can be pasted into an
|
|
;; Org buffer with hot links. It will also work for regions in gnus
|
|
;; buffers that have been washed with w3m.
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;;
|
|
;;; Acknowledgments:
|
|
|
|
;; Richard Riley <rileyrgdev at googlemail dot com>
|
|
;;
|
|
;; The idea of transforming the HTML content with Org syntax is
|
|
;; proposed by Richard, I'm just coding it.
|
|
;;
|
|
|
|
;;; Code:
|
|
|
|
(require 'org)
|
|
|
|
(defvar w3m-current-url)
|
|
(defvar w3m-current-title)
|
|
|
|
(org-link-set-parameters "w3m" :store #'org-w3m-store-link)
|
|
(defun org-w3m-store-link ()
|
|
"Store a link to a w3m buffer."
|
|
(when (eq major-mode 'w3m-mode)
|
|
(org-store-link-props
|
|
:type "w3m"
|
|
:link w3m-current-url
|
|
:url (url-view-url t)
|
|
:description (or w3m-current-title w3m-current-url))))
|
|
|
|
(defun org-w3m-copy-for-org-mode ()
|
|
"Copy current buffer content or active region with Org style links.
|
|
This will encode `link-title' and `link-location' with
|
|
`org-make-link-string', and insert the transformed test into the kill ring,
|
|
so that it can be yanked into an Org buffer with links working correctly."
|
|
(interactive)
|
|
(let* ((regionp (org-region-active-p))
|
|
(transform-start (point-min))
|
|
(transform-end (point-max))
|
|
return-content
|
|
link-location link-title
|
|
temp-position out-bound)
|
|
(when regionp
|
|
(setq transform-start (region-beginning))
|
|
(setq transform-end (region-end))
|
|
;; Deactivate mark if current mark is activate.
|
|
(when (fboundp 'deactivate-mark) (deactivate-mark)))
|
|
(message "Transforming links...")
|
|
(save-excursion
|
|
(goto-char transform-start)
|
|
(while (and (not out-bound) ; still inside region to copy
|
|
(not (org-w3m-no-next-link-p))) ; no next link current buffer
|
|
;; store current point before jump next anchor
|
|
(setq temp-position (point))
|
|
;; move to next anchor when current point is not at anchor
|
|
(or (get-text-property (point) 'w3m-href-anchor) (org-w3m-get-next-link-start))
|
|
(if (<= (point) transform-end) ; if point is inside transform bound
|
|
(progn
|
|
;; get content between two links.
|
|
(when (> (point) temp-position)
|
|
(setq return-content (concat return-content
|
|
(buffer-substring
|
|
temp-position (point)))))
|
|
;; get link location at current point.
|
|
(setq link-location (get-text-property (point) 'w3m-href-anchor))
|
|
;; get link title at current point.
|
|
(setq link-title (buffer-substring (point)
|
|
(org-w3m-get-anchor-end)))
|
|
;; concat Org style url to `return-content'.
|
|
(setq return-content
|
|
(concat return-content
|
|
(if (org-string-nw-p link-location)
|
|
(org-make-link-string link-location link-title)
|
|
link-title))))
|
|
(goto-char temp-position) ; reset point before jump next anchor
|
|
(setq out-bound t))) ; for break out `while' loop
|
|
;; add the rest until end of the region to be copied
|
|
(when (< (point) transform-end)
|
|
(setq return-content
|
|
(concat return-content
|
|
(buffer-substring (point) transform-end))))
|
|
(org-kill-new return-content)
|
|
(message "Transforming links...done, use C-y to insert text into Org file")
|
|
(message "Copy with link transformation complete."))))
|
|
|
|
(defun org-w3m-get-anchor-start ()
|
|
"Move cursor to the start of current anchor. Return point."
|
|
;; get start position of anchor or current point
|
|
(goto-char (or (previous-single-property-change (point) 'w3m-anchor-sequence)
|
|
(point))))
|
|
|
|
(defun org-w3m-get-anchor-end ()
|
|
"Move cursor to the end of current anchor. Return point."
|
|
;; get end position of anchor or point
|
|
(goto-char (or (next-single-property-change (point) 'w3m-anchor-sequence)
|
|
(point))))
|
|
|
|
(defun org-w3m-get-next-link-start ()
|
|
"Move cursor to the start of next link. Return point."
|
|
(catch 'reach
|
|
(while (next-single-property-change (point) 'w3m-anchor-sequence)
|
|
;; jump to next anchor
|
|
(goto-char (next-single-property-change (point) 'w3m-anchor-sequence))
|
|
(when (get-text-property (point) 'w3m-href-anchor)
|
|
;; return point when current is valid link
|
|
(throw 'reach nil))))
|
|
(point))
|
|
|
|
(defun org-w3m-get-prev-link-start ()
|
|
"Move cursor to the start of previous link. Return point."
|
|
(catch 'reach
|
|
(while (previous-single-property-change (point) 'w3m-anchor-sequence)
|
|
;; jump to previous anchor
|
|
(goto-char (previous-single-property-change (point) 'w3m-anchor-sequence))
|
|
(when (get-text-property (point) 'w3m-href-anchor)
|
|
;; return point when current is valid link
|
|
(throw 'reach nil))))
|
|
(point))
|
|
|
|
(defun org-w3m-no-next-link-p ()
|
|
"Whether there is no next link after the cursor.
|
|
Return t if there is no next link; otherwise, return nil."
|
|
(save-excursion
|
|
(equal (point) (org-w3m-get-next-link-start))))
|
|
|
|
(defun org-w3m-no-prev-link-p ()
|
|
"Whether there is no previous link after the cursor.
|
|
Return t if there is no previous link; otherwise, return nil."
|
|
(save-excursion
|
|
(equal (point) (org-w3m-get-prev-link-start))))
|
|
|
|
;; Install keys into the w3m keymap
|
|
(defvar w3m-mode-map)
|
|
(defvar w3m-minor-mode-map)
|
|
(when (and (boundp 'w3m-mode-map)
|
|
(keymapp w3m-mode-map))
|
|
(define-key w3m-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
|
|
(define-key w3m-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode))
|
|
(when (and (boundp 'w3m-minor-mode-map)
|
|
(keymapp w3m-minor-mode-map))
|
|
(define-key w3m-minor-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
|
|
(define-key w3m-minor-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode))
|
|
(add-hook
|
|
'w3m-mode-hook
|
|
(lambda ()
|
|
(define-key w3m-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
|
|
(define-key w3m-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode)))
|
|
(add-hook
|
|
'w3m-minor-mode-hook
|
|
(lambda ()
|
|
(define-key w3m-minor-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
|
|
(define-key w3m-minor-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode)))
|
|
|
|
(provide 'org-w3m)
|
|
|
|
;;; org-w3m.el ends here
|