forked from mirrors/org-mode
ec0b3892b9
* ob.el (org-babel-process-file-name): New function (org-babel-maybe-remote-file): Delete function * ob-sql.el (org-babel-execute:sql): Use org-babel-process-file-name * ob-scheme.el (org-babel-execute:scheme): Use org-babel-process-file-name * ob-sass.el (org-babel-execute:sass): Use org-babel-process-file-name * ob-ruby.el (org-babel-ruby-evaluate): Use org-babel-process-file-name * ob-python.el (org-babel-python-evaluate-external-process): Use org-babel-process-file-name (org-babel-python-evaluate-session): Use org-babel-process-file-name * ob-plantuml.el (org-babel-execute:plantuml): Use org-babel-process-file-name * ob-perl.el (org-babel-perl-evaluate): Use org-babel-process-file-name * ob-octave.el (org-babel-octave-evaluate-external-process): Use org-babel-process-file-name (org-babel-octave-evaluate-session): Use org-babel-process-file-name, don't use org-babel-maybe-remote-file * ob-lisp.el (org-babel-execute:lisp): Use org-babel-process-file-name * ob-ledger.el (org-babel-execute:ledger): Use org-babel-process-file-name * ob-js.el (org-babel-execute:js): Use org-babel-process-file-name * ob-haskell.el (org-babel-haskell-export-to-lhs): Use org-babel-process-file-name * ob-gnuplot.el (org-babel-execute:gnuplot): Use org-babel-process-file-name * ob-eval.el (org-babel-eval-read-file): Don't use org-babel-maybe-remote-file * ob-dot.el (org-babel-execute:dot): Use org-babel-process-file-name * ob-ditaa.el (org-babel-execute:ditaa): Use org-babel-process-file-name * ob-clojure.el (org-babel-clojure-evaluate-external-process): Use org-babel-process-file-name * ob-asymptote.el (org-babel-execute:asymptote): Use org-babel-process-file-name * ob-R.el (org-babel-R-assign-elisp): Don't use org-babel-maybe-remote-file, use org-babel-process-file-name (org-babel-R-evaluate-external-process): Use org-babel-process-file-name (org-babel-R-evaluate-session): Use org-babel-process-file-name * ob-C.el (org-babel-C-execute): Use org-babel-process-file-name In addition to passing the file path through `expand-file-name', tramp-style remote file names are converted to conventional (local) file paths. The reason is that, if a tramp file name was in use in emacs, then the shell command will be executing on the remote machine in question. Further, by default the file name is passed through `shell-quote-argument'.
87 lines
3 KiB
EmacsLisp
87 lines
3 KiB
EmacsLisp
;;; ob-plantuml.el --- org-babel functions for plantuml evaluation
|
|
|
|
;; Copyright (C) 2010 Free Software Foundation, Inc.
|
|
|
|
;; Author: Zhang Weize
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
;; Version: 7.01trans
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating plantuml script.
|
|
;;
|
|
;; Inspired by Ian Yang's org-export-blocks-format-plantuml
|
|
;; http://www.emacswiki.org/emacs/org-export-blocks-format-plantuml.el
|
|
|
|
;;; Requirements:
|
|
|
|
;; plantuml | http://plantuml.sourceforge.net/
|
|
;; plantuml.jar | `org-plantuml-jar-path' should point to the jar file
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'ob-eval)
|
|
|
|
(defvar org-babel-default-header-args:plantuml
|
|
'((:results . "file") (:exports . "results"))
|
|
"Default arguments for evaluating a plantuml source block.")
|
|
|
|
(defun org-babel-expand-body:plantuml (body params &optional processed-params)
|
|
"Expand BODY according to PARAMS, return the expanded body." body)
|
|
|
|
(defcustom org-plantuml-jar-path nil
|
|
"Path to the plantuml.jar file."
|
|
:group 'org-babel
|
|
:type 'string)
|
|
|
|
(defun org-babel-execute:plantuml (body params)
|
|
"Execute a block of plantuml code with org-babel.
|
|
This function is called by `org-babel-execute-src-block'."
|
|
(let* ((result-params (split-string (or (cdr (assoc :results params)) "")))
|
|
(out-file (or (cdr (assoc :file params))
|
|
(error "plantuml requires a \":file\" header argument")))
|
|
(cmdline (cdr (assoc :cmdline params)))
|
|
(in-file (org-babel-temp-file "plantuml-"))
|
|
(cmd (if (not org-plantuml-jar-path)
|
|
(error "`org-plantuml-jar-path' is not set")
|
|
(concat "java -jar "
|
|
(shell-quote-argument
|
|
(expand-file-name org-plantuml-jar-path))
|
|
(if (string= (file-name-extension out-file) "svg")
|
|
"-tsvg" "")
|
|
" -p " cmdline " < "
|
|
(org-babel-process-file-name in-file)
|
|
" > "
|
|
(org-babel-process-file-name out-file)))))
|
|
(unless (file-exists-p org-plantuml-jar-path)
|
|
(error "Could not find plantuml.jar at %s" org-plantuml-jar-path))
|
|
(with-temp-file in-file (insert (concat "@startuml\n" body "\n@enduml")))
|
|
(message "%s" cmd) (org-babel-eval cmd "")
|
|
out-file))
|
|
|
|
(defun org-babel-prep-session:plantuml (session params)
|
|
"Return an error because plantuml does not support sessions."
|
|
(error "Plantuml does not support sessions"))
|
|
|
|
(provide 'ob-plantuml)
|
|
|
|
;; arch-tag: 451f50c5-e779-407e-ad64-70e0e8f161d1
|
|
|
|
;;; ob-plantuml.el ends here
|