forked from mirrors/org-mode
2013-11-12 Stefan Monnier <monnier@iro.umontreal.ca> Address some byte-compiler warnings. * ob-abc.el (org-babel-expand-body:abc): Use dolist. (org-babel-execute:abc): Fix regexp quoting. * ob-calc.el (org--var-syms): Rename from `var-syms'. * ob-lilypond.el (ly-compile-lilyfile): Remove redundant let-binding. * ob-table.el (sbe): Move debug declaration. * org-clock.el (org--msg-extra): Rename from `msg-extra'. * org.el (org-version): Avoid var name starting with _. (org-inhibit-startup, org-called-with-limited-levels) (org-link-search-inhibit-query, org-time-was-given) (org-end-time-was-given, org-def, org-defdecode, org-with-time): * org-colview.el (org-agenda-overriding-columns-format): * org-agenda.el (org-agenda-multi, org-depend-tag-blocked) (org-agenda-show-log-scoped): * ob-python.el (py-which-bufname, python-shell-buffer-name): * ob-haskell.el (org-export-copy-to-kill-ring): * ob-exp.el (org-link-search-inhibit-query): * ob-R.el (ess-eval-visibly-p): * ob-core.el (org-src-window-setup): Declare before use. (org-babel-expand-noweb-references): Remove unused `blocks-in-buffer'. * ox-odt.el (org-odt-hfy-face-to-css): * org-src.el (org-src-associate-babel-session, org-src-get-lang-mode): * org-bibtex.el (org-bibtex-get, org-bibtex-ask, org-bibtex) (org-bibtex-check): * ob-tangle.el (org-babel-tangle, org-babel-spec-to-string) (org-babel-tangle-single-block, org-babel-tangle-comment-links): * ob-table.el (sbe): * ob-sqlite.el (org-babel-sqlite-expand-vars): * ob-sql.el (org-babel-sql-expand-vars): * ob-shen.el (org-babel-execute:shen): * ob-sh.el (org-babel-execute:sh, org-babel-sh-evaluate): * ob-scala.el (org-babel-scala-evaluate): * ob-ruby.el (org-babel-ruby-table-or-string) (org-babel-ruby-evaluate): * ob-python.el (org-babel-python-table-or-string) (org-babel-python-evaluate-external-process) (org-babel-python-evaluate-session): * ob-picolisp.el (org-babel-execute:picolisp): * ob-perl.el (org-babel-perl-evaluate): * ob-maxima.el (org-babel-execute:maxima): * ob-lisp.el (org-babel-execute:lisp): * ob-java.el (org-babel-execute:java): * ob-io.el (org-babel-io-evaluate): * ob-haskell.el (org-babel-execute:haskell): * ob-fortran.el (org-babel-execute:fortran): * ob-exp.el (org-babel-exp-code): * ob-emacs-lisp.el (org-babel-execute:emacs-lisp): * ob-ditaa.el (org-babel-execute:ditaa): * ob-core.el (org-babel-execute-src-block, org-babel-sha1-hash) (org-babel-parse-header-arguments, org-babel-reassemble-table) (org-babel-goto-src-block-head, org-babel-mark-block) (org-babel-expand-noweb-references, org-babel-script-escape) (org-babel-process-file-name): * ob-clojure.el (org-babel-execute:clojure): * ob-calc.el (org-babel-execute:calc): * ob-awk.el (org-babel-execute:awk): * ob-abc.el (org-babel-execute:abc): * ob-R.el (org-babel-expand-body:R): * ob-C.el (org-babel-C-execute): Avoid deprecated ((lambda) ...). 2013-11-12 Glenn Morris <rgm@gnu.org> * ox-html.el (org-html-scripts): Add 2013 to copyright years. (org-html-infojs-template): Copyright holder to FSF.
109 lines
3.7 KiB
EmacsLisp
109 lines
3.7 KiB
EmacsLisp
;;; ob-calc.el --- org-babel functions for calc code evaluation
|
|
|
|
;; Copyright (C) 2010-2013 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Org-Babel support for evaluating calc code
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
(require 'calc)
|
|
(unless (featurep 'xemacs)
|
|
(require 'calc-trail)
|
|
(require 'calc-store))
|
|
|
|
(declare-function calc-store-into "calc-store" (&optional var))
|
|
(declare-function calc-recall "calc-store" (&optional var))
|
|
(declare-function math-evaluate-expr "calc-ext" (x))
|
|
|
|
(defvar org-babel-default-header-args:calc nil
|
|
"Default arguments for evaluating an calc source block.")
|
|
|
|
(defun org-babel-expand-body:calc (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body." body)
|
|
|
|
(defvar org--var-syms) ; Dynamically scoped from org-babel-execute:calc
|
|
|
|
(defun org-babel-execute:calc (body params)
|
|
"Execute a block of calc code with Babel."
|
|
(unless (get-buffer "*Calculator*")
|
|
(save-window-excursion (calc) (calc-quit)))
|
|
(let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
|
|
(org--var-syms (mapcar #'car vars))
|
|
(var-names (mapcar #'symbol-name org--var-syms)))
|
|
(mapc
|
|
(lambda (pair)
|
|
(calc-push-list (list (cdr pair)))
|
|
(calc-store-into (car pair)))
|
|
vars)
|
|
(mapc
|
|
(lambda (line)
|
|
(when (> (length line) 0)
|
|
(cond
|
|
;; simple variable name
|
|
((member line var-names) (calc-recall (intern line)))
|
|
;; stack operation
|
|
((string= "'" (substring line 0 1))
|
|
(funcall (lookup-key calc-mode-map (substring line 1)) nil))
|
|
;; complex expression
|
|
(t
|
|
(calc-push-list
|
|
(list (let ((res (calc-eval line)))
|
|
(cond
|
|
((numberp res) res)
|
|
((math-read-number res) (math-read-number res))
|
|
((listp res) (error "Calc error \"%s\" on input \"%s\""
|
|
(cadr res) line))
|
|
(t (replace-regexp-in-string
|
|
"'" ""
|
|
(calc-eval
|
|
(math-evaluate-expr
|
|
;; resolve user variables, calc built in
|
|
;; variables are handled automatically
|
|
;; upstream by calc
|
|
(mapcar #'org-babel-calc-maybe-resolve-var
|
|
;; parse line into calc objects
|
|
(car (math-read-exprs line)))))))))
|
|
))))))
|
|
(mapcar #'org-babel-trim
|
|
(split-string (org-babel-expand-body:calc body params) "[\n\r]"))))
|
|
(save-excursion
|
|
(with-current-buffer (get-buffer "*Calculator*")
|
|
(calc-eval (calc-top 1)))))
|
|
|
|
(defun org-babel-calc-maybe-resolve-var (el)
|
|
(if (consp el)
|
|
(if (and (equal 'var (car el)) (member (cadr el) org--var-syms))
|
|
(progn
|
|
(calc-recall (cadr el))
|
|
(prog1 (calc-top 1)
|
|
(calc-pop 1)))
|
|
(mapcar #'org-babel-calc-maybe-resolve-var el))
|
|
el))
|
|
|
|
(provide 'ob-calc)
|
|
|
|
|
|
|
|
;;; ob-calc.el ends here
|