forked from mirrors/org-mode
2013-11-12 Stefan Monnier <monnier@iro.umontreal.ca> Address some byte-compiler warnings. * ob-abc.el (org-babel-expand-body:abc): Use dolist. (org-babel-execute:abc): Fix regexp quoting. * ob-calc.el (org--var-syms): Rename from `var-syms'. * ob-lilypond.el (ly-compile-lilyfile): Remove redundant let-binding. * ob-table.el (sbe): Move debug declaration. * org-clock.el (org--msg-extra): Rename from `msg-extra'. * org.el (org-version): Avoid var name starting with _. (org-inhibit-startup, org-called-with-limited-levels) (org-link-search-inhibit-query, org-time-was-given) (org-end-time-was-given, org-def, org-defdecode, org-with-time): * org-colview.el (org-agenda-overriding-columns-format): * org-agenda.el (org-agenda-multi, org-depend-tag-blocked) (org-agenda-show-log-scoped): * ob-python.el (py-which-bufname, python-shell-buffer-name): * ob-haskell.el (org-export-copy-to-kill-ring): * ob-exp.el (org-link-search-inhibit-query): * ob-R.el (ess-eval-visibly-p): * ob-core.el (org-src-window-setup): Declare before use. (org-babel-expand-noweb-references): Remove unused `blocks-in-buffer'. * ox-odt.el (org-odt-hfy-face-to-css): * org-src.el (org-src-associate-babel-session, org-src-get-lang-mode): * org-bibtex.el (org-bibtex-get, org-bibtex-ask, org-bibtex) (org-bibtex-check): * ob-tangle.el (org-babel-tangle, org-babel-spec-to-string) (org-babel-tangle-single-block, org-babel-tangle-comment-links): * ob-table.el (sbe): * ob-sqlite.el (org-babel-sqlite-expand-vars): * ob-sql.el (org-babel-sql-expand-vars): * ob-shen.el (org-babel-execute:shen): * ob-sh.el (org-babel-execute:sh, org-babel-sh-evaluate): * ob-scala.el (org-babel-scala-evaluate): * ob-ruby.el (org-babel-ruby-table-or-string) (org-babel-ruby-evaluate): * ob-python.el (org-babel-python-table-or-string) (org-babel-python-evaluate-external-process) (org-babel-python-evaluate-session): * ob-picolisp.el (org-babel-execute:picolisp): * ob-perl.el (org-babel-perl-evaluate): * ob-maxima.el (org-babel-execute:maxima): * ob-lisp.el (org-babel-execute:lisp): * ob-java.el (org-babel-execute:java): * ob-io.el (org-babel-io-evaluate): * ob-haskell.el (org-babel-execute:haskell): * ob-fortran.el (org-babel-execute:fortran): * ob-exp.el (org-babel-exp-code): * ob-emacs-lisp.el (org-babel-execute:emacs-lisp): * ob-ditaa.el (org-babel-execute:ditaa): * ob-core.el (org-babel-execute-src-block, org-babel-sha1-hash) (org-babel-parse-header-arguments, org-babel-reassemble-table) (org-babel-goto-src-block-head, org-babel-mark-block) (org-babel-expand-noweb-references, org-babel-script-escape) (org-babel-process-file-name): * ob-clojure.el (org-babel-execute:clojure): * ob-calc.el (org-babel-execute:calc): * ob-awk.el (org-babel-execute:awk): * ob-abc.el (org-babel-execute:abc): * ob-R.el (org-babel-expand-body:R): * ob-C.el (org-babel-C-execute): Avoid deprecated ((lambda) ...). 2013-11-12 Glenn Morris <rgm@gnu.org> * ox-html.el (org-html-scripts): Add 2013 to copyright years. (org-html-infojs-template): Copyright holder to FSF.
142 lines
5 KiB
EmacsLisp
142 lines
5 KiB
EmacsLisp
;;; ob-table.el --- support for calling org-babel functions from tables
|
|
|
|
;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Should allow calling functions from org-mode tables using the
|
|
;; function `sbe' as so...
|
|
|
|
;; #+begin_src emacs-lisp :results silent
|
|
;; (defun fibbd (n) (if (< n 2) 1 (+ (fibbd (- n 1)) (fibbd (- n 2)))))
|
|
;; #+end_src
|
|
|
|
;; #+name: fibbd
|
|
;; #+begin_src emacs-lisp :var n=2 :results silent
|
|
;; (fibbd n)
|
|
;; #+end_src
|
|
|
|
;; | original | fibbd |
|
|
;; |----------+--------|
|
|
;; | 0 | |
|
|
;; | 1 | |
|
|
;; | 2 | |
|
|
;; | 3 | |
|
|
;; | 4 | |
|
|
;; | 5 | |
|
|
;; | 6 | |
|
|
;; | 7 | |
|
|
;; | 8 | |
|
|
;; | 9 | |
|
|
;; #+TBLFM: $2='(sbe 'fibbd (n $1))
|
|
|
|
;;; Code:
|
|
(require 'ob-core)
|
|
|
|
(defun org-babel-table-truncate-at-newline (string)
|
|
"Replace newline character with ellipses.
|
|
If STRING ends in a newline character, then remove the newline
|
|
character and replace it with ellipses."
|
|
(if (and (stringp string) (string-match "[\n\r]\\(.\\)?" string))
|
|
(concat (substring string 0 (match-beginning 0))
|
|
(if (match-string 1 string) "...")) string))
|
|
|
|
(defmacro sbe (source-block &rest variables) ;FIXME: Namespace prefix!
|
|
"Return the results of calling SOURCE-BLOCK with VARIABLES.
|
|
Each element of VARIABLES should be a two
|
|
element list, whose first element is the name of the variable and
|
|
second element is a string of its value. The following call to
|
|
`sbe' would be equivalent to the following source code block.
|
|
|
|
(sbe 'source-block (n $2) (m 3))
|
|
|
|
#+begin_src emacs-lisp :var results=source-block(n=val_at_col_2, m=3) :results silent
|
|
results
|
|
#+end_src
|
|
|
|
NOTE: by default string variable names are interpreted as
|
|
references to source-code blocks, to force interpretation of a
|
|
cell's value as a string, prefix the identifier a \"$\" (e.g.,
|
|
\"$$2\" instead of \"$2\" or \"$@2$2\" instead of \"@2$2\").
|
|
|
|
NOTE: it is also possible to pass header arguments to the code
|
|
block. In this case a table cell should hold the string value of
|
|
the header argument which can then be passed before all variables
|
|
as shown in the example below.
|
|
|
|
| 1 | 2 | :file nothing.png | nothing.png |
|
|
#+TBLFM: @1$4='(sbe test-sbe $3 (x $1) (y $2))"
|
|
(declare (debug (form form)))
|
|
(let* ((header-args (if (stringp (car variables)) (car variables) ""))
|
|
(variables (if (stringp (car variables)) (cdr variables) variables)))
|
|
(let* (quote
|
|
(variables
|
|
(mapcar
|
|
(lambda (var)
|
|
;; ensure that all cells prefixed with $'s are strings
|
|
(cons (car var)
|
|
(delq nil (mapcar
|
|
(lambda (el)
|
|
(if (eq '$ el)
|
|
(prog1 nil (setq quote t))
|
|
(prog1
|
|
(cond
|
|
(quote (format "\"%s\"" el))
|
|
((stringp el) (org-no-properties el))
|
|
(t el))
|
|
(setq quote nil))))
|
|
(cdr var)))))
|
|
variables)))
|
|
(unless (stringp source-block)
|
|
(setq source-block (symbol-name source-block)))
|
|
(let ((result
|
|
(if (and source-block (> (length source-block) 0))
|
|
(let ((params
|
|
;; FIXME: Why `eval'?!?!?
|
|
(eval `(org-babel-parse-header-arguments
|
|
(concat
|
|
":var results="
|
|
,source-block
|
|
"[" ,header-args "]"
|
|
"("
|
|
(mapconcat
|
|
(lambda (var-spec)
|
|
(if (> (length (cdr var-spec)) 1)
|
|
(format "%S='%S"
|
|
(car var-spec)
|
|
(mapcar #'read (cdr var-spec)))
|
|
(format "%S=%s"
|
|
(car var-spec) (cadr var-spec))))
|
|
',variables ", ")
|
|
")")))))
|
|
(org-babel-execute-src-block
|
|
nil (list "emacs-lisp" "results" params)
|
|
'((:results . "silent"))))
|
|
"")))
|
|
(org-babel-trim (if (stringp result) result (format "%S" result)))))))
|
|
|
|
(provide 'ob-table)
|
|
|
|
|
|
|
|
;;; ob-table.el ends here
|